lcdproc5.inc 2.7 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081
  1. DESCRIPTION = "LCDproc is a client/server suite to drive all kinds of LCD (-like) devices. The client \
  2. shipped with this package can be used to acquire various kinds of system stats."
  3. SUMMARY = "Drivers for character-based LCD displays"
  4. HOMEPAGE = "http://lcdproc.org"
  5. SECTION = "utils"
  6. LICENSE = "GPLv2+"
  7. DEPENDS = "ncurses"
  8. LIC_FILES_CHKSUM = "file://COPYING;md5=18810669f13b87348459e611d31ab760 \
  9. file://README;beginline=60;md5=637e042cdd3671ba00e78b58ede45d3b"
  10. SRC_URI = "${SOURCEFORGE_MIRROR}/lcdproc/${BP}.tar.gz"
  11. inherit autotools update-rc.d
  12. LCD_DRIVERS ?= "all"
  13. LCD_DEFAULT_DRIVER ?= "curses"
  14. PACKAGECONFIG ??= "usb"
  15. PACKAGECONFIG[usb] = "--enable-libusb,--disable-libusb,virtual/libusb0"
  16. PACKAGECONFIG[ftdi] = "--enable-libftdi,--disable-libftdi,libftdi"
  17. EXTRA_OECONF = "--enable-drivers=${LCD_DRIVERS}"
  18. do_install () {
  19. # binaries
  20. install -D -m 0755 server/LCDd ${D}${sbindir}/LCDd
  21. install -D -m 0755 clients/lcdproc/lcdproc ${D}${bindir}/lcdproc
  22. # init scripts
  23. install -d ${D}${sysconfdir}/init.d
  24. # so far, not fixed :-( and now even uglier :-((
  25. cat scripts/init-LCDd.debian | sed -e s'/--oknodo//' -e 's/ -s -f / -s 1 -f 1 /' -e 's/force-reload/force-restart/' -e 's/sleep 1/sleep 4/' > ${D}${sysconfdir}/init.d/lcdd
  26. chmod 0755 ${D}${sysconfdir}/init.d/lcdd
  27. install -m 0755 scripts/init-lcdproc.debian ${D}${sysconfdir}/init.d/lcdproc
  28. sed -i s'/--oknodo//' ${D}${sysconfdir}/init.d/lcdproc
  29. # configuration files
  30. install -m 0644 ${S}/LCDd.conf ${D}${sysconfdir}/LCDd.conf
  31. sed -i 's!^DriverPath=.*!DriverPath=${libdir}/lcdproc/!' ${D}${sysconfdir}/LCDd.conf
  32. sed -i 's!^Driver=.*!Driver=${LCD_DEFAULT_DRIVER}!' ${D}${sysconfdir}/LCDd.conf
  33. install -m 0644 ${S}/clients/lcdproc/lcdproc.conf ${D}${sysconfdir}/lcdproc.conf
  34. # driver library files
  35. install -d ${D}${libdir}/lcdproc
  36. for i in server/drivers/*.so; do
  37. install -m 0644 $i ${D}${libdir}/lcdproc/
  38. done
  39. }
  40. PACKAGES =+ "lcdd"
  41. RRECOMMENDS_${PN} = "lcdd"
  42. FILES_lcdd = "${sysconfdir}/LCDd.conf \
  43. ${sbindir}/LCDd \
  44. ${sysconfdir}/init.d/lcdd"
  45. CONFFILES_lcdd = "${sysconfdir}/LCDd.conf"
  46. CONFFILES_${PN} = "${sysconfdir}/lcdproc.conf"
  47. # Driver packages
  48. # USB / no USB trickery
  49. RCONFLICTS_lcdd-driver-hd47780nousb = "lcdd-driver-hd44780"
  50. RCONFLICTS_lcdd-driver-hd47780 = "lcdd-driver-hd44780nousb"
  51. INITSCRIPT_PACKAGES = "lcdd lcdproc"
  52. INITSCRIPT_NAME_lcdd = "lcdd"
  53. INITSCRIPT_NAME_lcdproc = "lcdproc"
  54. INITSCRIPT_PARAMS_lcdd = "defaults 70 21"
  55. INITSCRIPT_PARAMS_lcdproc = "defaults 71 20"
  56. python populate_packages_prepend() {
  57. plugindir = d.expand('${libdir}/lcdproc')
  58. do_split_packages(d, plugindir, '(.*)\.so$', 'lcdd-driver-%s', 'LCDd driver for %s', prepend=True)
  59. }
  60. PACKAGES_DYNAMIC += "^lcdd-driver-.*"