terminus-font_4.49.1.bb 1.6 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445
  1. SUMMARY = "Terminus fonts packages (console and X11)"
  2. DESCRIPTION = "Terminus Font is a clean, fixed width bitmap font, designed for \
  3. long (8 and more hours per day) work with computers."
  4. HOMEPAGE = "http://terminus-font.sourceforge.net/"
  5. AUTHOR = "Dimitar Zhekov"
  6. SECTION = "fonts"
  7. LICENSE = "OFL-1.1"
  8. LIC_FILES_CHKSUM = "file://OFL.TXT;md5=f57e6cca943dbc6ef83dc14f1855bdcc"
  9. DEPENDS = "hostperl-runtime-native gzip-native bdftopcf-native"
  10. SRC_URI = "${SOURCEFORGE_MIRROR}/${BPN}/${BPN}-${PV}.tar.gz"
  11. SRC_URI[md5sum] = "1b6acbd221957e33c8a792ebfaf3a659"
  12. SRC_URI[sha256sum] = "d961c1b781627bf417f9b340693d64fc219e0113ad3a3af1a3424c7aa373ef79"
  13. inherit allarch fontcache
  14. PACKAGECONFIG ?= "${@bb.utils.filter('DISTRO_FEATURES', 'x11', d)}"
  15. PACKAGECONFIG[x11] = ""
  16. # Don't use font cache mecanism for console packages
  17. FONT_PACKAGES = "${@bb.utils.contains('PACKAGECONFIG', 'x11', '${PN}-pcf', '', d)}"
  18. # Hand made configure script. Don't need oe_runconf
  19. do_configure() {
  20. chmod +x ${S}/configure
  21. ${S}/configure --prefix=${prefix} \
  22. --psfdir=${datadir}/consolefonts \
  23. --acmdir=${datadir}/consoletrans \
  24. --x11dir=${datadir}/fonts/terminus
  25. }
  26. do_compile() {
  27. oe_runmake DESTDIR=${D} psf ${@bb.utils.contains('PACKAGECONFIG', 'x11', 'pcf', '', d)}
  28. }
  29. do_install() {
  30. oe_runmake DESTDIR=${D} install-psf ${@bb.utils.contains('PACKAGECONFIG', 'x11', 'install-pcf', '', d)}
  31. }
  32. PACKAGES += "${PN}-consolefonts ${PN}-consoletrans ${PN}-pcf"
  33. FILES_${PN}-consolefonts = "${datadir}/consolefonts"
  34. FILES_${PN}-consoletrans = "${datadir}/consoletrans"
  35. FILES_${PN}-pcf = "${datadir}/fonts/terminus"