NGbzero.S 3.4 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161
  1. /* SPDX-License-Identifier: GPL-2.0 */
  2. /* NGbzero.S: Niagara optimized memset/clear_user.
  3. *
  4. * Copyright (C) 2006 David S. Miller (davem@davemloft.net)
  5. */
  6. #include <asm/asi.h>
  7. #define EX_ST(x,y) \
  8. 98: x,y; \
  9. .section __ex_table,"a";\
  10. .align 4; \
  11. .word 98b, __retl_o1_asi;\
  12. .text; \
  13. .align 4;
  14. .text
  15. .globl NGmemset
  16. .type NGmemset, #function
  17. NGmemset: /* %o0=buf, %o1=pat, %o2=len */
  18. and %o1, 0xff, %o3
  19. mov %o2, %o1
  20. sllx %o3, 8, %g1
  21. or %g1, %o3, %o2
  22. sllx %o2, 16, %g1
  23. or %g1, %o2, %o2
  24. sllx %o2, 32, %g1
  25. ba,pt %xcc, 1f
  26. or %g1, %o2, %o2
  27. .globl NGbzero
  28. .type NGbzero, #function
  29. NGbzero:
  30. clr %o2
  31. 1: brz,pn %o1, NGbzero_return
  32. mov %o0, %o3
  33. /* %o5: saved %asi, restored at NGbzero_done
  34. * %g7: store-init %asi to use
  35. * %o4: non-store-init %asi to use
  36. */
  37. rd %asi, %o5
  38. mov ASI_BLK_INIT_QUAD_LDD_P, %g7
  39. mov ASI_P, %o4
  40. wr %o4, 0x0, %asi
  41. NGbzero_from_clear_user:
  42. cmp %o1, 15
  43. bl,pn %icc, NGbzero_tiny
  44. andcc %o0, 0x7, %g1
  45. be,pt %xcc, 2f
  46. mov 8, %g2
  47. sub %g2, %g1, %g1
  48. sub %o1, %g1, %o1
  49. 1: EX_ST(stba %o2, [%o0 + 0x00] %asi)
  50. subcc %g1, 1, %g1
  51. bne,pt %xcc, 1b
  52. add %o0, 1, %o0
  53. 2: cmp %o1, 128
  54. bl,pn %icc, NGbzero_medium
  55. andcc %o0, (64 - 1), %g1
  56. be,pt %xcc, NGbzero_pre_loop
  57. mov 64, %g2
  58. sub %g2, %g1, %g1
  59. sub %o1, %g1, %o1
  60. 1: EX_ST(stxa %o2, [%o0 + 0x00] %asi)
  61. subcc %g1, 8, %g1
  62. bne,pt %xcc, 1b
  63. add %o0, 8, %o0
  64. NGbzero_pre_loop:
  65. wr %g7, 0x0, %asi
  66. andn %o1, (64 - 1), %g1
  67. sub %o1, %g1, %o1
  68. NGbzero_loop:
  69. EX_ST(stxa %o2, [%o0 + 0x00] %asi)
  70. EX_ST(stxa %o2, [%o0 + 0x08] %asi)
  71. EX_ST(stxa %o2, [%o0 + 0x10] %asi)
  72. EX_ST(stxa %o2, [%o0 + 0x18] %asi)
  73. EX_ST(stxa %o2, [%o0 + 0x20] %asi)
  74. EX_ST(stxa %o2, [%o0 + 0x28] %asi)
  75. EX_ST(stxa %o2, [%o0 + 0x30] %asi)
  76. EX_ST(stxa %o2, [%o0 + 0x38] %asi)
  77. subcc %g1, 64, %g1
  78. bne,pt %xcc, NGbzero_loop
  79. add %o0, 64, %o0
  80. membar #Sync
  81. wr %o4, 0x0, %asi
  82. brz,pn %o1, NGbzero_done
  83. NGbzero_medium:
  84. andncc %o1, 0x7, %g1
  85. be,pn %xcc, 2f
  86. sub %o1, %g1, %o1
  87. 1: EX_ST(stxa %o2, [%o0 + 0x00] %asi)
  88. subcc %g1, 8, %g1
  89. bne,pt %xcc, 1b
  90. add %o0, 8, %o0
  91. 2: brz,pt %o1, NGbzero_done
  92. nop
  93. NGbzero_tiny:
  94. 1: EX_ST(stba %o2, [%o0 + 0x00] %asi)
  95. subcc %o1, 1, %o1
  96. bne,pt %icc, 1b
  97. add %o0, 1, %o0
  98. /* fallthrough */
  99. NGbzero_done:
  100. wr %o5, 0x0, %asi
  101. NGbzero_return:
  102. retl
  103. mov %o3, %o0
  104. .size NGbzero, .-NGbzero
  105. .size NGmemset, .-NGmemset
  106. .globl NGclear_user
  107. .type NGclear_user, #function
  108. NGclear_user: /* %o0=buf, %o1=len */
  109. rd %asi, %o5
  110. brz,pn %o1, NGbzero_done
  111. clr %o3
  112. cmp %o5, ASI_AIUS
  113. bne,pn %icc, NGbzero
  114. clr %o2
  115. mov ASI_BLK_INIT_QUAD_LDD_AIUS, %g7
  116. ba,pt %xcc, NGbzero_from_clear_user
  117. mov ASI_AIUS, %o4
  118. .size NGclear_user, .-NGclear_user
  119. #define BRANCH_ALWAYS 0x10680000
  120. #define NOP 0x01000000
  121. #define NG_DO_PATCH(OLD, NEW) \
  122. sethi %hi(NEW), %g1; \
  123. or %g1, %lo(NEW), %g1; \
  124. sethi %hi(OLD), %g2; \
  125. or %g2, %lo(OLD), %g2; \
  126. sub %g1, %g2, %g1; \
  127. sethi %hi(BRANCH_ALWAYS), %g3; \
  128. sll %g1, 11, %g1; \
  129. srl %g1, 11 + 2, %g1; \
  130. or %g3, %lo(BRANCH_ALWAYS), %g3; \
  131. or %g3, %g1, %g3; \
  132. stw %g3, [%g2]; \
  133. sethi %hi(NOP), %g3; \
  134. or %g3, %lo(NOP), %g3; \
  135. stw %g3, [%g2 + 0x4]; \
  136. flush %g2;
  137. .globl niagara_patch_bzero
  138. .type niagara_patch_bzero,#function
  139. niagara_patch_bzero:
  140. NG_DO_PATCH(memset, NGmemset)
  141. NG_DO_PATCH(__bzero, NGbzero)
  142. NG_DO_PATCH(__clear_user, NGclear_user)
  143. NG_DO_PATCH(tsb_init, NGtsb_init)
  144. retl
  145. nop
  146. .size niagara_patch_bzero,.-niagara_patch_bzero