emacs.inc 6.3 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147
  1. DESCRIPTION = "Emacs"
  2. HOMEPAGE = "http://www.gnu.org/software/emacs/"
  3. LICENSE = "GPLv3"
  4. LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
  5. SECTION = "editor"
  6. # and it needs to run some generated binaries..
  7. DEPENDS += "qemu-native"
  8. DEPENDS +=" liblockfile"
  9. X11DEPENDS = " \
  10. libice libsm atk cairo dbus expat libffi fontconfig freetype gconf giflib \
  11. jpeg xz pixman libpng librsvg tiff libcroco \
  12. libx11 libxau libxcomposite libxcursor libxdamage libxdmcp libxext libxfixes \
  13. libxft libxpm libxrandr libxrender \
  14. gdk-pixbuf glib-2.0 gtk+ pango libxcb harfbuzz icu \
  15. "
  16. EXTRA_OECONF = "--without-sound --with-crt-dir=${STAGING_LIBDIR} "
  17. PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'x11', d)}"
  18. PACKAGECONFIG[x11] = "--with-x-toolkit=gtk,--without-x --without-dbus,${X11DEPENDS}"
  19. inherit autotools
  20. PACKAGES =+ "${PN}-el"
  21. FILES_${PN}-el = "${datadir}/emacs/*/*/*.el.gz \
  22. ${datadir}/emacs/*/*/*/*.el.gz"
  23. FILES_${PN} += "${datadir}/emacs ${datadir}/icons"
  24. FILES_${PN}-dbg += "${libexecdir}/emacs/*/*/.debug ${datadir}/emacs/*/*/.debug"
  25. TREEDIR = "${WORKDIR}/qemu-treedir"
  26. QEMUARCH= "${TARGET_ARCH}"
  27. QEMUARCH_x86 = "i386"
  28. # Large stack is required at least on x86_64 host, otherwise random segfaults appear:
  29. QEMU = "qemu-${QEMUARCH} ${QEMU_OPTIONS} -s 1048576 -L ${TREEDIR} "
  30. export LOGNAME = "$(whoami)"
  31. do_compile_prepend() {
  32. sed -i ':1;s:\(START.* \|LIB_STANDARD.* \|LIBES.* \)/usr/lib:\1${STAGING_LIBDIR}:;t1' ${S}/src/s/gnu-linux.h `find "${S}" -name Makefile`
  33. export LD_LIBRARY_PATH="$LD_LIBRARY_PATH:${TOOLCHAIN_PATH}/${TARGET_SYS}/lib"
  34. # Ugly hack, see files/use-qemu.patch for more:
  35. ln -sf ../src/emacs lisp/emacs
  36. ln -sf ../src/emacs lib-src/emacs
  37. ln -sf ../src/emacs leim/emacs
  38. #copy STAGING_DIR_TARGET and libgcc_s.so* to WORKDIR/qemu-treedir #copied code from glibc-package.bbclass
  39. treedir=${TREEDIR}
  40. if [ -e $treedir ];then
  41. rm -rf $treedir
  42. fi
  43. mkdir -p $treedir/${base_libdir}
  44. if [ -f ${TOOLCHAIN_PATH}/${TARGET_SYS}/${base_libdir}/libgcc_s.so ]; then
  45. cp -pPR ${TOOLCHAIN_PATH}/${TARGET_SYS}/${base_libdir}/libgcc_s.so $treedir/${base_libdir}
  46. fi
  47. if [ -f ${TOOLCHAIN_PATH}/${TARGET_SYS}/${base_libdir}/libgcc_s.so.* ]; then
  48. cp -pPR ${TOOLCHAIN_PATH}/${TARGET_SYS}/${base_libdir}/libgcc_s.so.* $treedir/${base_libdir}
  49. fi
  50. # stupid hack, but without it, it tries to use /usr/lib/libc.so from host and fails
  51. # temacs: error while loading shared libraries: /usr/lib/libc.so: ELF file version does not match current one
  52. if [ ! -f $treedir/${base_libdir}/libc.so ]; then
  53. ln -s libc.so.6 $treedir/${base_libdir}/libc.so
  54. fi
  55. # copy only as much stuff as we need
  56. # before: 5.5G ../../qemu-treedir/
  57. # after: 17M ../../qemu-treedir/
  58. cp -pPR \
  59. ${STAGING_DIR_TARGET}/${base_libdir}/ld-* \
  60. ${STAGING_DIR_TARGET}/${base_libdir}/libc.* \
  61. ${STAGING_DIR_TARGET}/${base_libdir}/libc-* \
  62. ${STAGING_DIR_TARGET}/${base_libdir}/libm-* \
  63. ${STAGING_DIR_TARGET}/${base_libdir}/libm.* \
  64. ${STAGING_DIR_TARGET}/${base_libdir}/libtinfo.so.* \
  65. ${STAGING_DIR_TARGET}/${base_libdir}/libresolv* \
  66. ${STAGING_DIR_TARGET}/${base_libdir}/libdl* \
  67. ${STAGING_DIR_TARGET}/${base_libdir}/librt* \
  68. ${STAGING_DIR_TARGET}/${base_libdir}/libgcc_s.so.* \
  69. ${STAGING_DIR_TARGET}/${base_libdir}/libpthread* $treedir/${base_libdir}/
  70. if [ ! -z "${@bb.utils.filter('PACKAGECONFIG', 'x11', d)}" ]; then
  71. echo "X11 build enabled"
  72. # copy only as much stuff as we need
  73. # before: 5.5G ../../qemu-treedir/
  74. # after: 86M ../../qemu-treedir/
  75. cp -pPR \
  76. ${STAGING_DIR_TARGET}/${base_libdir}/libuuid.so.* \
  77. ${STAGING_DIR_TARGET}/${base_libdir}/libz.so.* \
  78. ${STAGING_DIR_TARGET}/${libdir}/libICE.so.* \
  79. ${STAGING_DIR_TARGET}/${libdir}/libSM.so.* \
  80. ${STAGING_DIR_TARGET}/${libdir}/libatk-1.0.so.* \
  81. ${STAGING_DIR_TARGET}/${libdir}/libcairo.so.* \
  82. ${STAGING_DIR_TARGET}/${libdir}/libdbus-1.so.* \
  83. ${STAGING_DIR_TARGET}/${libdir}/libdbus-glib-1.so.* \
  84. ${STAGING_DIR_TARGET}/${libdir}/libexpat.so.* \
  85. ${STAGING_DIR_TARGET}/${libdir}/libffi.so.* \
  86. ${STAGING_DIR_TARGET}/${libdir}/libfontconfig.so.* \
  87. ${STAGING_DIR_TARGET}/${libdir}/libfreetype.so.* \
  88. ${STAGING_DIR_TARGET}/${libdir}/libgconf-2.so.* \
  89. ${STAGING_DIR_TARGET}/${libdir}/libgif.so.* \
  90. ${STAGING_DIR_TARGET}/${libdir}/libjpeg.so.* \
  91. ${STAGING_DIR_TARGET}/${libdir}/liblzma.so.* \
  92. ${STAGING_DIR_TARGET}/${libdir}/libpixman-1.so.* \
  93. ${STAGING_DIR_TARGET}/${libdir}/libpng1*.so.* \
  94. ${STAGING_DIR_TARGET}/${libdir}/librsvg-2.so.* \
  95. ${STAGING_DIR_TARGET}/${libdir}/libstdc++.so.* \
  96. ${STAGING_DIR_TARGET}/${libdir}/libtiff.so.* \
  97. ${STAGING_DIR_TARGET}/${libdir}/libxml2.so.* \
  98. ${STAGING_DIR_TARGET}/${libdir}/libcroco-0.6.so.* \
  99. ${STAGING_DIR_TARGET}/${libdir}/libharfbuzz.so.* \
  100. ${STAGING_DIR_TARGET}/${libdir}/libicule.so.* \
  101. ${STAGING_DIR_TARGET}/${libdir}/libicuuc.so.* \
  102. ${STAGING_DIR_TARGET}/${libdir}/libicudata.so.* $treedir/${base_libdir}/
  103. # X11 Xau Xcomposite Xcursor Xdamage Xdmcp Xext Xfixes Xft Xpm Xrandr Xrender
  104. cp -pPR ${STAGING_DIR_TARGET}/${libdir}/libX*.so.* $treedir/${base_libdir}/
  105. # gdk-x11 gdk_pixbuf gio glib gmodule gobject gthread gtk-x11
  106. cp -pPR ${STAGING_DIR_TARGET}/${libdir}/libg*-2.0.so.* $treedir/${base_libdir}/
  107. # pango pangocairo pangoft2
  108. cp -pPR ${STAGING_DIR_TARGET}/${libdir}/libpango*-1.0.so.* $treedir/${base_libdir}/
  109. # xcb-render xcb-shm xcb
  110. cp -pPR ${STAGING_DIR_TARGET}/${libdir}/libxcb*.so.* $treedir/${base_libdir}/
  111. fi
  112. }
  113. do_install_append() {
  114. # freaks package.bbclass and whole bitbake call returns error code
  115. # ERROR: runstrip: ''arm-oe-linux-gnueabi-strip' '/var/lib/jenkins/jobs/shr-core-branches/workspace/shr-core/tmp-eglibc/work/armv4t-oe-linux-gnueabi/emacs-23.4-r0/package/usr/share/emacs/23.4/etc/tutorials/TUTORIAL.ko'' strip command failed
  116. mv ${D}${datadir}/${BPN}/${PV}/etc/tutorials/TUTORIAL.ko ${D}${datadir}/${BPN}/${PV}/etc/tutorials/TUTORIAL.KO
  117. # Info dir listing isn't interesting at this point so remove it if it exists.
  118. if [ -e "${D}${infodir}/dir" ]; then
  119. rm -f ${D}${infodir}/dir
  120. fi
  121. }
  122. EXTRA_OEMAKE += 'QEMU="${QEMU}"'