tk_8.6.10.bb 3.1 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293
  1. SUMMARY = "Tool Command Language ToolKit Extension"
  2. HOMEPAGE = "http://tcl.sourceforge.net"
  3. SECTION = "devel/tcltk"
  4. # http://www.tcl.tk/software/tcltk/license.html
  5. LICENSE = "tcl"
  6. LIC_FILES_CHKSUM = "file://${S}/../license.terms;md5=c88f99decec11afa967ad33d314f87fe \
  7. file://${S}/../compat/license.terms;md5=c88f99decec11afa967ad33d314f87fe \
  8. file://${S}/../doc/license.terms;md5=c88f99decec11afa967ad33d314f87fe \
  9. file://${S}/../library/license.terms;md5=c88f99decec11afa967ad33d314f87fe \
  10. file://${S}/../macosx/license.terms;md5=c88f99decec11afa967ad33d314f87fe \
  11. file://${S}/../tests/license.terms;md5=c88f99decec11afa967ad33d314f87fe \
  12. file://${S}/../unix/license.terms;md5=c88f99decec11afa967ad33d314f87fe \
  13. file://${S}/../win/license.terms;md5=c88f99decec11afa967ad33d314f87fe \
  14. file://${S}/../xlib/license.terms;md5=c88f99decec11afa967ad33d314f87fe \
  15. "
  16. DEPENDS = "tcl virtual/libx11 libxt"
  17. SRC_URI = "\
  18. ${SOURCEFORGE_MIRROR}/tcl/${BPN}${PV}-src.tar.gz \
  19. file://confsearch.diff;striplevel=2 \
  20. file://tkprivate.diff;striplevel=2 \
  21. file://fix-xft.diff \
  22. "
  23. SRC_URI[md5sum] = "602a47ad9ecac7bf655ada729d140a94"
  24. SRC_URI[sha256sum] = "63df418a859d0a463347f95ded5cd88a3dd3aaa1ceecaeee362194bc30f3e386"
  25. S = "${WORKDIR}/${BPN}${PV}/unix"
  26. # Short version format: "8.6"
  27. VER = "${@os.path.splitext(d.getVar('PV'))[0]}"
  28. LDFLAGS += "-Wl,-rpath,${libdir}/tcltk/${PV}/lib"
  29. inherit autotools features_check
  30. # depends on virtual/libx11
  31. REQUIRED_DISTRO_FEATURES = "x11"
  32. EXTRA_OECONF = "\
  33. --enable-threads \
  34. --with-x \
  35. --with-tcl=${STAGING_BINDIR}/crossscripts \
  36. --libdir=${libdir} \
  37. "
  38. export TK_LIBRARY='${libdir}/tk${VER}'
  39. do_install_append() {
  40. ln -sf libtk${VER}.so ${D}${libdir}/libtk${VER}.so.0
  41. oe_libinstall -so libtk${VER} ${D}${libdir}
  42. ln -sf wish${VER} ${D}${bindir}/wish
  43. sed -i "s;-L${B};-L${STAGING_LIBDIR};g" tkConfig.sh
  44. sed -i "s;'${WORKDIR};'${STAGING_INCDIR};g" tkConfig.sh
  45. install -d ${D}${bindir_crossscripts}
  46. install -m 0755 tkConfig.sh ${D}${bindir_crossscripts}
  47. }
  48. PACKAGECONFIG ??= "xft"
  49. PACKAGECONFIG[xft] = "--enable-xft,--disable-xft,xft"
  50. PACKAGECONFIG[xss] = "--enable-xss,--disable-xss,libxscrnsaver libxext"
  51. PACKAGES =+ "${PN}-lib"
  52. FILES_${PN}-lib = "${libdir}/libtk${VER}.so*"
  53. FILES_${PN} += "${libdir}/tk*"
  54. # isn't getting picked up by shlibs code
  55. RDEPENDS_${PN} += "tk-lib"
  56. RDEPENDS_${PN}_class-native = ""
  57. BBCLASSEXTEND = "native nativesdk"
  58. # Fix the path in sstate
  59. SSTATE_SCAN_FILES += "*Config.sh"
  60. inherit binconfig
  61. SYSROOT_DIRS += "${bindir_crossscripts}"
  62. # Fix some paths that might be used by Tcl extensions
  63. BINCONFIG_GLOB = "*Config.sh"
  64. # Cleanup host path from ${libdir}/tclConfig.sh and remove the
  65. # ${bindir_crossscripts}/tclConfig.sh from target
  66. PACKAGE_PREPROCESS_FUNCS += "tcl_package_preprocess"
  67. tcl_package_preprocess() {
  68. sed -i -e "s;${DEBUG_PREFIX_MAP};;g" \
  69. -e "s;-L${STAGING_LIBDIR};-L${libdir};g" \
  70. -e "s;${STAGING_INCDIR};${includedir};g" \
  71. -e "s;--sysroot=${RECIPE_SYSROOT};;g" \
  72. ${PKGD}${libdir}/tkConfig.sh
  73. rm -f ${PKGD}${bindir_crossscripts}/tkConfig.sh
  74. }