sys32.S 7.1 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241
  1. /* SPDX-License-Identifier: GPL-2.0 */
  2. /*
  3. * sys32.S: I-cache tricks for 32-bit compatibility layer simple
  4. * conversions.
  5. *
  6. * Copyright (C) 1997 David S. Miller (davem@caip.rutgers.edu)
  7. * Copyright (C) 1998 Jakub Jelinek (jj@ultra.linux.cz)
  8. */
  9. #include <asm/errno.h>
  10. /* NOTE: call as jump breaks return stack, we have to avoid that */
  11. .text
  12. .globl sys32_mmap2
  13. sys32_mmap2:
  14. sethi %hi(sys_mmap), %g1
  15. jmpl %g1 + %lo(sys_mmap), %g0
  16. sllx %o5, 12, %o5
  17. .align 32
  18. .globl sys32_socketcall
  19. sys32_socketcall: /* %o0=call, %o1=args */
  20. cmp %o0, 1
  21. bl,pn %xcc, do_einval
  22. cmp %o0, 18
  23. bg,pn %xcc, do_einval
  24. sub %o0, 1, %o0
  25. sllx %o0, 5, %o0
  26. sethi %hi(__socketcall_table_begin), %g2
  27. or %g2, %lo(__socketcall_table_begin), %g2
  28. jmpl %g2 + %o0, %g0
  29. nop
  30. do_einval:
  31. retl
  32. mov -EINVAL, %o0
  33. .align 32
  34. __socketcall_table_begin:
  35. /* Each entry is exactly 32 bytes. */
  36. do_sys_socket: /* sys_socket(int, int, int) */
  37. 1: ldswa [%o1 + 0x0] %asi, %o0
  38. sethi %hi(sys_socket), %g1
  39. 2: ldswa [%o1 + 0x8] %asi, %o2
  40. jmpl %g1 + %lo(sys_socket), %g0
  41. 3: ldswa [%o1 + 0x4] %asi, %o1
  42. nop
  43. nop
  44. nop
  45. do_sys_bind: /* sys_bind(int fd, struct sockaddr *, int) */
  46. 4: ldswa [%o1 + 0x0] %asi, %o0
  47. sethi %hi(sys_bind), %g1
  48. 5: ldswa [%o1 + 0x8] %asi, %o2
  49. jmpl %g1 + %lo(sys_bind), %g0
  50. 6: lduwa [%o1 + 0x4] %asi, %o1
  51. nop
  52. nop
  53. nop
  54. do_sys_connect: /* sys_connect(int, struct sockaddr *, int) */
  55. 7: ldswa [%o1 + 0x0] %asi, %o0
  56. sethi %hi(sys_connect), %g1
  57. 8: ldswa [%o1 + 0x8] %asi, %o2
  58. jmpl %g1 + %lo(sys_connect), %g0
  59. 9: lduwa [%o1 + 0x4] %asi, %o1
  60. nop
  61. nop
  62. nop
  63. do_sys_listen: /* sys_listen(int, int) */
  64. 10: ldswa [%o1 + 0x0] %asi, %o0
  65. sethi %hi(sys_listen), %g1
  66. jmpl %g1 + %lo(sys_listen), %g0
  67. 11: ldswa [%o1 + 0x4] %asi, %o1
  68. nop
  69. nop
  70. nop
  71. nop
  72. do_sys_accept: /* sys_accept(int, struct sockaddr *, int *) */
  73. 12: ldswa [%o1 + 0x0] %asi, %o0
  74. sethi %hi(sys_accept), %g1
  75. 13: lduwa [%o1 + 0x8] %asi, %o2
  76. jmpl %g1 + %lo(sys_accept), %g0
  77. 14: lduwa [%o1 + 0x4] %asi, %o1
  78. nop
  79. nop
  80. nop
  81. do_sys_getsockname: /* sys_getsockname(int, struct sockaddr *, int *) */
  82. 15: ldswa [%o1 + 0x0] %asi, %o0
  83. sethi %hi(sys_getsockname), %g1
  84. 16: lduwa [%o1 + 0x8] %asi, %o2
  85. jmpl %g1 + %lo(sys_getsockname), %g0
  86. 17: lduwa [%o1 + 0x4] %asi, %o1
  87. nop
  88. nop
  89. nop
  90. do_sys_getpeername: /* sys_getpeername(int, struct sockaddr *, int *) */
  91. 18: ldswa [%o1 + 0x0] %asi, %o0
  92. sethi %hi(sys_getpeername), %g1
  93. 19: lduwa [%o1 + 0x8] %asi, %o2
  94. jmpl %g1 + %lo(sys_getpeername), %g0
  95. 20: lduwa [%o1 + 0x4] %asi, %o1
  96. nop
  97. nop
  98. nop
  99. do_sys_socketpair: /* sys_socketpair(int, int, int, int *) */
  100. 21: ldswa [%o1 + 0x0] %asi, %o0
  101. sethi %hi(sys_socketpair), %g1
  102. 22: ldswa [%o1 + 0x8] %asi, %o2
  103. 23: lduwa [%o1 + 0xc] %asi, %o3
  104. jmpl %g1 + %lo(sys_socketpair), %g0
  105. 24: ldswa [%o1 + 0x4] %asi, %o1
  106. nop
  107. nop
  108. do_sys_send: /* sys_send(int, void *, size_t, unsigned int) */
  109. 25: ldswa [%o1 + 0x0] %asi, %o0
  110. sethi %hi(sys_send), %g1
  111. 26: lduwa [%o1 + 0x8] %asi, %o2
  112. 27: lduwa [%o1 + 0xc] %asi, %o3
  113. jmpl %g1 + %lo(sys_send), %g0
  114. 28: lduwa [%o1 + 0x4] %asi, %o1
  115. nop
  116. nop
  117. do_sys_recv: /* sys_recv(int, void *, size_t, unsigned int) */
  118. 29: ldswa [%o1 + 0x0] %asi, %o0
  119. sethi %hi(sys_recv), %g1
  120. 30: lduwa [%o1 + 0x8] %asi, %o2
  121. 31: lduwa [%o1 + 0xc] %asi, %o3
  122. jmpl %g1 + %lo(sys_recv), %g0
  123. 32: lduwa [%o1 + 0x4] %asi, %o1
  124. nop
  125. nop
  126. do_sys_sendto: /* sys_sendto(int, u32, compat_size_t, unsigned int, u32, int) */
  127. 33: ldswa [%o1 + 0x0] %asi, %o0
  128. sethi %hi(sys_sendto), %g1
  129. 34: lduwa [%o1 + 0x8] %asi, %o2
  130. 35: lduwa [%o1 + 0xc] %asi, %o3
  131. 36: lduwa [%o1 + 0x10] %asi, %o4
  132. 37: ldswa [%o1 + 0x14] %asi, %o5
  133. jmpl %g1 + %lo(sys_sendto), %g0
  134. 38: lduwa [%o1 + 0x4] %asi, %o1
  135. do_sys_recvfrom: /* sys_recvfrom(int, u32, compat_size_t, unsigned int, u32, u32) */
  136. 39: ldswa [%o1 + 0x0] %asi, %o0
  137. sethi %hi(sys_recvfrom), %g1
  138. 40: lduwa [%o1 + 0x8] %asi, %o2
  139. 41: lduwa [%o1 + 0xc] %asi, %o3
  140. 42: lduwa [%o1 + 0x10] %asi, %o4
  141. 43: lduwa [%o1 + 0x14] %asi, %o5
  142. jmpl %g1 + %lo(sys_recvfrom), %g0
  143. 44: lduwa [%o1 + 0x4] %asi, %o1
  144. do_sys_shutdown: /* sys_shutdown(int, int) */
  145. 45: ldswa [%o1 + 0x0] %asi, %o0
  146. sethi %hi(sys_shutdown), %g1
  147. jmpl %g1 + %lo(sys_shutdown), %g0
  148. 46: ldswa [%o1 + 0x4] %asi, %o1
  149. nop
  150. nop
  151. nop
  152. nop
  153. do_sys_setsockopt: /* sys_setsockopt(int, int, int, char *, int) */
  154. 47: ldswa [%o1 + 0x0] %asi, %o0
  155. sethi %hi(sys_setsockopt), %g1
  156. 48: ldswa [%o1 + 0x8] %asi, %o2
  157. 49: lduwa [%o1 + 0xc] %asi, %o3
  158. 50: ldswa [%o1 + 0x10] %asi, %o4
  159. jmpl %g1 + %lo(sys_setsockopt), %g0
  160. 51: ldswa [%o1 + 0x4] %asi, %o1
  161. nop
  162. do_sys_getsockopt: /* sys_getsockopt(int, int, int, u32, u32) */
  163. 52: ldswa [%o1 + 0x0] %asi, %o0
  164. sethi %hi(sys_getsockopt), %g1
  165. 53: ldswa [%o1 + 0x8] %asi, %o2
  166. 54: lduwa [%o1 + 0xc] %asi, %o3
  167. 55: lduwa [%o1 + 0x10] %asi, %o4
  168. jmpl %g1 + %lo(sys_getsockopt), %g0
  169. 56: ldswa [%o1 + 0x4] %asi, %o1
  170. nop
  171. do_sys_sendmsg: /* compat_sys_sendmsg(int, struct compat_msghdr *, unsigned int) */
  172. 57: ldswa [%o1 + 0x0] %asi, %o0
  173. sethi %hi(compat_sys_sendmsg), %g1
  174. 58: lduwa [%o1 + 0x8] %asi, %o2
  175. jmpl %g1 + %lo(compat_sys_sendmsg), %g0
  176. 59: lduwa [%o1 + 0x4] %asi, %o1
  177. nop
  178. nop
  179. nop
  180. do_sys_recvmsg: /* compat_sys_recvmsg(int, struct compat_msghdr *, unsigned int) */
  181. 60: ldswa [%o1 + 0x0] %asi, %o0
  182. sethi %hi(compat_sys_recvmsg), %g1
  183. 61: lduwa [%o1 + 0x8] %asi, %o2
  184. jmpl %g1 + %lo(compat_sys_recvmsg), %g0
  185. 62: lduwa [%o1 + 0x4] %asi, %o1
  186. nop
  187. nop
  188. nop
  189. do_sys_accept4: /* sys_accept4(int, struct sockaddr *, int *, int) */
  190. 63: ldswa [%o1 + 0x0] %asi, %o0
  191. sethi %hi(sys_accept4), %g1
  192. 64: lduwa [%o1 + 0x8] %asi, %o2
  193. 65: ldswa [%o1 + 0xc] %asi, %o3
  194. jmpl %g1 + %lo(sys_accept4), %g0
  195. 66: lduwa [%o1 + 0x4] %asi, %o1
  196. nop
  197. nop
  198. .section __ex_table,"a"
  199. .align 4
  200. .word 1b, __retl_efault, 2b, __retl_efault
  201. .word 3b, __retl_efault, 4b, __retl_efault
  202. .word 5b, __retl_efault, 6b, __retl_efault
  203. .word 7b, __retl_efault, 8b, __retl_efault
  204. .word 9b, __retl_efault, 10b, __retl_efault
  205. .word 11b, __retl_efault, 12b, __retl_efault
  206. .word 13b, __retl_efault, 14b, __retl_efault
  207. .word 15b, __retl_efault, 16b, __retl_efault
  208. .word 17b, __retl_efault, 18b, __retl_efault
  209. .word 19b, __retl_efault, 20b, __retl_efault
  210. .word 21b, __retl_efault, 22b, __retl_efault
  211. .word 23b, __retl_efault, 24b, __retl_efault
  212. .word 25b, __retl_efault, 26b, __retl_efault
  213. .word 27b, __retl_efault, 28b, __retl_efault
  214. .word 29b, __retl_efault, 30b, __retl_efault
  215. .word 31b, __retl_efault, 32b, __retl_efault
  216. .word 33b, __retl_efault, 34b, __retl_efault
  217. .word 35b, __retl_efault, 36b, __retl_efault
  218. .word 37b, __retl_efault, 38b, __retl_efault
  219. .word 39b, __retl_efault, 40b, __retl_efault
  220. .word 41b, __retl_efault, 42b, __retl_efault
  221. .word 43b, __retl_efault, 44b, __retl_efault
  222. .word 45b, __retl_efault, 46b, __retl_efault
  223. .word 47b, __retl_efault, 48b, __retl_efault
  224. .word 49b, __retl_efault, 50b, __retl_efault
  225. .word 51b, __retl_efault, 52b, __retl_efault
  226. .word 53b, __retl_efault, 54b, __retl_efault
  227. .word 55b, __retl_efault, 56b, __retl_efault
  228. .word 57b, __retl_efault, 58b, __retl_efault
  229. .word 59b, __retl_efault, 60b, __retl_efault
  230. .word 61b, __retl_efault, 62b, __retl_efault
  231. .word 63b, __retl_efault, 64b, __retl_efault
  232. .word 65b, __retl_efault, 66b, __retl_efault
  233. .previous