cyrus-sasl_2.1.26.bb 3.7 KB

1234567891011121314151617181920212223242526272829303132333435363738394041424344454647484950515253545556575859606162636465666768697071727374757677787980818283848586878889909192939495
  1. SUMMARY = "Generic client/server library for SASL authentication"
  2. SECTION = "libs"
  3. DEPENDS = "openssl virtual/db"
  4. LICENSE = "BSD"
  5. LIC_FILES_CHKSUM = "file://COPYING;md5=3f55e0974e3d6db00ca6f57f2d206396"
  6. SRC_URI = "ftp://ftp.cyrusimap.org/cyrus-sasl/cyrus-sasl-${PV}.tar.gz \
  7. file://avoid-to-call-AC_TRY_RUN.patch \
  8. file://Fix-hardcoded-libdir.patch \
  9. file://debian_patches_0009_sasldb_al.diff \
  10. file://debian_patches_0014_avoid_pic_overwrite.diff \
  11. file://sasl.h-include-stddef.h-for-size_t-on-NetBSD.patch \
  12. file://saslauthd.service \
  13. file://saslauthd.conf \
  14. "
  15. inherit autotools-brokensep pkgconfig useradd systemd
  16. EXTRA_OECONF += "--with-dblib=berkeley \
  17. --with-bdb-libdir=${STAGING_LIBDIR} \
  18. --with-bdb-incdir=${STAGING_INCDIR} \
  19. --with-bdb=db-5.3 \
  20. --with-plugindir="${libdir}/sasl2" \
  21. andrew_cv_runpath_switch=none"
  22. PACKAGECONFIG ??= "ntlm \
  23. ${@bb.utils.contains('DISTRO_FEATURES', 'ldap', 'ldap', '', d)} \
  24. ${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'pam', '', d)} \
  25. "
  26. PACKAGECONFIG[gssapi] = "--enable-gssapi=yes,--enable-gssapi=no,krb5,"
  27. PACKAGECONFIG[pam] = "--with-pam,--without-pam,libpam,"
  28. PACKAGECONFIG[opie] = "--with-opie,--without-opie,opie,"
  29. PACKAGECONFIG[des] = "--with-des,--without-des,,"
  30. PACKAGECONFIG[ldap] = "--with-ldap=${STAGING_LIBDIR} --enable-ldapdb,--without-ldap --disable-ldapdb,openldap,"
  31. PACKAGECONFIG[ntlm] = "--with-ntlm,--without-ntlm,,"
  32. CFLAGS += "-fPIC"
  33. do_configure_prepend () {
  34. rm -f acinclude.m4 config/libtool.m4
  35. # make it be able to work with db 5.0 version
  36. local sed_files="sasldb/db_berkeley.c utils/dbconverter-2.c"
  37. for sed_file in $sed_files; do
  38. sed -i 's#DB_VERSION_MAJOR == 4.*#(&) || DB_VERSION_MAJOR == 5#' $sed_file
  39. done
  40. }
  41. do_compile_prepend () {
  42. cd include
  43. ${BUILD_CC} ${BUILD_CFLAGS} ${BUILD_LDFLAGS} makemd5.c -o makemd5
  44. touch makemd5.o makemd5.lo makemd5
  45. cd ..
  46. }
  47. do_install_append() {
  48. if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then
  49. install -d ${D}${systemd_unitdir}/system
  50. install -m 0644 ${WORKDIR}/saslauthd.service ${D}${systemd_unitdir}/system
  51. sed -i -e 's#@SBINDIR@#${sbindir}#g' ${D}${systemd_unitdir}/system/saslauthd.service
  52. sed -i -e 's#@LOCALSTATEDIR@#${localstatedir}#g' ${D}${systemd_unitdir}/system/saslauthd.service
  53. sed -i -e 's#@SYSCONFDIR@#${sysconfdir}#g' ${D}${systemd_unitdir}/system/saslauthd.service
  54. install -d ${D}${sysconfdir}/tmpfiles.d
  55. echo "d /run/saslauthd/ - - - -" > ${D}${sysconfdir}/tmpfiles.d/saslauthd.conf
  56. install -d ${D}${sysconfdir}/default/
  57. install -m 0644 ${WORKDIR}/saslauthd.conf ${D}${sysconfdir}/default/saslauthd
  58. sed -i -e 's#@LOCALSTATEDIR@#${localstatedir}#g' ${D}${sysconfdir}/default/saslauthd
  59. fi
  60. }
  61. USERADD_PACKAGES = "${PN}-bin"
  62. USERADD_PARAM_${PN}-bin = "--system --home=/var/spool/mail -g mail cyrus"
  63. SYSTEMD_PACKAGES = "${PN}"
  64. SYSTEMD_SERVICE_${PN} = "saslauthd.service"
  65. SYSTEMD_AUTO_ENABLE = "disable"
  66. SRC_URI[md5sum] = "a7f4e5e559a0e37b3ffc438c9456e425"
  67. SRC_URI[sha256sum] = "8fbc5136512b59bb793657f36fadda6359cae3b08f01fd16b3d406f1345b7bc3"
  68. PACKAGES =+ "${PN}-bin"
  69. FILES_${PN} += "${libdir}/sasl2/*.so*"
  70. FILES_${PN}-bin += "${bindir} \
  71. ${sysconfdir}/default/saslauthd \
  72. ${systemd_unitdir}/system/saslauthd.service \
  73. ${sysconfdir}/tmpfiles.d/saslauthd.conf"
  74. FILES_${PN}-dev += "${libdir}/sasl2/*.la"
  75. FILES_${PN}-dbg += "${libdir}/sasl2/.debug"
  76. FILES_${PN}-staticdev += "${libdir}/sasl2/*.a"
  77. INSANE_SKIP_${PN} += "dev-so"