pcsc-lite_1.8.26.bb 1.8 KB

12345678910111213141516171819202122232425262728293031323334353637383940414243444546474849505152535455565758
  1. SUMMARY = "PC/SC Lite smart card framework and applications"
  2. HOMEPAGE = "http://pcsclite.alioth.debian.org/"
  3. LICENSE = "BSD & GPLv3+"
  4. LICENSE_${PN} = "BSD"
  5. LICENSE_${PN}-lib = "BSD"
  6. LICENSE_${PN}-doc = "BSD"
  7. LICENSE_${PN}-dev = "BSD"
  8. LICENSE_${PN}-dbg = "BSD & GPLv3+"
  9. LICENSE_${PN}-spy = "GPLv3+"
  10. LICENSE_${PN}-spy-dev = "GPLv3+"
  11. LIC_FILES_CHKSUM = "file://COPYING;md5=628c01ba985ecfa21677f5ee2d5202f6"
  12. SRC_URI = "\
  13. https://pcsclite.apdu.fr/files/${BP}.tar.bz2 \
  14. file://0001-pcsc-spy-use-python3-only.patch \
  15. "
  16. SRC_URI[md5sum] = "9d36882998449daceec267c68a21ff0d"
  17. SRC_URI[sha256sum] = "3eb7be7d6ef618c0a444316cf5c1f2f9d7227aedba7a192f389fe3e7c0dfbbd9"
  18. inherit autotools systemd pkgconfig perlnative
  19. EXTRA_OECONF = " \
  20. --disable-libusb \
  21. --enable-usbdropdir=${libdir}/pcsc/drivers \
  22. "
  23. S = "${WORKDIR}/pcsc-lite-${PV}"
  24. PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)} udev"
  25. PACKAGECONFIG_class-native ??= ""
  26. PACKAGECONFIG[systemd] = ",--disable-libsystemd,systemd,"
  27. PACKAGECONFIG[udev] = "--enable-libudev,--disable-libudev,udev"
  28. PACKAGES = "${PN} ${PN}-dbg ${PN}-dev ${PN}-lib ${PN}-doc ${PN}-spy ${PN}-spy-dev"
  29. RRECOMMENDS_${PN} = "ccid"
  30. RRECOMMENDS_${PN}_class-native = ""
  31. FILES_${PN} = "${sbindir}/pcscd"
  32. FILES_${PN}-lib = "${libdir}/libpcsclite*${SOLIBS}"
  33. FILES_${PN}-dev = "${includedir} \
  34. ${libdir}/pkgconfig \
  35. ${libdir}/libpcsclite.la \
  36. ${libdir}/libpcsclite.so"
  37. FILES_${PN}-spy = "${bindir}/pcsc-spy \
  38. ${libdir}/libpcscspy*${SOLIBS}"
  39. FILES_${PN}-spy-dev = "${libdir}/libpcscspy.la \
  40. ${libdir}/libpcscspy.so "
  41. RPROVIDES_${PN} += "${PN}-systemd"
  42. RREPLACES_${PN} += "${PN}-systemd"
  43. RCONFLICTS_${PN} += "${PN}-systemd"
  44. SYSTEMD_SERVICE_${PN} = "pcscd.socket"
  45. RDEPENDS_${PN}-spy +="python3"
  46. BBCLASSEXTEND = "native"