squid_3.5.20.bb 3.1 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081
  1. SUMMARY = "A fully-featured http proxy and web-cache daemon for Linux"
  2. DESCRIPTION = "A fully-featured http proxy and web-cache daemon for Linux. \
  3. Squid offers a rich access control, authorization and logging environment to \
  4. develop web proxy and content serving applications. \
  5. Squid offers a rich set of traffic optimization options, most of which are \
  6. enabled by default for simpler installation and high performance. \
  7. "
  8. HOMEPAGE = "http://www.squid-cache.org"
  9. SECTION = "web"
  10. LICENSE = "GPLv2+"
  11. MAJ_VER = "${@oe.utils.trim_version("${PV}", 1)}"
  12. MIN_VER = "${@oe.utils.trim_version("${PV}", 2)}"
  13. SRC_URI = "http://www.squid-cache.org/Versions/v${MAJ_VER}/${MIN_VER}/${BPN}-${PV}.tar.bz2 \
  14. file://Set-up-for-cross-compilation.patch \
  15. file://Skip-AC_RUN_IFELSE-tests.patch \
  16. file://Fix-flawed-dynamic-ldb-link-test-in-configure.patch \
  17. file://squid-use-serial-tests-config-needed-by-ptest.patch \
  18. file://run-ptest \
  19. file://volatiles.03_squid \
  20. file://set_sysroot_patch.patch \
  21. "
  22. LIC_FILES_CHKSUM = "file://COPYING;md5=c492e2d6d32ec5c1aad0e0609a141ce9 \
  23. file://errors/COPYRIGHT;md5=0d98c4448c368d146f31a970bb0ced21 \
  24. "
  25. SRC_URI[md5sum] = "6a29d7dfc544205001f7a75c6996dc60"
  26. SRC_URI[sha256sum] = "5a114f8f7f44b5ae3c9b77d7b81aef13fe69e7f530855213d551f48b157cb5f1"
  27. DEPENDS = "libtool krb5 openldap db cyrus-sasl"
  28. inherit autotools useradd ptest
  29. USERADD_PACKAGES = "${PN}"
  30. USERADD_PARAM_${PN} = "--system --no-create-home --home-dir /var/run/squid --shell /bin/false --user-group squid"
  31. PACKAGECONFIG ??= "${@bb.utils.contains('TARGET_ARCH', 'powerpc', 'noatomics', '', d)} \
  32. ${@bb.utils.contains('TARGET_ARCH', 'mips', 'noatomics', '', d)} \
  33. "
  34. PACKAGECONFIG[libnetfilter-conntrack] = "--with-netfilter-conntrack=${includedir}, --without-netfilter-conntrack, libnetfilter-conntrack"
  35. PACKAGECONFIG[noatomics] = "squid_cv_gnu_atomics=no,squid_cv_gnu_atomics=yes,,"
  36. BASIC_AUTH = "DB SASL LDAP NIS"
  37. DEPENDS += "${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'libpam', '', d)}"
  38. BASIC_AUTH += "${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'PAM', '', d)}"
  39. EXTRA_OECONF += "--with-default-user=squid --enable-auth-basic='${BASIC_AUTH}'"
  40. export BUILDCXXFLAGS="${BUILD_CXXFLAGS}"
  41. TESTDIR = "test-suite"
  42. do_configure_prepend() {
  43. export SYSROOT=$PKG_CONFIG_SYSROOT_DIR
  44. }
  45. do_compile_ptest() {
  46. oe_runmake -C ${TESTDIR} buildtest-TESTS
  47. }
  48. do_install_ptest() {
  49. cp -rf ${B}/${TESTDIR} ${D}${PTEST_PATH}
  50. cp -rf ${S}/${TESTDIR} ${D}${PTEST_PATH}
  51. # do NOT need to rebuild Makefile itself
  52. sed -i 's/^Makefile:.*$/Makefile:/' ${D}${PTEST_PATH}/${TESTDIR}/Makefile
  53. }
  54. do_install_append() {
  55. install -d ${D}${sysconfdir}/default/volatiles
  56. install -m 0644 ${WORKDIR}/volatiles.03_squid ${D}${sysconfdir}/default/volatiles/volatiles.03_squid
  57. rmdir "${D}${localstatedir}/run/${BPN}"
  58. rmdir --ignore-fail-on-non-empty "${D}${localstatedir}/run"
  59. }
  60. FILES_${PN} += "${libdir} ${datadir}/errors ${datadir}/icons"
  61. FILES_${PN}-dbg += "/usr/src/debug"
  62. FILES_${PN}-doc += "${datadir}/*.txt"
  63. RDEPENDS_${PN} += "perl"
  64. RDEPENDS_${PN}-ptest += "make"