inetutils_1.9.4.bb 7.9 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198
  1. DESCRIPTION = "The GNU inetutils are a collection of common \
  2. networking utilities and servers including ftp, ftpd, rcp, \
  3. rexec, rlogin, rlogind, rsh, rshd, syslog, syslogd, talk, \
  4. talkd, telnet, telnetd, tftp, tftpd, and uucpd."
  5. HOMEPAGE = "http://www.gnu.org/software/inetutils"
  6. SECTION = "net"
  7. DEPENDS = "ncurses netbase readline"
  8. LICENSE = "GPLv3"
  9. LIC_FILES_CHKSUM = "file://COPYING;md5=0c7051aef9219dc7237f206c5c4179a7"
  10. SRC_URI = "${GNU_MIRROR}/inetutils/inetutils-${PV}.tar.gz \
  11. file://version.patch \
  12. file://inetutils-1.8-0001-printf-parse-pull-in-features.h-for-__GLIBC__.patch \
  13. file://inetutils-1.8-0003-wchar.patch \
  14. file://rexec.xinetd.inetutils \
  15. file://rlogin.xinetd.inetutils \
  16. file://rsh.xinetd.inetutils \
  17. file://telnet.xinetd.inetutils \
  18. file://tftpd.xinetd.inetutils \
  19. file://inetutils-1.9-PATH_PROCNET_DEV.patch \
  20. file://inetutils-only-check-pam_appl.h-when-pam-enabled.patch \
  21. file://0001-rcp-fix-to-work-with-large-files.patch \
  22. "
  23. SRC_URI[md5sum] = "04852c26c47cc8c6b825f2b74f191f52"
  24. SRC_URI[sha256sum] = "be8f75eff936b8e41b112462db51adf689715658a1b09e0d6b05d11ec92cc616"
  25. inherit autotools gettext update-alternatives texinfo
  26. acpaths = "-I ./m4"
  27. SRC_URI += "${@bb.utils.contains('DISTRO_FEATURES', 'ipv6', '', 'file://fix-disable-ipv6.patch', d)}"
  28. PACKAGECONFIG ??= "ftp uucpd \
  29. ${@bb.utils.filter('DISTRO_FEATURES', 'pam', d)} \
  30. ${@bb.utils.contains('DISTRO_FEATURES', 'ipv6', 'ipv6 ping6', '', d)} \
  31. "
  32. PACKAGECONFIG[ftp] = "--enable-ftp,--disable-ftp,readline"
  33. PACKAGECONFIG[uucpd] = "--enable-uucpd,--disable-uucpd,readline"
  34. PACKAGECONFIG[pam] = "--with-pam,--without-pam,libpam"
  35. PACKAGECONFIG[ipv6] = "--enable-ipv6,--disable-ipv6 gl_cv_socket_ipv6=no,"
  36. PACKAGECONFIG[ping6] = "--enable-ping6,--disable-ping6,"
  37. EXTRA_OECONF = "--with-ncurses-include-dir=${STAGING_INCDIR} \
  38. inetutils_cv_path_login=${base_bindir}/login \
  39. --with-libreadline-prefix=${STAGING_LIBDIR} \
  40. --enable-rpath=no \
  41. "
  42. EXTRA_OECONF_append_libc-musl = " --disable-rsh --disable-rcp --disable-rlogin "
  43. do_configure_prepend () {
  44. export HELP2MAN='true'
  45. cp ${STAGING_DATADIR_NATIVE}/gettext/config.rpath ${S}/build-aux/config.rpath
  46. rm -f ${S}/glob/configure*
  47. }
  48. do_install_append () {
  49. install -m 0755 -d ${D}${base_bindir}
  50. install -m 0755 -d ${D}${base_sbindir}
  51. install -m 0755 -d ${D}${sbindir}
  52. install -m 0755 -d ${D}${sysconfdir}/xinetd.d
  53. mv ${D}${bindir}/ping* ${D}${base_bindir}/
  54. mv ${D}${bindir}/ifconfig ${D}${base_sbindir}/
  55. mv ${D}${libexecdir}/syslogd ${D}${base_sbindir}/
  56. mv ${D}${bindir}/hostname ${D}${base_bindir}/
  57. mv ${D}${libexecdir}/tftpd ${D}${sbindir}/in.tftpd
  58. mv ${D}${libexecdir}/telnetd ${D}${sbindir}/in.telnetd
  59. mv ${D}${libexecdir}/rexecd ${D}${sbindir}/in.rexecd
  60. if [ -e ${D}${libexecdir}/rlogind ]; then
  61. mv ${D}${libexecdir}/rlogind ${D}${sbindir}/in.rlogind
  62. fi
  63. if [ -e ${D}${libexecdir}/rshd ]; then
  64. mv ${D}${libexecdir}/rshd ${D}${sbindir}/in.rshd
  65. fi
  66. if [ -e ${D}${libexecdir}/talkd ]; then
  67. mv ${D}${libexecdir}/talkd ${D}${sbindir}/in.talkd
  68. fi
  69. mv ${D}${libexecdir}/uucpd ${D}${sbindir}/in.uucpd
  70. mv ${D}${libexecdir}/* ${D}${bindir}/
  71. cp ${WORKDIR}/rexec.xinetd.inetutils ${D}/${sysconfdir}/xinetd.d/rexec
  72. cp ${WORKDIR}/rlogin.xinetd.inetutils ${D}/${sysconfdir}/xinetd.d/rlogin
  73. cp ${WORKDIR}/rsh.xinetd.inetutils ${D}/${sysconfdir}/xinetd.d/rsh
  74. cp ${WORKDIR}/telnet.xinetd.inetutils ${D}/${sysconfdir}/xinetd.d/telnet
  75. cp ${WORKDIR}/tftpd.xinetd.inetutils ${D}/${sysconfdir}/xinetd.d/tftpd
  76. sed -e 's,@SBINDIR@,${sbindir},g' -i ${D}/${sysconfdir}/xinetd.d/*
  77. if [ -e ${D}${libdir}/charset.alias ]; then
  78. rm -rf ${D}${libdir}/charset.alias
  79. fi
  80. rm -rf ${D}${libexecdir}/
  81. # remove usr/lib if empty
  82. rmdir ${D}${libdir} || true
  83. }
  84. PACKAGES =+ "${PN}-ping ${PN}-ping6 ${PN}-hostname ${PN}-ifconfig \
  85. ${PN}-tftp ${PN}-logger ${PN}-traceroute ${PN}-syslogd \
  86. ${PN}-ftp ${PN}-ftpd ${PN}-tftpd ${PN}-telnet ${PN}-telnetd ${PN}-inetd \
  87. ${PN}-rsh ${PN}-rshd"
  88. # The packages tftpd, telnetd and rshd conflict with the ones
  89. # provided by netkit, so add the corresponding -dbg packages
  90. # for them to avoid the confliction between the dbg package
  91. # of inetutils and netkit.
  92. PACKAGES =+ "${PN}-tftpd-dbg ${PN}-telnetd-dbg ${PN}-rshd-dbg"
  93. NOAUTOPACKAGEDEBUG = "1"
  94. ALTERNATIVE_PRIORITY = "80"
  95. ALTERNATIVE_${PN} = "talk whois"
  96. ALTERNATIVE_LINK_NAME[talkd] = "${sbindir}/in.talkd"
  97. ALTERNATIVE_LINK_NAME[uucpd] = "${sbindir}/in.uucpd"
  98. ALTERNATIVE_PRIORITY_${PN}-logger = "60"
  99. ALTERNATIVE_${PN}-logger = "logger"
  100. ALTERNATIVE_${PN}-syslogd = "syslogd"
  101. ALTERNATIVE_LINK_NAME[syslogd] = "${base_sbindir}/syslogd"
  102. ALTERNATIVE_${PN}-ftp = "ftp"
  103. ALTERNATIVE_${PN}-ftpd = "ftpd"
  104. ALTERNATIVE_${PN}-tftp = "tftp"
  105. ALTERNATIVE_${PN}-tftpd = "tftpd"
  106. ALTERNATIVE_LINK_NAME[tftpd] = "${sbindir}/tftpd"
  107. ALTERNATIVE_TARGET[tftpd] = "${sbindir}/in.tftpd"
  108. ALTERNATIVE_${PN}-telnet = "telnet"
  109. ALTERNATIVE_${PN}-telnetd = "telnetd"
  110. ALTERNATIVE_LINK_NAME[telnetd] = "${sbindir}/telnetd"
  111. ALTERNATIVE_TARGET[telnetd] = "${sbindir}/in.telnetd"
  112. ALTERNATIVE_${PN}-rsh = "rcp rexec rlogin rsh"
  113. ALTERNATIVE_${PN}-rshd = "rshd rexecd rlogind"
  114. ALTERNATIVE_LINK_NAME[rshd] = "${sbindir}/rshd"
  115. ALTERNATIVE_TARGET[rshd] = "${sbindir}/in.rshd"
  116. ALTERNATIVE_LINK_NAME[rexecd] = "${sbindir}/rexecd"
  117. ALTERNATIVE_TARGET[rexecd] = "${sbindir}/in.rexecd"
  118. ALTERNATIVE_LINK_NAME[rlogind] = "${sbindir}/rlogind"
  119. ALTERNATIVE_TARGET[rlogind] = "${sbindir}/in.rlogind"
  120. ALTERNATIVE_${PN}-inetd= "inetd"
  121. ALTERNATIVE_${PN}-traceroute = "traceroute"
  122. ALTERNATIVE_${PN}-hostname = "hostname"
  123. ALTERNATIVE_LINK_NAME[hostname] = "${base_bindir}/hostname"
  124. ALTERNATIVE_${PN}-doc = "hostname.1"
  125. ALTERNATIVE_LINK_NAME[hostname.1] = "${mandir}/man1/hostname.1"
  126. ALTERNATIVE_${PN}-ifconfig = "ifconfig"
  127. ALTERNATIVE_LINK_NAME[ifconfig] = "${base_sbindir}/ifconfig"
  128. ALTERNATIVE_${PN}-ping = "ping"
  129. ALTERNATIVE_LINK_NAME[ping] = "${base_bindir}/ping"
  130. ALTERNATIVE_${PN}-ping6 = "${@bb.utils.filter('PACKAGECONFIG', 'ping6', d)}"
  131. ALTERNATIVE_LINK_NAME[ping6] = "${base_bindir}/ping6"
  132. FILES_${PN}-dbg += "${base_bindir}/.debug ${base_sbindir}/.debug ${bindir}/.debug ${sbindir}/.debug"
  133. FILES_${PN}-ping = "${base_bindir}/ping.${BPN}"
  134. FILES_${PN}-ping6 = "${base_bindir}/ping6.${BPN}"
  135. FILES_${PN}-hostname = "${base_bindir}/hostname.${BPN}"
  136. FILES_${PN}-ifconfig = "${base_sbindir}/ifconfig.${BPN}"
  137. FILES_${PN}-traceroute = "${bindir}/traceroute.${BPN}"
  138. FILES_${PN}-logger = "${bindir}/logger.${BPN}"
  139. FILES_${PN}-syslogd = "${base_sbindir}/syslogd.${BPN}"
  140. FILES_${PN}-ftp = "${bindir}/ftp.${BPN}"
  141. FILES_${PN}-tftp = "${bindir}/tftp.${BPN}"
  142. FILES_${PN}-telnet = "${bindir}/telnet.${BPN}"
  143. FILES_${PN}-rsh = "${bindir}/rsh.${BPN} ${bindir}/rlogin.${BPN} ${bindir}/rexec.${BPN} ${bindir}/rcp.${BPN}"
  144. FILES_${PN}-rshd = "${sbindir}/in.rshd ${sbindir}/in.rlogind ${sbindir}/in.rexecd \
  145. ${sysconfdir}/xinetd.d/rsh ${sysconfdir}/xinetd.d/rlogin ${sysconfdir}/xinetd.d/rexec"
  146. FILES_${PN}-rshd-dbg = "${sbindir}/.debug/in.rshd ${sbindir}/.debug/in.rlogind ${sbindir}/.debug/in.rexecd"
  147. RDEPENDS_${PN}-rshd += "xinetd tcp-wrappers"
  148. RCONFLICTS_${PN}-rshd += "netkit-rshd"
  149. RPROVIDES_${PN}-rshd = "rshd"
  150. FILES_${PN}-ftpd = "${bindir}/ftpd.${BPN}"
  151. FILES_${PN}-ftpd-dbg = "${bindir}/.debug/ftpd.${BPN}"
  152. RDEPENDS_${PN}-ftpd += "xinetd"
  153. FILES_${PN}-tftpd = "${sbindir}/in.tftpd ${sysconfdir}/xinetd.d/tftpd"
  154. FILES_${PN}-tftpd-dbg = "${sbindir}/.debug/in.tftpd"
  155. RCONFLICTS_${PN}-tftpd += "netkit-tftpd"
  156. RDEPENDS_${PN}-tftpd += "xinetd"
  157. FILES_${PN}-telnetd = "${sbindir}/in.telnetd ${sysconfdir}/xinetd.d/telnet"
  158. FILES_${PN}-telnetd-dbg = "${sbindir}/.debug/in.telnetd"
  159. RCONFLICTS_${PN}-telnetd += "netkit-telnetd"
  160. RPROVIDES_${PN}-telnetd = "telnetd"
  161. RDEPENDS_${PN}-telnetd += "xinetd"
  162. FILES_${PN}-inetd = "${bindir}/inetd.${BPN}"
  163. RDEPENDS_${PN} = "xinetd"