collectd_5.2.2.bb 2.8 KB

12345678910111213141516171819202122232425262728293031323334353637383940414243444546474849505152535455565758596061
  1. SUMMARY = "Collects and summarises system performance statistics"
  2. DESCRIPTION = "collectd is a daemon which collects system performance statistics periodically and provides mechanisms to store the values in a variety of ways, for example in RRD files."
  3. LICENSE = "GPLv2"
  4. LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe"
  5. DEPENDS = "rrdtool curl mysql5 libpcap libxml2 yajl libgcrypt libtool"
  6. SRC_URI = "http://collectd.org/files/collectd-${PV}.tar.bz2 \
  7. file://no-gcrypt-badpath.patch \
  8. file://collectd-version.patch \
  9. file://collectd.init"
  10. SRC_URI[md5sum] = "29e61411e51845d5ae71ab676078867e"
  11. SRC_URI[sha256sum] = "7b8906d1c8866155b31820ef108be92abcee7fcd278d386bf0d449e704ba4696"
  12. inherit autotools pythonnative update-rc.d pkgconfig
  13. # Floatingpoint layout, architecture dependent
  14. # 'nothing', 'endianflip' or 'intswap'
  15. FPLAYOUT ?= "--with-fp-layout=nothing"
  16. PACKAGECONFIG ??= ""
  17. PACKAGECONFIG[snmp] = "--enable-snmp,--disable-snmp --with-libnetsnmp=no,net-snmp"
  18. PACKAGECONFIG[libmemcached] = "--with-libmemcached,--without-libmemcached,libmemcached"
  19. PACKAGECONFIG[iptables] = "--enable-iptables,--disable-iptables,iptables"
  20. PACKAGECONFIG[postgresql] = "--enable-postgresql --with-libpq=yes, \
  21. --disable-postgresql --with-libpq=no,postgresql"
  22. PACKAGECONFIG[dbi] = "--enable-dbi,--disable-dbi,libdbi"
  23. PACKAGECONFIG[modbus] = "--enable-modbus,--disable-modbus,libmodbus"
  24. PACKAGECONFIG[libowcapi] = "--with-libowcapi,--without-libowcapi,owfs"
  25. PACKAGECONFIG[sensors] = "--enable-sensors --with-libsensors=yes, \
  26. --disable-sensors --with-libsensors=no,lmsensors"
  27. EXTRA_OECONF = " \
  28. ${FPLAYOUT} \
  29. --disable-perl --with-libperl=no --with-perl-bindings=no \
  30. --with-libgcrypt=${STAGING_BINDIR_CROSS}/libgcrypt-config \
  31. --disable-notify_desktop \
  32. "
  33. do_install_append() {
  34. install -d ${D}${sysconfdir}/init.d
  35. install -m 0755 ${WORKDIR}/collectd.init ${D}${sysconfdir}/init.d/collectd
  36. sed -i 's!/usr/sbin/!${sbindir}/!g' ${D}${sysconfdir}/init.d/collectd
  37. sed -i 's!/etc/!${sysconfdir}/!g' ${D}${sysconfdir}/init.d/collectd
  38. sed -i 's!/var/!${localstatedir}/!g' ${D}${sysconfdir}/init.d/collectd
  39. sed -i 's!^PATH=.*!PATH=${base_sbindir}:${base_bindir}:${sbindir}:${bindir}!' ${D}${sysconfdir}/init.d/collectd
  40. # Fix configuration file to allow collectd to start up
  41. sed -i 's!^#FQDNLookup[ \t]*true!FQDNLookup false!g' ${D}${sysconfdir}/collectd.conf
  42. rmdir "${D}${localstatedir}/run"
  43. rmdir --ignore-fail-on-non-empty "${D}${localstatedir}"
  44. }
  45. INITSCRIPT_NAME = "collectd"
  46. INITSCRIPT_PARAMS = "defaults"
  47. # threshold.so load.so are also provided by gegl
  48. # disk.so is also provided by libgphoto2-camlibs
  49. PRIVATE_LIBS = "threshold.so load.so disk.so"