nss_3.60.bb 8.8 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271
  1. SUMMARY = "Mozilla's SSL and TLS implementation"
  2. DESCRIPTION = "Network Security Services (NSS) is a set of libraries \
  3. designed to support cross-platform development of \
  4. security-enabled client and server applications. \
  5. Applications built with NSS can support SSL v2 and v3, \
  6. TLS, PKCS 5, PKCS 7, PKCS 11, PKCS 12, S/MIME, X.509 \
  7. v3 certificates, and other security standards."
  8. HOMEPAGE = "http://www.mozilla.org/projects/security/pki/nss/"
  9. SECTION = "libs"
  10. DEPENDS = "sqlite3 nspr zlib nss-native"
  11. DEPENDS_class-native = "sqlite3-native nspr-native zlib-native"
  12. LICENSE = "MPL-2.0 | (MPL-2.0 & GPL-2.0+) | (MPL-2.0 & LGPL-2.1+)"
  13. LIC_FILES_CHKSUM = "file://nss/COPYING;md5=3b1e88e1b9c0b5a4b2881d46cce06a18 \
  14. file://nss/lib/freebl/mpi/doc/LICENSE;md5=491f158d09d948466afce85d6f1fe18f \
  15. file://nss/lib/freebl/mpi/doc/LICENSE-MPL;md5=5d425c8f3157dbf212db2ec53d9e5132"
  16. VERSION_DIR = "${@d.getVar('BP').upper().replace('-', '_').replace('.', '_') + '_RTM'}"
  17. SRC_URI = "http://ftp.mozilla.org/pub/mozilla.org/security/nss/releases/${VERSION_DIR}/src/${BP}.tar.gz \
  18. file://nss.pc.in \
  19. file://0001-nss-fix-support-cross-compiling.patch \
  20. file://nss-no-rpath-for-cross-compiling.patch \
  21. file://nss-fix-incorrect-shebang-of-perl.patch \
  22. file://disable-Wvarargs-with-clang.patch \
  23. file://pqg.c-ULL_addend.patch \
  24. file://blank-cert9.db \
  25. file://blank-key4.db \
  26. file://system-pkcs11.txt \
  27. file://nss-fix-nsinstall-build.patch \
  28. file://0001-freebl-add-a-configure-option-to-disable-ARM-HW-cryp.patch \
  29. "
  30. SRC_URI[sha256sum] = "84abd5575ab874c53ae511bd461e5d0868d1a1b384ee40753154cdd1d590fe3d"
  31. UPSTREAM_CHECK_URI = "https://developer.mozilla.org/en-US/docs/Mozilla/Projects/NSS/NSS_Releases"
  32. UPSTREAM_CHECK_REGEX = "NSS_(?P<pver>.+)_release_notes"
  33. inherit siteinfo
  34. TD = "${S}/tentative-dist"
  35. TDS = "${S}/tentative-dist-staging"
  36. # cortex-a55 is ARMv8.2-a based but libatomic explicitly asks for -march=armv8.1-a
  37. # which caused -march conflicts in gcc
  38. TUNE_CCARGS_remove = "-mcpu=cortex-a55+crc -mcpu=cortex-a55 -mcpu=cortex-a55+crc+crypto"
  39. TARGET_CC_ARCH += "${LDFLAGS}"
  40. do_configure_prepend_libc-musl () {
  41. sed -i -e '/-DHAVE_SYS_CDEFS_H/d' ${S}/nss/lib/dbm/config/config.mk
  42. }
  43. do_compile_prepend_class-native() {
  44. export NSPR_INCLUDE_DIR=${STAGING_INCDIR_NATIVE}/nspr
  45. export NSPR_LIB_DIR=${STAGING_LIBDIR_NATIVE}
  46. }
  47. do_compile_prepend_class-nativesdk() {
  48. export LDFLAGS=""
  49. }
  50. do_compile_prepend_class-native() {
  51. # Need to set RPATH so that chrpath will do its job correctly
  52. RPATH="-Wl,-rpath-link,${STAGING_LIBDIR_NATIVE} -Wl,-rpath-link,${STAGING_BASE_LIBDIR_NATIVE} -Wl,-rpath,${STAGING_LIBDIR_NATIVE} -Wl,-rpath,${STAGING_BASE_LIBDIR_NATIVE}"
  53. }
  54. do_compile() {
  55. export NSPR_INCLUDE_DIR=${STAGING_INCDIR}/nspr
  56. export NSS_ENABLE_WERROR=0
  57. export CROSS_COMPILE=1
  58. export NATIVE_CC="${BUILD_CC}"
  59. # Additional defines needed on Centos 7
  60. export NATIVE_FLAGS="${BUILD_CFLAGS} -DLINUX -Dlinux"
  61. export BUILD_OPT=1
  62. export FREEBL_NO_DEPEND=1
  63. export FREEBL_LOWHASH=1
  64. export LIBDIR=${libdir}
  65. export MOZILLA_CLIENT=1
  66. export NS_USE_GCC=1
  67. export NSS_USE_SYSTEM_SQLITE=1
  68. export NSS_ENABLE_ECC=1
  69. ${@bb.utils.contains("TUNE_FEATURES", "crypto", "export NSS_USE_ARM_HW_CRYPTO=1", "", d)}
  70. export OS_RELEASE=3.4
  71. export OS_TARGET=Linux
  72. export OS_ARCH=Linux
  73. if [ "${TARGET_ARCH}" = "powerpc" ]; then
  74. OS_TEST=ppc
  75. elif [ "${TARGET_ARCH}" = "powerpc64" ]; then
  76. OS_TEST=ppc64
  77. elif [ "${TARGET_ARCH}" = "mips" -o "${TARGET_ARCH}" = "mipsel" -o "${TARGET_ARCH}" = "mips64" -o "${TARGET_ARCH}" = "mips64el" ]; then
  78. OS_TEST=mips
  79. elif [ "${TARGET_ARCH}" = "aarch64_be" ]; then
  80. OS_TEST="aarch64"
  81. else
  82. OS_TEST="${TARGET_ARCH}"
  83. fi
  84. if [ "${SITEINFO_BITS}" = "64" ]; then
  85. export USE_64=1
  86. elif [ "${TARGET_ARCH}" = "x86_64" -a "${SITEINFO_BITS}" = "32" ]; then
  87. export USE_X32=1
  88. fi
  89. export NSS_DISABLE_GTESTS=1
  90. # We can modify CC in the environment, but if we set it via an
  91. # argument to make, nsinstall, a host program, will also build with it!
  92. #
  93. # nss pretty much does its own thing with CFLAGS, so we put them into CC.
  94. # Optimization will get clobbered, but most of the stuff will survive.
  95. # The motivation for this is to point to the correct place for debug
  96. # source files and CFLAGS does that. Nothing uses CCC.
  97. #
  98. export CC="${CC} ${CFLAGS}"
  99. make -C ./nss CCC="${CXX} -g" \
  100. OS_TEST=${OS_TEST} \
  101. RPATH="${RPATH}" \
  102. autobuild
  103. }
  104. do_compile[vardepsexclude] += "SITEINFO_BITS"
  105. do_install_prepend_class-nativesdk() {
  106. export LDFLAGS=""
  107. }
  108. do_install() {
  109. export CROSS_COMPILE=1
  110. export NATIVE_CC="${BUILD_CC}"
  111. export BUILD_OPT=1
  112. export FREEBL_NO_DEPEND=1
  113. export LIBDIR=${libdir}
  114. export MOZILLA_CLIENT=1
  115. export NS_USE_GCC=1
  116. export NSS_USE_SYSTEM_SQLITE=1
  117. export NSS_ENABLE_ECC=1
  118. export OS_RELEASE=3.4
  119. export OS_TARGET=Linux
  120. export OS_ARCH=Linux
  121. if [ "${TARGET_ARCH}" = "powerpc" ]; then
  122. OS_TEST=ppc
  123. elif [ "${TARGET_ARCH}" = "powerpc64" ]; then
  124. OS_TEST=ppc64
  125. elif [ "${TARGET_ARCH}" = "mips" -o "${TARGET_ARCH}" = "mipsel" -o "${TARGET_ARCH}" = "mips64" -o "${TARGET_ARCH}" = "mips64el" ]; then
  126. OS_TEST=mips
  127. elif [ "${TARGET_ARCH}" = "aarch64_be" ]; then
  128. CPU_ARCH=aarch64
  129. OS_TEST="aarch64"
  130. else
  131. OS_TEST="${TARGET_ARCH}"
  132. fi
  133. if [ "${SITEINFO_BITS}" = "64" ]; then
  134. export USE_64=1
  135. elif [ "${TARGET_ARCH}" = "x86_64" -a "${SITEINFO_BITS}" = "32" ]; then
  136. export USE_X32=1
  137. fi
  138. export NSS_DISABLE_GTESTS=1
  139. make -C ./nss \
  140. CCC="${CXX}" \
  141. OS_TEST=${OS_TEST} \
  142. SOURCE_LIB_DIR="${TD}/${libdir}" \
  143. SOURCE_BIN_DIR="${TD}/${bindir}" \
  144. install
  145. install -d ${D}/${libdir}/
  146. for file in ${S}/dist/*.OBJ/lib/*.so; do
  147. echo "Installing `basename $file`..."
  148. cp $file ${D}/${libdir}/
  149. done
  150. for shared_lib in ${TD}/${libdir}/*.so.*; do
  151. if [ -f $shared_lib ]; then
  152. cp $shared_lib ${D}/${libdir}
  153. ln -sf $(basename $shared_lib) ${D}/${libdir}/$(basename $shared_lib .1oe)
  154. fi
  155. done
  156. for shared_lib in ${TD}/${libdir}/*.so; do
  157. if [ -f $shared_lib -a ! -e ${D}/${libdir}/$shared_lib ]; then
  158. cp $shared_lib ${D}/${libdir}
  159. fi
  160. done
  161. install -d ${D}/${includedir}/nss3
  162. install -m 644 -t ${D}/${includedir}/nss3 dist/public/nss/*
  163. install -d ${D}/${bindir}
  164. for binary in ${TD}/${bindir}/*; do
  165. install -m 755 -t ${D}/${bindir} $binary
  166. done
  167. }
  168. do_install[vardepsexclude] += "SITEINFO_BITS"
  169. do_install_append() {
  170. # Create empty .chk files for the NSS libraries at build time. They could
  171. # be regenerated at target's boot time.
  172. for file in libsoftokn3.chk libfreebl3.chk libnssdbm3.chk; do
  173. touch ${D}/${libdir}/$file
  174. chmod 755 ${D}/${libdir}/$file
  175. done
  176. install -d ${D}${libdir}/pkgconfig/
  177. sed 's/%NSS_VERSION%/${PV}/' ${WORKDIR}/nss.pc.in | sed 's/%NSPR_VERSION%/4.9.2/' > ${D}${libdir}/pkgconfig/nss.pc
  178. sed -i s:OEPREFIX:${prefix}:g ${D}${libdir}/pkgconfig/nss.pc
  179. sed -i s:OEEXECPREFIX:${exec_prefix}:g ${D}${libdir}/pkgconfig/nss.pc
  180. sed -i s:OELIBDIR:${libdir}:g ${D}${libdir}/pkgconfig/nss.pc
  181. sed -i s:OEINCDIR:${includedir}/nss3:g ${D}${libdir}/pkgconfig/nss.pc
  182. }
  183. do_install_append_class-target() {
  184. # It used to call certutil to create a blank certificate with empty password at
  185. # build time, but the checksum of key4.db changes every time when certutil is called.
  186. # It causes non-determinism issue, so provide databases with a blank certificate
  187. # which are originally from output of nss in qemux86-64 build. You can get these
  188. # databases by:
  189. # certutil -N -d sql:/database/path/ --empty-password
  190. install -d ${D}${sysconfdir}/pki/nssdb/
  191. install -m 0644 ${WORKDIR}/blank-cert9.db ${D}${sysconfdir}/pki/nssdb/cert9.db
  192. install -m 0644 ${WORKDIR}/blank-key4.db ${D}${sysconfdir}/pki/nssdb/key4.db
  193. install -m 0644 ${WORKDIR}/system-pkcs11.txt ${D}${sysconfdir}/pki/nssdb/pkcs11.txt
  194. }
  195. PACKAGE_WRITE_DEPS += "nss-native"
  196. pkg_postinst_${PN} () {
  197. for I in $D${libdir}/lib*.chk; do
  198. DN=`dirname $I`
  199. BN=`basename $I .chk`
  200. FN=$DN/$BN.so
  201. shlibsign -i $FN
  202. if [ $? -ne 0 ]; then
  203. echo "shlibsign -i $FN failed"
  204. fi
  205. done
  206. }
  207. PACKAGES =+ "${PN}-smime"
  208. FILES_${PN}-smime = "\
  209. ${bindir}/smime \
  210. "
  211. FILES_${PN} = "\
  212. ${sysconfdir} \
  213. ${bindir} \
  214. ${libdir}/lib*.chk \
  215. ${libdir}/lib*.so \
  216. "
  217. FILES_${PN}-dev = "\
  218. ${libdir}/nss \
  219. ${libdir}/pkgconfig/* \
  220. ${includedir}/* \
  221. "
  222. RDEPENDS_${PN}-smime = "perl"
  223. BBCLASSEXTEND = "native nativesdk"