net-snmp_5.7.3.bb 9.9 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236
  1. SUMMARY = "Various tools relating to the Simple Network Management Protocol"
  2. HOMEPAGE = "http://www.net-snmp.org/"
  3. SECTION = "net"
  4. LICENSE = "BSD"
  5. LIC_FILES_CHKSUM = "file://README;beginline=3;endline=8;md5=7f7f00ba639ac8e8deb5a622ea24634e"
  6. DEPENDS = "openssl libnl pciutils"
  7. SRC_URI = "${SOURCEFORGE_MIRROR}/net-snmp/net-snmp-${PV}.zip \
  8. file://init \
  9. file://snmpd.conf \
  10. file://snmptrapd.conf \
  11. file://systemd-support.patch \
  12. file://snmpd.service \
  13. file://snmptrapd.service \
  14. file://net-snmp-add-knob-whether-nlist.h-are-checked.patch \
  15. file://fix-libtool-finish.patch \
  16. file://net-snmp-testing-add-the-output-format-for-ptest.patch \
  17. file://run-ptest \
  18. file://dont-return-incompletely-parsed-varbinds.patch \
  19. file://0001-config_os_headers-Error-Fix.patch \
  20. file://0001-config_os_libs2-Error-Fix.patch \
  21. file://0001-snmplib-keytools.c-Don-t-check-for-return-from-EVP_M.patch \
  22. file://net-snmp-agentx-crash.patch \
  23. file://0001-get_pid_from_inode-Include-limit.h.patch \
  24. file://0001-BUG-a2584-Fix-snmptrap-to-use-clientaddr-from-snmp.c.patch \
  25. file://0001-snmplib-UDPIPv6-transport-Add-a-missing-return-state.patch \
  26. file://0001-configure-fix-check-for-enable-perl-cc-checks.patch \
  27. file://0002-configure-fix-a-cc-check-issue.patch \
  28. file://0003-CHANGES-BUG-2712-Fix-Perl-module-compilation.patch \
  29. file://0004-configure-fix-incorrect-variable.patch \
  30. file://net-snmp-5.7.2-fix-engineBoots-value-on-SIGHUP.patch \
  31. file://net-snmp-fix-for-disable-des.patch \
  32. "
  33. SRC_URI[md5sum] = "9f682bd70c717efdd9f15b686d07baee"
  34. SRC_URI[sha256sum] = "e8dfc79b6539b71a6ff335746ce63d2da2239062ad41872fff4354cafed07a3e"
  35. inherit autotools-brokensep update-rc.d siteinfo systemd pkgconfig perlnative
  36. EXTRA_OEMAKE = "INSTALL_PREFIX=${D} OTHERLDFLAGS='${LDFLAGS}' HOST_CPPFLAGS='${BUILD_CPPFLAGS}'"
  37. PARALLEL_MAKE = ""
  38. CCACHE = ""
  39. TARGET_CC_ARCH += "${LDFLAGS}"
  40. PACKAGECONFIG ??= ""
  41. PACKAGECONFIG[elfutils] = "--with-elf, --without-elf, elfutils"
  42. PACKAGECONFIG[libnl] = "--with-nl, --without-nl, libnl"
  43. PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'ipv6', d)}"
  44. PACKAGECONFIG[ipv6] = "--enable-ipv6,--disable-ipv6,,"
  45. PACKAGECONFIG[perl] = "--enable-embedded-perl --with-perl-modules=yes, --disable-embedded-perl --with-perl-modules=no,\
  46. perl, perl perl-lib"
  47. EXTRA_OECONF = "--enable-shared \
  48. --disable-manuals \
  49. --with-defaults \
  50. --with-install-prefix=${D} \
  51. --with-persistent-directory=${localstatedir}/lib/net-snmp \
  52. ${@oe.utils.conditional('SITEINFO_ENDIANNESS', 'le', '--with-endianness=little', '--with-endianness=big', d)} \
  53. "
  54. # net-snmp needs to have mib-modules=smux enabled to enable quagga to support snmp
  55. EXTRA_OECONF += "--with-mib-modules=smux"
  56. CACHED_CONFIGUREVARS = " \
  57. ac_cv_header_valgrind_valgrind_h=no \
  58. ac_cv_header_valgrind_memcheck_h=no \
  59. ac_cv_ETC_MNTTAB=/etc/mtab \
  60. lt_cv_shlibpath_overrides_runpath=yes \
  61. "
  62. export PERLPROG="${bindir}/env perl"
  63. PERLPROG_append = "${@bb.utils.contains('PACKAGECONFIG', 'perl', ' -I${WORKDIR}', '', d)}"
  64. HAS_PERL = "${@bb.utils.contains('PACKAGECONFIG', 'perl', '1', '0', d)}"
  65. do_configure_prepend() {
  66. sed -i -e "s|I/usr/include|I${STAGING_INCDIR}|g" \
  67. "${S}"/configure \
  68. "${S}"/configure.d/config_os_libs2
  69. if [ "${HAS_PERL}" = "1" ]; then
  70. # this may need to be changed when package perl has any change.
  71. cp -f ${STAGING_DIR_TARGET}/usr/lib*/perl/*/Config.pm ${WORKDIR}/
  72. cp -f ${STAGING_DIR_TARGET}/usr/lib*/perl/*/Config_heavy.pl ${WORKDIR}/
  73. sed -e "s@libpth => '/usr/lib.*@libpth => '${STAGING_DIR_TARGET}/${libdir} ${STAGING_DIR_TARGET}/${base_libdir}',@g" \
  74. -e "s@privlibexp => '/usr@privlibexp => '${STAGING_DIR_TARGET}/usr@g" \
  75. -e "s@scriptdir => '/usr@scriptdir => '${STAGING_DIR_TARGET}/usr@g" \
  76. -e "s@sitearchexp => '/usr@sitearchexp => '${STAGING_DIR_TARGET}/usr@g" \
  77. -e "s@sitelibexp => '/usr@sitearchexp => '${STAGING_DIR_TARGET}/usr@g" \
  78. -e "s@vendorarchexp => '/usr@vendorarchexp => '${STAGING_DIR_TARGET}/usr@g" \
  79. -e "s@vendorlibexp => '/usr@vendorlibexp => '${STAGING_DIR_TARGET}/usr@g" \
  80. -i ${WORKDIR}/Config.pm
  81. fi
  82. }
  83. do_configure_append() {
  84. if [ "${HAS_PERL}" = "1" ]; then
  85. sed -e "s@^NSC_INCLUDEDIR=.*@NSC_INCLUDEDIR=${STAGING_DIR_TARGET}\$\{includedir\}@g" \
  86. -e "s@^NSC_LIBDIR=-L.*@NSC_LIBDIR=-L${STAGING_DIR_TARGET}\$\{libdir\}@g" \
  87. -i ${B}/net-snmp-config
  88. fi
  89. }
  90. do_install_append() {
  91. install -d ${D}${sysconfdir}/snmp
  92. install -d ${D}${sysconfdir}/init.d
  93. install -m 755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/snmpd
  94. install -m 644 ${WORKDIR}/snmpd.conf ${D}${sysconfdir}/snmp/
  95. install -m 644 ${WORKDIR}/snmptrapd.conf ${D}${sysconfdir}/snmp/
  96. install -d ${D}${systemd_unitdir}/system
  97. install -m 0644 ${WORKDIR}/snmpd.service ${D}${systemd_unitdir}/system
  98. install -m 0644 ${WORKDIR}/snmptrapd.service ${D}${systemd_unitdir}/system
  99. sed -e "s@^NSC_SRCDIR=.*@NSC_SRCDIR=.@g" \
  100. -i ${D}${bindir}/net-snmp-create-v3-user
  101. sed -e "s@^NSC_SRCDIR=.*@NSC_SRCDIR=.@g" \
  102. -e "s@${STAGING_DIR_NATIVE}[=]*@@g" \
  103. -e "s@${STAGING_DIR_HOST}[=]*@@g" \
  104. -e "s@${WORKDIR}[=]*@@g" \
  105. -e "s@${D}@@g" \
  106. -i ${D}${bindir}/net-snmp-config
  107. if [ "${HAS_PERL}" = "1" ]; then
  108. sed -e "s@^NSC_INCLUDEDIR=.*@NSC_INCLUDEDIR=\$\{includedir\}@g" \
  109. -e "s@^NSC_LIBDIR=-L.*@NSC_LIBDIR=-L\$\{libdir\}@g" \
  110. -i ${D}${bindir}/net-snmp-config
  111. fi
  112. }
  113. do_install_ptest() {
  114. install -d ${D}${PTEST_PATH}
  115. for i in ${S}/dist ${S}/include ${B}/include ${S}/mibs ${S}/configure \
  116. ${B}/net-snmp-config ${S}/testing; do
  117. if [ -e "$i" ]; then
  118. cp -R --no-dereference --preserve=mode,links -v "$i" ${D}${PTEST_PATH}
  119. fi
  120. done
  121. echo `autoconf -V|awk '/autoconf/{print $NF}'` > ${D}${PTEST_PATH}/dist/autoconf-version
  122. rmdlist="${D}${PTEST_PATH}/dist/net-snmp-solaris-build"
  123. for i in $rmdlist; do
  124. if [ -d "$i" ]; then
  125. rm -rf "$i"
  126. fi
  127. done
  128. }
  129. SYSROOT_PREPROCESS_FUNCS += "net_snmp_sysroot_preprocess"
  130. net_snmp_sysroot_preprocess () {
  131. if [ -e ${D}${bindir}/net-snmp-config ]; then
  132. install -d ${SYSROOT_DESTDIR}${bindir_crossscripts}/
  133. install -m 755 ${D}${bindir}/net-snmp-config ${SYSROOT_DESTDIR}${bindir_crossscripts}/
  134. sed -e "s@-I/usr/include@-I${STAGING_INCDIR}@g" \
  135. -e "s@^prefix=.*@prefix=${STAGING_DIR_HOST}${prefix}@g" \
  136. -e "s@^exec_prefix=.*@exec_prefix=${STAGING_EXECPREFIXDIR}@g" \
  137. -e "s@^includedir=.*@includedir=${STAGING_INCDIR}@g" \
  138. -e "s@^libdir=.*@libdir=${STAGING_LIBDIR}@g" \
  139. -e "s@^NSC_SRCDIR=.*@NSC_SRCDIR=${S}@g" \
  140. -i ${SYSROOT_DESTDIR}${bindir_crossscripts}/net-snmp-config
  141. fi
  142. }
  143. PACKAGES += "${PN}-libs ${PN}-mibs ${PN}-server ${PN}-client ${PN}-server-snmpd ${PN}-server-snmptrapd"
  144. # perl module
  145. PACKAGES += "${@bb.utils.contains('PACKAGECONFIG', 'perl', '${PN}-perl-modules', '', d)}"
  146. ALLOW_EMPTY_${PN} = "1"
  147. ALLOW_EMPTY_${PN}-server = "1"
  148. FILES_${PN}-perl-modules = "${libdir}/perl/*"
  149. FILES_${PN}-libs = "${libdir}/lib*${SOLIBS}"
  150. FILES_${PN}-mibs = "${datadir}/snmp/mibs"
  151. FILES_${PN}-server-snmpd = "${sbindir}/snmpd \
  152. ${sysconfdir}/snmp/snmpd.conf \
  153. ${sysconfdir}/init.d \
  154. ${systemd_unitdir}/system/snmpd.service \
  155. "
  156. FILES_${PN}-server-snmptrapd = "${sbindir}/snmptrapd \
  157. ${sysconfdir}/snmp/snmptrapd.conf \
  158. ${systemd_unitdir}/system/snmptrapd.service \
  159. "
  160. FILES_${PN} = ""
  161. FILES_${PN}-client = "${bindir}/* ${datadir}/snmp/"
  162. FILES_${PN}-dbg += "${libdir}/.debug/ ${sbindir}/.debug/ ${bindir}/.debug/"
  163. FILES_${PN}-dev += "${bindir}/mib2c ${bindir}/mib2c-update"
  164. CONFFILES_${PN}-server-snmpd = "${sysconfdir}/snmp/snmpd.conf"
  165. CONFFILES_${PN}-server-snmptrapd = "${sysconfdir}/snmp/snmptrapd.conf"
  166. INITSCRIPT_PACKAGES = "${PN}-server-snmpd"
  167. INITSCRIPT_NAME_${PN}-server-snmpd = "snmpd"
  168. INITSCRIPT_PARAMS_${PN}-server-snmpd = "start 90 2 3 4 5 . stop 60 0 1 6 ."
  169. EXTRA_OECONF += "${@bb.utils.contains('DISTRO_FEATURES', 'systemd', '--with-systemd', '--without-systemd', d)}"
  170. SYSTEMD_PACKAGES = "${PN}-server-snmpd \
  171. ${PN}-server-snmptrapd"
  172. SYSTEMD_SERVICE_${PN}-server-snmpd = "snmpd.service"
  173. SYSTEMD_SERVICE_${PN}-server-snmptrapd = "snmptrapd.service"
  174. RDEPENDS_${PN} += "${@bb.utils.contains('PACKAGECONFIG', 'perl', 'net-snmp-perl-modules', '', d)}"
  175. RDEPENDS_${PN} += "net-snmp-client"
  176. RDEPENDS_${PN}-server-snmpd += "net-snmp-mibs"
  177. RDEPENDS_${PN}-server-snmptrapd += "net-snmp-server-snmpd"
  178. RDEPENDS_${PN}-server += "net-snmp-server-snmpd net-snmp-server-snmptrapd"
  179. RDEPENDS_${PN}-client += "net-snmp-mibs net-snmp-libs"
  180. RDEPENDS_${PN}-libs += "libpci"
  181. RDEPENDS_${PN}-ptest += "perl \
  182. perl-module-test \
  183. perl-module-file-basename \
  184. perl-module-getopt-long \
  185. perl-module-file-temp \
  186. perl-module-data-dumper \
  187. "
  188. RDEPENDS_${PN}-dev = "net-snmp-client (= ${EXTENDPKGV}) net-snmp-server (= ${EXTENDPKGV})"
  189. RRECOMMENDS_${PN}-dbg = "net-snmp-client (= ${EXTENDPKGV}) net-snmp-server (= ${EXTENDPKGV})"
  190. RPROVIDES_${PN}-server-snmpd += "${PN}-server-snmpd-systemd"
  191. RREPLACES_${PN}-server-snmpd += "${PN}-server-snmpd-systemd"
  192. RCONFLICTS_${PN}-server-snmpd += "${PN}-server-snmpd-systemd"
  193. RPROVIDES_${PN}-server-snmptrapd += "${PN}-server-snmptrapd-systemd"
  194. RREPLACES_${PN}-server-snmptrapd += "${PN}-server-snmptrapd-systemd"
  195. RCONFLICTS_${PN}-server-snmptrapd += "${PN}-server-snmptrapd-systemd"
  196. LEAD_SONAME = "libnetsnmp.so"