net-snmp_5.7.3.bb 7.4 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184
  1. SUMMARY = "Various tools relating to the Simple Network Management Protocol"
  2. HOMEPAGE = "http://www.net-snmp.org/"
  3. SECTION = "net"
  4. LICENSE = "BSD"
  5. LIC_FILES_CHKSUM = "file://README;beginline=3;endline=8;md5=7f7f00ba639ac8e8deb5a622ea24634e"
  6. DEPENDS = "openssl libnl pciutils"
  7. SRC_URI = "${SOURCEFORGE_MIRROR}/net-snmp/net-snmp-${PV}.zip \
  8. file://init \
  9. file://snmpd.conf \
  10. file://snmptrapd.conf \
  11. file://systemd-support.patch \
  12. file://snmpd.service \
  13. file://snmptrapd.service \
  14. file://net-snmp-add-knob-whether-nlist.h-are-checked.patch \
  15. file://fix-libtool-finish.patch \
  16. file://net-snmp-testing-add-the-output-format-for-ptest.patch \
  17. file://run-ptest \
  18. file://dont-return-incompletely-parsed-varbinds.patch \
  19. file://0001-config_os_headers-Error-Fix.patch \
  20. file://0001-config_os_libs2-Error-Fix.patch \
  21. file://0001-snmplib-keytools.c-Don-t-check-for-return-from-EVP_M.patch \
  22. file://net-snmp-agentx-crash.patch \
  23. file://0001-get_pid_from_inode-Include-limit.h.patch \
  24. file://0001-BUG-a2584-Fix-snmptrap-to-use-clientaddr-from-snmp.c.patch \
  25. file://0001-snmplib-UDPIPv6-transport-Add-a-missing-return-state.patch \
  26. "
  27. SRC_URI[md5sum] = "9f682bd70c717efdd9f15b686d07baee"
  28. SRC_URI[sha256sum] = "e8dfc79b6539b71a6ff335746ce63d2da2239062ad41872fff4354cafed07a3e"
  29. inherit autotools update-rc.d siteinfo systemd pkgconfig
  30. EXTRA_OEMAKE = "INSTALL_PREFIX=${D} OTHERLDFLAGS='${LDFLAGS}' HOST_CPPFLAGS='${BUILD_CPPFLAGS}'"
  31. PARALLEL_MAKE = ""
  32. CCACHE = ""
  33. TARGET_CC_ARCH += "${LDFLAGS}"
  34. PACKAGECONFIG ??= ""
  35. PACKAGECONFIG[elfutils] = "--with-elf, --without-elf, elfutils"
  36. PACKAGECONFIG[libnl] = "--with-nl, --without-nl, libnl"
  37. PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'ipv6', d)}"
  38. PACKAGECONFIG[ipv6] = "--enable-ipv6,--disable-ipv6,,"
  39. EXTRA_OECONF = "--disable-embedded-perl \
  40. --with-perl-modules=no \
  41. --disable-manuals \
  42. --with-defaults \
  43. --with-install-prefix=${D} \
  44. --with-persistent-directory=${localstatedir}/lib/net-snmp \
  45. ${@base_conditional('SITEINFO_ENDIANNESS', 'le', '--with-endianness=little', '--with-endianness=big', d)}"
  46. # net-snmp needs to have mib-modules=smux enabled to enable quagga to support snmp
  47. EXTRA_OECONF += "--with-mib-modules=smux"
  48. CACHED_CONFIGUREVARS = " \
  49. ac_cv_header_valgrind_valgrind_h=no \
  50. ac_cv_header_valgrind_memcheck_h=no \
  51. ac_cv_ETC_MNTTAB=/etc/mtab \
  52. lt_cv_shlibpath_overrides_runpath=yes \
  53. "
  54. do_configure_prepend() {
  55. export PERLPROG="${bindir}/env perl"
  56. sed -i -e "s|I/usr/include|I${STAGING_INCDIR}|g" \
  57. "${S}"/configure \
  58. "${S}"/configure.d/config_os_libs2
  59. }
  60. do_install_append() {
  61. install -d ${D}${sysconfdir}/snmp
  62. install -d ${D}${sysconfdir}/init.d
  63. install -m 755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/snmpd
  64. install -m 644 ${WORKDIR}/snmpd.conf ${D}${sysconfdir}/snmp/
  65. install -m 644 ${WORKDIR}/snmptrapd.conf ${D}${sysconfdir}/snmp/
  66. install -d ${D}${systemd_unitdir}/system
  67. install -m 0644 ${WORKDIR}/snmpd.service ${D}${systemd_unitdir}/system
  68. install -m 0644 ${WORKDIR}/snmptrapd.service ${D}${systemd_unitdir}/system
  69. sed -e "s@^NSC_SRCDIR=.*@NSC_SRCDIR=.@g" \
  70. -i ${D}${bindir}/net-snmp-create-v3-user
  71. sed -e "s@^NSC_SRCDIR=.*@NSC_SRCDIR=.@g" \
  72. -i ${D}${bindir}/net-snmp-config
  73. }
  74. do_install_ptest() {
  75. install -d ${D}${PTEST_PATH}
  76. for i in ${S}/dist ${S}/include ${B}/include ${S}/mibs ${S}/configure \
  77. ${B}/net-snmp-config ${S}/testing; do
  78. if [ -e "$i" ]; then
  79. cp -R --no-dereference --preserve=mode,links -v "$i" ${D}${PTEST_PATH}
  80. fi
  81. done
  82. echo `autoconf -V|awk '/autoconf/{print $NF}'` > ${D}${PTEST_PATH}/dist/autoconf-version
  83. rmdlist="${D}${PTEST_PATH}/dist/net-snmp-solaris-build"
  84. for i in $rmdlist; do
  85. if [ -d "$i" ]; then
  86. rm -rf "$i"
  87. fi
  88. done
  89. }
  90. SYSROOT_PREPROCESS_FUNCS += "net_snmp_sysroot_preprocess"
  91. net_snmp_sysroot_preprocess () {
  92. if [ -e ${D}${bindir}/net-snmp-config ]; then
  93. install -d ${SYSROOT_DESTDIR}${bindir_crossscripts}/
  94. install -m 755 ${D}${bindir}/net-snmp-config ${SYSROOT_DESTDIR}${bindir_crossscripts}/
  95. sed -e "s@-I/usr/include@-I${STAGING_INCDIR}@g" \
  96. -e "s@^prefix=.*@prefix=${STAGING_DIR_HOST}${prefix}@g" \
  97. -e "s@^exec_prefix=.*@exec_prefix=${STAGING_EXECPREFIXDIR}@g" \
  98. -e "s@^includedir=.*@includedir=${STAGING_INCDIR}@g" \
  99. -e "s@^libdir=.*@libdir=${STAGING_LIBDIR}@g" \
  100. -e "s@^NSC_SRCDIR=.*@NSC_SRCDIR=${S}@g" \
  101. -i ${SYSROOT_DESTDIR}${bindir_crossscripts}/net-snmp-config
  102. fi
  103. }
  104. PACKAGES += "${PN}-libs ${PN}-mibs ${PN}-server ${PN}-client ${PN}-server-snmpd ${PN}-server-snmptrapd"
  105. ALLOW_EMPTY_${PN} = "1"
  106. ALLOW_EMPTY_${PN}-server = "1"
  107. FILES_${PN}-libs = "${libdir}/lib*${SOLIBS}"
  108. FILES_${PN}-mibs = "${datadir}/snmp/mibs"
  109. FILES_${PN}-server-snmpd = "${sbindir}/snmpd \
  110. ${sysconfdir}/snmp/snmpd.conf \
  111. ${sysconfdir}/init.d \
  112. ${systemd_unitdir}/system/snmpd.service \
  113. "
  114. FILES_${PN}-server-snmptrapd = "${sbindir}/snmptrapd \
  115. ${sysconfdir}/snmp/snmptrapd.conf \
  116. ${systemd_unitdir}/system/snmptrapd.service \
  117. "
  118. FILES_${PN} = ""
  119. FILES_${PN}-client = "${bindir}/* ${datadir}/snmp/"
  120. FILES_${PN}-dbg += "${libdir}/.debug/ ${sbindir}/.debug/ ${bindir}/.debug/"
  121. FILES_${PN}-dev += "${bindir}/mib2c ${bindir}/mib2c-update"
  122. CONFFILES_${PN}-server-snmpd = "${sysconfdir}/snmp/snmpd.conf"
  123. CONFFILES_${PN}-server-snmptrapd = "${sysconfdir}/snmp/snmptrapd.conf"
  124. INITSCRIPT_PACKAGES = "${PN}-server-snmpd"
  125. INITSCRIPT_NAME_${PN}-server-snmpd = "snmpd"
  126. INITSCRIPT_PARAMS_${PN}-server-snmpd = "start 90 2 3 4 5 . stop 60 0 1 6 ."
  127. EXTRA_OECONF += "${@bb.utils.contains('DISTRO_FEATURES', 'systemd', '--with-systemd', '--without-systemd', d)}"
  128. SYSTEMD_PACKAGES = "${PN}-server-snmpd \
  129. ${PN}-server-snmptrapd"
  130. SYSTEMD_SERVICE_${PN}-server-snmpd = "snmpd.service"
  131. SYSTEMD_SERVICE_${PN}-server-snmptrapd = "snmptrapd.service"
  132. RDEPENDS_${PN} += "net-snmp-client"
  133. RDEPENDS_${PN}-server-snmpd += "net-snmp-mibs"
  134. RDEPENDS_${PN}-server-snmptrapd += "net-snmp-server-snmpd"
  135. RDEPENDS_${PN}-server += "net-snmp-server-snmpd net-snmp-server-snmptrapd"
  136. RDEPENDS_${PN}-client += "net-snmp-mibs"
  137. RDEPENDS_${PN}-ptest += "perl \
  138. perl-module-test \
  139. perl-module-file-basename \
  140. perl-module-getopt-long \
  141. perl-module-file-temp \
  142. perl-module-data-dumper \
  143. "
  144. RDEPENDS_${PN}-dev = "net-snmp-client (= ${EXTENDPKGV}) net-snmp-server (= ${EXTENDPKGV})"
  145. RRECOMMENDS_${PN}-dbg = "net-snmp-client (= ${EXTENDPKGV}) net-snmp-server (= ${EXTENDPKGV})"
  146. RPROVIDES_${PN}-server-snmpd += "${PN}-server-snmpd-systemd"
  147. RREPLACES_${PN}-server-snmpd += "${PN}-server-snmpd-systemd"
  148. RCONFLICTS_${PN}-server-snmpd += "${PN}-server-snmpd-systemd"
  149. RPROVIDES_${PN}-server-snmptrapd += "${PN}-server-snmptrapd-systemd"
  150. RREPLACES_${PN}-server-snmptrapd += "${PN}-server-snmptrapd-systemd"
  151. RCONFLICTS_${PN}-server-snmptrapd += "${PN}-server-snmptrapd-systemd"
  152. LEAD_SONAME = "libnetsnmp.so"