fuse3_3.10.1.bb 1.8 KB

12345678910111213141516171819202122232425262728293031323334353637383940414243444546474849505152535455565758596061
  1. SUMMARY = "Implementation of a fully functional filesystem in a userspace program"
  2. DESCRIPTION = "FUSE (Filesystem in Userspace) is a simple interface for userspace \
  3. programs to export a virtual filesystem to the Linux kernel. FUSE \
  4. also aims to provide a secure method for non privileged users to \
  5. create and mount their own filesystem implementations. \
  6. "
  7. HOMEPAGE = "https://github.com/libfuse/libfuse"
  8. SECTION = "libs"
  9. LICENSE = "GPLv2 & LGPLv2"
  10. LIC_FILES_CHKSUM = "file://GPL2.txt;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
  11. file://LGPL2.txt;md5=4fbd65380cdd255951079008b364516c \
  12. file://LICENSE;md5=a55c12a2d7d742ecb41ca9ae0a6ddc66"
  13. SRC_URI = "https://github.com/libfuse/libfuse/releases/download/fuse-${PV}/fuse-${PV}.tar.xz \
  14. "
  15. SRC_URI[sha256sum] = "d82d74d4c03e099f806e4bb31483955637c69226576bf0ca9bd142f1d50ae451"
  16. S = "${WORKDIR}/fuse-${PV}"
  17. UPSTREAM_CHECK_URI = "https://github.com/libfuse/libfuse/releases"
  18. UPSTREAM_CHECK_REGEX = "fuse\-(?P<pver>3(\.\d+)+).tar.xz"
  19. inherit meson pkgconfig ptest
  20. SRC_URI += " \
  21. file://run-ptest \
  22. "
  23. RDEPENDS_${PN}-ptest += " \
  24. ${PYTHON_PN}-pytest \
  25. bash \
  26. "
  27. do_install_ptest() {
  28. install -d ${D}${PTEST_PATH}/test
  29. cp -rf ${S}/test/* ${D}${PTEST_PATH}/test/
  30. }
  31. DEPENDS = "udev"
  32. PACKAGES =+ "fuse3-utils"
  33. RPROVIDES_${PN}-dbg += "fuse3-utils-dbg"
  34. RRECOMMENDS_${PN}_class-target = "kernel-module-fuse fuse3-utils"
  35. FILES_${PN} += "${libdir}/libfuse3.so.*"
  36. FILES_${PN}-dev += "${libdir}/libfuse3*.la"
  37. EXTRA_OEMESON += " \
  38. -Dexamples=false \
  39. "
  40. # Forbid auto-renaming to libfuse3-utils
  41. FILES_fuse3-utils = "${bindir} ${base_sbindir}"
  42. DEBIAN_NOAUTONAME_fuse3-utils = "1"
  43. DEBIAN_NOAUTONAME_${PN}-dbg = "1"
  44. do_install_append() {
  45. rm -rf ${D}${base_prefix}/dev
  46. }