networkmanager_1.14.4.bb 4.9 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142
  1. SUMMARY = "NetworkManager"
  2. HOMEPAGE = "https://wiki.gnome.org/Projects/NetworkManager"
  3. SECTION = "net/misc"
  4. LICENSE = "GPLv2+"
  5. LIC_FILES_CHKSUM = "file://COPYING;md5=cbbffd568227ada506640fe950a4823b \
  6. file://libnm-util/COPYING;md5=1c4fa765d6eb3cd2fbd84344a1b816cd \
  7. file://docs/api/html/license.html;md5=2d56a1b0c42e388aa86aef59b154e8c3 \
  8. "
  9. DEPENDS = " \
  10. intltool-native \
  11. libxslt-native \
  12. libnl \
  13. libgudev \
  14. util-linux \
  15. libndp \
  16. libnewt \
  17. polkit \
  18. jansson \
  19. curl \
  20. "
  21. inherit gnomebase gettext systemd bluetooth bash-completion vala gobject-introspection gtk-doc
  22. SRC_URI = " \
  23. ${GNOME_MIRROR}/NetworkManager/${@gnome_verdir("${PV}")}/NetworkManager-${PV}.tar.xz \
  24. file://0001-sd-lldp.h-Remove-net-ethernet.h-seems-to-be-over-spe.patch \
  25. file://0002-Fixed-configure.ac-Fix-pkgconfig-sysroot-locations.patch \
  26. file://0003-Do-not-create-settings-settings-property-documentati.patch \
  27. file://0001-Do-not-include-net-ethernet.h-and-linux-if_ether.h.patch \
  28. file://musl/0001-musl-basic.patch \
  29. file://musl/0002-musl-dlopen-configure-ac.patch \
  30. file://musl/0003-musl-network-support.patch \
  31. file://musl/0004-musl-process-util.patch \
  32. file://musl/0005-musl-avoid-further-conflicts-by-including-net-ethern.patch \
  33. file://musl/0006-Add-a-strndupa-replacement-for-musl.patch \
  34. "
  35. SRC_URI[md5sum] = "54ce62f0aa18ef6c5e754eaac47494ac"
  36. SRC_URI[sha256sum] = "35a3ede4c7d12d6212033c9e44cb82b7692f38063b53a067567f02f5937c8c18"
  37. UPSTREAM_CHECK_URI = "${GNOME_MIRROR}/NetworkManager/1.10/"
  38. UPSTREAM_CHECK_REGEX = "NetworkManager\-(?P<pver>1\.10(\.\d+)+).tar.xz"
  39. S = "${WORKDIR}/NetworkManager-${PV}"
  40. EXTRA_OECONF = " \
  41. --disable-ifcfg-rh \
  42. --disable-more-warnings \
  43. --with-iptables=${sbindir}/iptables \
  44. --with-tests \
  45. --with-nmtui=yes \
  46. "
  47. # gobject-introspection related
  48. GI_DATA_ENABLED_libc-musl = "False"
  49. # stolen from https://github.com/voidlinux/void-packages/blob/master/srcpkgs/NetworkManager/template
  50. CFLAGS_libc-musl_append = " \
  51. -DHAVE_SECURE_GETENV -Dsecure_getenv=getenv \
  52. -D__USE_POSIX199309 -DRTLD_DEEPBIND=0 \
  53. "
  54. do_compile_prepend() {
  55. export GIR_EXTRA_LIBS_PATH="${B}/libnm/.libs:${B}/libnm-glib/.libs:${B}/libnm-util/.libs"
  56. }
  57. PACKAGECONFIG ??= "nss ifupdown dhclient dnsmasq \
  58. ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'systemd', bb.utils.contains('DISTRO_FEATURES', 'x11', 'consolekit', '', d), d)} \
  59. ${@bb.utils.contains('DISTRO_FEATURES', 'bluetooth', '${BLUEZ}', '', d)} \
  60. ${@bb.utils.filter('DISTRO_FEATURES', 'wifi', d)} \
  61. "
  62. PACKAGECONFIG[systemd] = " \
  63. --with-systemdsystemunitdir=${systemd_unitdir}/system --with-session-tracking=systemd --enable-polkit, \
  64. --without-systemdsystemunitdir, \
  65. polkit \
  66. "
  67. PACKAGECONFIG[bluez5] = "--enable-bluez5-dun,--disable-bluez5-dun,bluez5"
  68. # consolekit is not picked by shlibs, so add it to RDEPENDS too
  69. PACKAGECONFIG[consolekit] = "--with-session-tracking=consolekit,,consolekit,consolekit"
  70. PACKAGECONFIG[modemmanager] = "--with-modem-manager-1=yes,--with-modem-manager-1=no,modemmanager"
  71. PACKAGECONFIG[ppp] = "--enable-ppp,--disable-ppp,ppp,ppp"
  72. # Use full featured dhcp client instead of internal one
  73. PACKAGECONFIG[dhclient] = "--with-dhclient=${base_sbindir}/dhclient,,,dhcp-client"
  74. PACKAGECONFIG[dnsmasq] = "--with-dnsmasq=${bindir}/dnsmasq"
  75. PACKAGECONFIG[nss] = "--with-crypto=nss,,nss"
  76. PACKAGECONFIG[glib] = "--with-libnm-glib,,dbus-glib-native dbus-glib"
  77. PACKAGECONFIG[gnutls] = "--with-crypto=gnutls,,gnutls"
  78. PACKAGECONFIG[wifi] = "--enable-wifi=yes,--enable-wifi=no,,wpa-supplicant"
  79. PACKAGECONFIG[ifupdown] = "--enable-ifupdown,--disable-ifupdown"
  80. PACKAGECONFIG[qt4-x11-free] = "--enable-qt,--disable-qt,qt4-x11-free"
  81. PACKAGES =+ "libnmutil libnmglib libnmglib-vpn \
  82. ${PN}-nmtui ${PN}-nmtui-doc \
  83. ${PN}-adsl \
  84. "
  85. FILES_libnmutil += "${libdir}/libnm-util.so.*"
  86. FILES_libnmglib += "${libdir}/libnm-glib.so.*"
  87. FILES_libnmglib-vpn += "${libdir}/libnm-glib-vpn.so.*"
  88. FILES_${PN}-adsl = "${libdir}/NetworkManager/libnm-device-plugin-adsl.so"
  89. FILES_${PN} += " \
  90. ${libexecdir} \
  91. ${libdir}/NetworkManager/${PV}/*.so \
  92. ${nonarch_libdir}/NetworkManager/VPN \
  93. ${nonarch_libdir}/NetworkManager/conf.d \
  94. ${datadir}/polkit-1 \
  95. ${datadir}/dbus-1 \
  96. ${base_libdir}/udev/* \
  97. ${systemd_unitdir}/system \
  98. "
  99. RRECOMMENDS_${PN} += "iptables \
  100. ${@bb.utils.filter('PACKAGECONFIG', 'dnsmasq', d)} \
  101. "
  102. RCONFLICTS_${PN} = "connman"
  103. FILES_${PN}-dev += " \
  104. ${datadir}/NetworkManager/gdb-cmd \
  105. ${libdir}/pppd/*/*.la \
  106. ${libdir}/NetworkManager/*.la \
  107. ${libdir}/NetworkManager/${PV}/*.la \
  108. "
  109. FILES_${PN}-nmtui = " \
  110. ${bindir}/nmtui \
  111. ${bindir}/nmtui-edit \
  112. ${bindir}/nmtui-connect \
  113. ${bindir}/nmtui-hostname \
  114. "
  115. FILES_${PN}-nmtui-doc = " \
  116. ${mandir}/man1/nmtui* \
  117. "
  118. SYSTEMD_SERVICE_${PN} = "NetworkManager.service NetworkManager-dispatcher.service"
  119. do_install_append() {
  120. rm -rf ${D}/run ${D}${localstatedir}/run
  121. }