tcmode-external.inc 6.7 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139
  1. # Configuration to use external Sourcery G++ toolchain
  2. EXTERNAL_TOOLCHAIN ??= "UNKNOWN"
  3. EXTERNAL_TARGET_SYS ??= "${TARGET_ARCH}-${TARGET_OS}"
  4. EXTERNAL_TOOLCHAIN_BIN ??= "${EXTERNAL_TOOLCHAIN}/bin"
  5. # External toolchain features.
  6. #
  7. # locale-utf8-is-default: assume en_US is utf8, not en_US.UTF-8, as is the
  8. # case for OE.
  9. EXTERNAL_TOOLCHAIN_FEATURES ?= ""
  10. python () {
  11. oe.utils.features_backfill("EXTERNAL_TOOLCHAIN_FEATURES", d)
  12. }
  13. # Prefer our recipes which extract files from the external toolchain
  14. PREFERRED_PROVIDER_virtual/${TARGET_PREFIX}gcc ?= "gcc-external-cross-${TARGET_ARCH}"
  15. PREFERRED_PROVIDER_virtual/${TARGET_PREFIX}gcc-intermediate ?= "gcc-external-cross-${TARGET_ARCH}"
  16. PREFERRED_PROVIDER_virtual/${TARGET_PREFIX}g++ ?= "gcc-external-cross-${TARGET_ARCH}"
  17. PREFERRED_PROVIDER_virtual/${TARGET_PREFIX}binutils ?= "binutils-external-cross-${TARGET_ARCH}"
  18. PREFERRED_PROVIDER_virtual/${TARGET_PREFIX}compilerlibs ?= "gcc-runtime-external"
  19. PREFERRED_PROVIDER_gcc-runtime = "gcc-runtime-external"
  20. PREFERRED_PROVIDER_gcc-sanitizers ?= "gcc-sanitizers-external"
  21. PREFERRED_PROVIDER_libgcc-initial = "libgcc-external"
  22. PREFERRED_PROVIDER_libnsl2 = "libnsl2"
  23. PREFERRED_PROVIDER_libtirpc = "libtirpc"
  24. # PREFERRED_PROVIDER_libgfortran = "libgfortran-external"
  25. PREFERRED_PROVIDER_glibc ?= "glibc-external"
  26. PREFERRED_PROVIDER_virtual/libc ?= "glibc-external"
  27. PREFERRED_PROVIDER_virtual/libintl ?= "glibc-external"
  28. PREFERRED_PROVIDER_virtual/libiconv ?= "glibc-external"
  29. PREFERRED_PROVIDER_virtual/crypt ?= "libxcrypt"
  30. PREFERRED_PROVIDER_gdb-cross-${TARGET_ARCH} ?= "gdb-external-cross-${TARGET_ARCH}"
  31. PREFERRED_PROVIDER_oprofile ??= "oprofile"
  32. # Work around bug where the implicitly created mlprefix preference isn't being
  33. # obeyed for the runtime package installation.
  34. PREFERRED_PROVIDER_${MLPREFIX}gdbserver ?= "${MLPREFIX}gdb"
  35. # This is defined in default-providers.inc, which is parsed before the tcmode,
  36. # so we can't use ?=
  37. PREFERRED_PROVIDER_linux-libc-headers = "glibc-external"
  38. PNBLACKLIST[linux-libc-headers] = "not building with an external toolchain"
  39. PNBLACKLIST[linux-libc-headers-yocto] = "not building with an external toolchain"
  40. PREFERRED_PROVIDER_gcc-cross-canadian-${TRANSLATED_TARGET_ARCH} ??= "gcc-external-cross-canadian-${TRANSLATED_TARGET_ARCH}"
  41. PREFERRED_PROVIDER_binutils-cross-canadian-${TRANSLATED_TARGET_ARCH} ??= "binutils-external-cross-canadian-${TRANSLATED_TARGET_ARCH}"
  42. PREFERRED_PROVIDER_gdb-cross-canadian-${TRANSLATED_TARGET_ARCH} ??= "gdb-external-cross-canadian-${TRANSLATED_TARGET_ARCH}"
  43. # This is defined in default-providers.inc, which is parsed before the tcmode,
  44. # so we can't use ?=
  45. PREFERRED_PROVIDER_libgcc = "libgcc-external"
  46. # Pass --no-sysroot-suffix when using an external toolchain with the SDK
  47. TOOLCHAIN_TARGET_TASK_append = " sdk-env-external-toolchain"
  48. # Sanity check the toolchain configuration and toolchain
  49. INHERIT += "sanity-external-toolchain"
  50. # Pull in our utility functions for use elsewhere
  51. INHERIT += "external-common"
  52. # Ensure that we don't pull in any internal toolchain recipes
  53. INHERIT += "blacklist blacklist_dynamic"
  54. PNBLACKLIST[uclibc] = "not building with an external toolchain"
  55. PNBLACKLIST[glibc] = "not building with an external toolchain"
  56. PNBLACKLIST[glibc-intermediate] = "not building with an external toolchain"
  57. PNBLACKLIST[gcc-runtime] = "not building with an external toolchain"
  58. PNBLACKLIST[gcc-sanitizers] = "not building with an external toolchain"
  59. PNBLACKLIST[gcc-source] = "not building with an external toolchain"
  60. PNBLACKLIST[libgcc-initial] = "not building with an external toolchain"
  61. PNBLACKLIST[libgcc] = "not building with an external toolchain"
  62. PNBLACKLIST[libgfortran] = "not building with an external toolchain"
  63. PNBLACKLIST_DYNAMIC += "\
  64. ${MLPREFIX}gcc-cross-${TARGET_ARCH} \
  65. \
  66. binutils-cross-canadian-${TRANSLATED_TARGET_ARCH} \
  67. gcc-cross-canadian-${TRANSLATED_TARGET_ARCH} \
  68. gdb-cross-canadian-${TRANSLATED_TARGET_ARCH} \
  69. \
  70. gcc-source-${@'${GCCVERSION}'.replace('%', '')} \
  71. "
  72. # We need our -cross recipes to rebuild when the external toolchain changes,
  73. # to recreate the links / wrapper scripts
  74. BB_HASHBASE_WHITELIST_remove = "EXTERNAL_TOOLCHAIN"
  75. # For a toolchain built with multilibs, we don't want any suffix implicitly
  76. # added to the oe sysroot path, as those dirs will not exist.
  77. # TOOLCHAIN_OPTIONS would seem more appropriate, but that gets added to LD as
  78. # well, and --no-sysroot-suffix only works for gcc, not binutils.
  79. HOST_CC_ARCH += "--no-sysroot-suffix"
  80. # Certain recipes call ld directly, so ensure the correct emulation is used,
  81. # particularly for multilib toolchains, since we can't rely on the default
  82. LDEMULATION = ""
  83. LDEMULATION_ENDIAN = "${@'bt' if 'bigendian' in '${TUNE_FEATURES}'.split() else 'lt'}"
  84. LDEMULATION_BITS = "${@'64' if 'n64' in '${TUNE_FEATURES}'.split() else '32'}"
  85. LDEMULATION_mips64 = "elf${LDEMULATION_BITS}${LDEMULATION_ENDIAN}smip${@bb.utils.contains('TUNE_FEATURES', 'n32', 'n32', '', d)}"
  86. LDEMULATION_x86-64 = "elf_${TARGET_ARCH}"
  87. LDEMULATION_x86-64_linux-gnux32 = "elf32_${TARGET_ARCH}"
  88. TUNE_LDARGS += "${@'-m ${LDEMULATION}' if '${LDEMULATION}' else ''}"
  89. # Additional search path for compiler component programs, to let us rebuild
  90. # binutils if necessary.
  91. gcc_bindir = "${STAGING_BINDIR_TOOLCHAIN}/gcc"
  92. TUNE_CCARGS .= "${@' -B${gcc_bindir}' if d.getVar('PREFERRED_PROVIDER_virtual/${TARGET_PREFIX}binutils') != 'binutils-external-cross-${TARGET_ARCH}' else ''}"
  93. # Align the external toolchain ldflags with the internal
  94. TARGET_LDFLAGS_BUILD_ID = "-Wl,--build-id=sha1"
  95. TARGET_LDFLAGS += "${TARGET_LDFLAGS_BUILD_ID}"
  96. TCMODEOVERRIDES = "tcmode-external"
  97. TCMODEOVERRIDES_append = ":tcmode-${TCMODE}"
  98. OVERRIDES =. "${TCMODEOVERRIDES}:"
  99. python toolchain_metadata_setup () {
  100. # The external toolchain may not have been built with the yocto preferred
  101. # gnu hash setting, so ensure that the corresponding sanity check is a
  102. # warning, not an error.
  103. error_qa = (d.getVar('ERROR_QA', True) or '').split()
  104. if 'ldflags' in error_qa:
  105. error_qa.remove('ldflags')
  106. d.setVar('ERROR_QA', ' '.join(error_qa))
  107. d.appendVar('WARN_QA', ' ldflags')
  108. }
  109. toolchain_metadata_setup[eventmask] = "bb.event.ConfigParsed"
  110. addhandler toolchain_metadata_setup
  111. GCCVERSION ?= "${@'.'.join('${GCC_VERSION}'.split('.')[:2])}%"
  112. GCC_VERSION = "${@external_run(d, 'gcc', '-dumpversion').rstrip()}"
  113. GCC_VERSION_allarch = ""
  114. GCC_VERSION[vardepvalue] = "${GCC_VERSION}"
  115. # macro-prefix-map was introduced in gcc 8
  116. REMOVE_MACRO_PREFIX_MAP = "-fmacro-prefix-map=${WORKDIR}=/usr/src/debug/${PN}/${EXTENDPE}${PV}-${PR}"
  117. DEBUG_PREFIX_MAP_remove_class-target = "${@'${REMOVE_MACRO_PREFIX_MAP}' if '${GCC_VERSION}' not in ['', 'UNKNOWN'] and [int(v) for v in '${GCC_VERSION}'.split('.')] < [8,0] else ''}"
  118. BUILDCFG_VARS += "EXTERNAL_TOOLCHAIN EXTERNAL_TARGET_SYS GCC_VERSION"