evolution-data-server.bb 2.2 KB

1234567891011121314151617181920212223242526272829303132333435363738394041424344454647484950515253545556575859606162636465666768697071
  1. require ${BPN}.inc
  2. DEPENDS = " \
  3. ${BPN}-native intltool-native gperf-native \
  4. glib-2.0 gtk+3 libgdata \
  5. dbus db virtual/libiconv zlib libsoup-2.4 libical nss libsecret \
  6. "
  7. inherit gsettings gobject-introspection features_check cmake gtk-doc gettext perlnative
  8. REQUIRED_DISTRO_FEATURES = "x11"
  9. SRC_URI += " \
  10. file://0001-CMakeLists.txt-Remove-TRY_RUN-for-iconv.patch \
  11. file://0002-CMakeLists.txt-remove-CHECK_C_SOURCE_RUNS-check.patch \
  12. file://0003-contact-Replace-the-Novell-sample-contact-with-somet.patch \
  13. file://0004-call-native-helpers.patch \
  14. file://iconv-detect.h \
  15. "
  16. LKSTRFTIME = "HAVE_LKSTRFTIME=ON"
  17. LKSTRFTIME_libc-musl = "HAVE_LKSTRFTIME=OFF"
  18. # For arm qemu-arm runs at 100% CPU load and never returns - so disable introspection for now
  19. GI_DATA_ENABLED="False"
  20. EXTRA_OECMAKE = " \
  21. -DSYSCONF_INSTALL_DIR=${sysconfdir} \
  22. -DWITH_KRB5=OFF \
  23. -DENABLE_GOA=OFF \
  24. -DENABLE_UOA=OFF \
  25. -DENABLE_GOOGLE_AUTH=OFF \
  26. -DENABLE_WEATHER=OFF \
  27. -DENABLE_GOOGLE=OFF \
  28. -DENABLE_INTROSPECTION=${@bb.utils.contains('GI_DATA_ENABLED', 'True', 'ON', 'OFF', d)} \
  29. -D${LKSTRFTIME} \
  30. -DLIB_SUFFIX=${@d.getVar('baselib').replace('lib', '')} \
  31. "
  32. PACKAGECONFIG[canberra] = "-DENABLE_CANBERRA=ON,-DENABLE_CANBERRA=OFF,libcanberra"
  33. PACKAGECONFIG[oauth] = "-DENABLE_OAUTH2=ON,-DENABLE_OAUTH2=OFF,webkitgtk json-glib"
  34. # BROKEN: due missing pkg-config in openldap eds' cmake finds host-libs when
  35. # searching for openldap-libs
  36. PACKAGECONFIG[openldap] = "-DWITH_OPENLDAP=ON,-DWITH_OPENLDAP=OFF,openldap"
  37. # -ldb needs this on some platforms
  38. LDFLAGS += "-lpthread -lgmodule-2.0 -lgthread-2.0"
  39. do_configure_append () {
  40. cp ${WORKDIR}/iconv-detect.h ${S}/src
  41. # fix native perl shebang
  42. sed -i 's:${STAGING_BINDIR_NATIVE}/perl-native:${bindir}:' ${B}/src/tools/addressbook-export/csv2vcard
  43. # fix abs path for g-ir-scanner-wrapper
  44. sed -i ${B}/build.ninja \
  45. -e 's: ${bindir}/g-ir-scanner-wrapper: ${STAGING_BINDIR}/g-ir-scanner-wrapper:g'
  46. }
  47. do_compile_prepend() {
  48. export GIR_EXTRA_LIBS_PATH="${B}/camel/.libs:${B}/libedataserver/.libs"
  49. }
  50. FILES_${PN} =+ " \
  51. ${datadir}/dbus-1 \
  52. ${datadir}/evolution-data-server-*/ui/ \
  53. ${systemd_user_unitdir} \
  54. "
  55. RDEPENDS_${PN} += "perl"