gcc-runtime-external.bb 3.8 KB

1234567891011121314151617181920212223242526272829303132333435363738394041424344454647484950515253545556575859606162636465666768697071727374757677787980818283848586878889909192939495969798
  1. PV = "${GCC_VERSION}"
  2. BINV = "${GCC_VERSION}"
  3. require recipes-devtools/gcc/gcc-runtime.inc
  4. inherit external-toolchain
  5. # GCC >4.2 is GPLv3
  6. DEPENDS = "libgcc"
  7. EXTRA_OECONF = ""
  8. COMPILERDEP = ""
  9. python () {
  10. lic_deps = d.getVarFlag('do_populate_lic', 'depends', False)
  11. d.setVarFlag('do_populate_lic', 'depends', lic_deps.replace('gcc-source-${PV}:do_unpack', ''))
  12. cfg_deps = d.getVarFlag('do_configure', 'depends', False)
  13. d.setVarFlag('do_configure', 'depends', cfg_deps.replace('gcc-source-${PV}:do_preconfigure', ''))
  14. }
  15. target_libdir = "${libdir}"
  16. HEADERS_MULTILIB_SUFFIX ?= "${@external_run(d, 'gcc', *('${TARGET_CC_ARCH}'.split() + ['-print-sysroot-headers-suffix'])).rstrip()}"
  17. external_libroot = "${@os.path.realpath('${EXTERNAL_TOOLCHAIN_LIBROOT}').replace(os.path.realpath('${EXTERNAL_TOOLCHAIN}') + '/', '/')}"
  18. FILES_MIRRORS =. "\
  19. ${libdir}/gcc/${TARGET_SYS}/${BINV}/|${external_libroot}/\n \
  20. ${libdir}/gcc/${TARGET_SYS}/${BINV}/include/|/lib/gcc/${EXTERNAL_TARGET_SYS}/${BINV}/include/ \n \
  21. ${libdir}/gcc/${TARGET_SYS}/|${libdir}/gcc/${EXTERNAL_TARGET_SYS}/\n \
  22. ${@'${includedir}/c\+\+/${GCC_VERSION}/${TARGET_SYS}/|${includedir}/c++/${GCC_VERSION}/${EXTERNAL_TARGET_SYS}${HEADERS_MULTILIB_SUFFIX}/\n' if d.getVar('HEADERS_MULTILIB_SUFFIX') != 'UNKNOWN' else ''} \
  23. ${includedir}/c\+\+/${GCC_VERSION}/${TARGET_SYS}/|${includedir}/c++/${GCC_VERSION}/${EXTERNAL_TARGET_SYS}/\n \
  24. "
  25. # The do_install_append in gcc-runtime.inc doesn't do well if the links
  26. # already exist, as it causes a recursion that breaks traversal.
  27. python () {
  28. adjusted = d.getVar('do_install_appended').replace('ln -s', 'link_if_no_dest')
  29. adjusted = adjusted.replace('mkdir', 'mkdir_if_no_dest')
  30. d.setVar('do_install_appended', adjusted)
  31. }
  32. link_if_no_dest () {
  33. if ! [ -e "$2" ] && ! [ -L "$2" ]; then
  34. ln -s "$1" "$2"
  35. fi
  36. }
  37. mkdir_if_no_dest () {
  38. if ! [ -e "$1" ] && ! [ -L "$1" ]; then
  39. mkdir "$1"
  40. fi
  41. }
  42. do_install_extra () {
  43. if [ "${TARGET_SYS}" != "${EXTERNAL_TARGET_SYS}" ]; then
  44. if [ -e "${D}${includedir}/c++/${GCC_VERSION}/${EXTERNAL_TARGET_SYS}" ]; then
  45. if ! [ -e "${D}${includedir}/c++/${GCC_VERSION}/${TARGET_SYS}" ]; then
  46. mv -v "${D}${includedir}/c++/${GCC_VERSION}/${EXTERNAL_TARGET_SYS}/." "${D}${includedir}/c++/${GCC_VERSION}/${TARGET_SYS}/"
  47. fi
  48. fi
  49. fi
  50. # Clear out the unused c++ header multilibs
  51. multilib="${HEADERS_MULTILIB_SUFFIX}"
  52. if [ "$multilib" != "UNKNOWN" ]; then
  53. for path in ${D}${includedir}/c++/${GCC_VERSION}/${TARGET_SYS}/*; do
  54. case ${path##*/} in
  55. ${multilib#/})
  56. mv -v "$path/"* "${D}${includedir}/c++/${GCC_VERSION}/${TARGET_SYS}/"
  57. ;;
  58. esac
  59. rm -rfv "$path"
  60. done
  61. fi
  62. }
  63. FILES_${PN}-dbg += "${datadir}/gdb/python/libstdcxx"
  64. FILES_libstdc++-dev = "\
  65. ${includedir}/c++ \
  66. ${libdir}/libstdc++.so \
  67. ${libdir}/libstdc++.la \
  68. ${libdir}/libsupc++.la \
  69. "
  70. FILES_libgomp-dev += "\
  71. ${libdir}/gcc/${TARGET_SYS}/${BINV}/include/openacc.h \
  72. "
  73. BBCLASSEXTEND = ""
  74. # gcc-runtime needs libc, but glibc's utilities need libssp in some cases, so
  75. # short-circuit the interdependency here by manually specifying it rather than
  76. # depending on the libc packagedata.
  77. libc_rdep = "${@'${PREFERRED_PROVIDER_virtual/libc}' if '${PREFERRED_PROVIDER_virtual/libc}' else '${TCLIBC}'}"
  78. RDEPENDS_libgomp += "${libc_rdep}"
  79. RDEPENDS_libssp += "${libc_rdep}"
  80. RDEPENDS_libstdc++ += "${libc_rdep}"
  81. RDEPENDS_libatomic += "${libc_rdep}"
  82. RDEPENDS_libquadmath += "${libc_rdep}"
  83. RDEPENDS_libmpx += "${libc_rdep}"
  84. do_package_write_ipk[depends] += "virtual/${MLPREFIX}libc:do_packagedata"
  85. do_package_write_deb[depends] += "virtual/${MLPREFIX}libc:do_packagedata"
  86. do_package_write_rpm[depends] += "virtual/${MLPREFIX}libc:do_packagedata"