vmlinux.lds.S 8.3 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390
  1. /* SPDX-License-Identifier: GPL-2.0 */
  2. #ifdef CONFIG_PPC64
  3. #define PROVIDE32(x) PROVIDE(__unused__##x)
  4. #else
  5. #define PROVIDE32(x) PROVIDE(x)
  6. #endif
  7. #define BSS_FIRST_SECTIONS *(.bss.prominit)
  8. #define EMITS_PT_NOTE
  9. #define RO_EXCEPTION_TABLE_ALIGN 0
  10. #include <asm/page.h>
  11. #include <asm-generic/vmlinux.lds.h>
  12. #include <asm/cache.h>
  13. #include <asm/thread_info.h>
  14. #define STRICT_ALIGN_SIZE (1 << CONFIG_DATA_SHIFT)
  15. ENTRY(_stext)
  16. PHDRS {
  17. text PT_LOAD FLAGS(7); /* RWX */
  18. note PT_NOTE FLAGS(0);
  19. }
  20. #ifdef CONFIG_PPC64
  21. OUTPUT_ARCH(powerpc:common64)
  22. jiffies = jiffies_64;
  23. #else
  24. OUTPUT_ARCH(powerpc:common)
  25. jiffies = jiffies_64 + 4;
  26. #endif
  27. SECTIONS
  28. {
  29. . = KERNELBASE;
  30. /*
  31. * Text, read only data and other permanent read-only sections
  32. */
  33. _text = .;
  34. _stext = .;
  35. /*
  36. * Head text.
  37. * This needs to be in its own output section to avoid ld placing
  38. * branch trampoline stubs randomly throughout the fixed sections,
  39. * which it will do (even if the branch comes from another section)
  40. * in order to optimize stub generation.
  41. */
  42. .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) {
  43. #ifdef CONFIG_PPC64
  44. KEEP(*(.head.text.first_256B));
  45. #ifdef CONFIG_PPC_BOOK3E
  46. #else
  47. KEEP(*(.head.text.real_vectors));
  48. *(.head.text.real_trampolines);
  49. KEEP(*(.head.text.virt_vectors));
  50. *(.head.text.virt_trampolines);
  51. # if defined(CONFIG_PPC_PSERIES) || defined(CONFIG_PPC_POWERNV)
  52. KEEP(*(.head.data.fwnmi_page));
  53. # endif
  54. #endif
  55. #else /* !CONFIG_PPC64 */
  56. HEAD_TEXT
  57. #endif
  58. } :text
  59. __head_end = .;
  60. #ifdef CONFIG_PPC64
  61. /*
  62. * ALIGN(0) overrides the default output section alignment because
  63. * this needs to start right after .head.text in order for fixed
  64. * section placement to work.
  65. */
  66. .text ALIGN(0) : AT(ADDR(.text) - LOAD_OFFSET) {
  67. #ifdef CONFIG_LD_HEAD_STUB_CATCH
  68. KEEP(*(.linker_stub_catch));
  69. . = . ;
  70. #endif
  71. #else
  72. .text : AT(ADDR(.text) - LOAD_OFFSET) {
  73. ALIGN_FUNCTION();
  74. #endif
  75. /* careful! __ftr_alt_* sections need to be close to .text */
  76. *(.text.hot .text.hot.* TEXT_MAIN .text.fixup .text.unlikely .text.unlikely.* .fixup __ftr_alt_* .ref.text);
  77. #ifdef CONFIG_PPC64
  78. *(.tramp.ftrace.text);
  79. #endif
  80. NOINSTR_TEXT
  81. SCHED_TEXT
  82. CPUIDLE_TEXT
  83. LOCK_TEXT
  84. KPROBES_TEXT
  85. IRQENTRY_TEXT
  86. SOFTIRQENTRY_TEXT
  87. /*
  88. * -Os builds call FP save/restore functions. The powerpc64
  89. * linker generates those on demand in the .sfpr section.
  90. * .sfpr gets placed at the beginning of a group of input
  91. * sections, which can break start-of-text offset if it is
  92. * included with the main text sections, so put it by itself.
  93. */
  94. *(.sfpr);
  95. MEM_KEEP(init.text)
  96. MEM_KEEP(exit.text)
  97. #ifdef CONFIG_PPC32
  98. *(.got1)
  99. __got2_start = .;
  100. *(.got2)
  101. __got2_end = .;
  102. #endif /* CONFIG_PPC32 */
  103. } :text
  104. . = ALIGN(PAGE_SIZE);
  105. _etext = .;
  106. PROVIDE32 (etext = .);
  107. /* Read-only data */
  108. RO_DATA(PAGE_SIZE)
  109. #ifdef CONFIG_PPC64
  110. . = ALIGN(8);
  111. __stf_entry_barrier_fixup : AT(ADDR(__stf_entry_barrier_fixup) - LOAD_OFFSET) {
  112. __start___stf_entry_barrier_fixup = .;
  113. *(__stf_entry_barrier_fixup)
  114. __stop___stf_entry_barrier_fixup = .;
  115. }
  116. . = ALIGN(8);
  117. __uaccess_flush_fixup : AT(ADDR(__uaccess_flush_fixup) - LOAD_OFFSET) {
  118. __start___uaccess_flush_fixup = .;
  119. *(__uaccess_flush_fixup)
  120. __stop___uaccess_flush_fixup = .;
  121. }
  122. . = ALIGN(8);
  123. __entry_flush_fixup : AT(ADDR(__entry_flush_fixup) - LOAD_OFFSET) {
  124. __start___entry_flush_fixup = .;
  125. *(__entry_flush_fixup)
  126. __stop___entry_flush_fixup = .;
  127. }
  128. . = ALIGN(8);
  129. __scv_entry_flush_fixup : AT(ADDR(__scv_entry_flush_fixup) - LOAD_OFFSET) {
  130. __start___scv_entry_flush_fixup = .;
  131. *(__scv_entry_flush_fixup)
  132. __stop___scv_entry_flush_fixup = .;
  133. }
  134. . = ALIGN(8);
  135. __stf_exit_barrier_fixup : AT(ADDR(__stf_exit_barrier_fixup) - LOAD_OFFSET) {
  136. __start___stf_exit_barrier_fixup = .;
  137. *(__stf_exit_barrier_fixup)
  138. __stop___stf_exit_barrier_fixup = .;
  139. }
  140. . = ALIGN(8);
  141. __rfi_flush_fixup : AT(ADDR(__rfi_flush_fixup) - LOAD_OFFSET) {
  142. __start___rfi_flush_fixup = .;
  143. *(__rfi_flush_fixup)
  144. __stop___rfi_flush_fixup = .;
  145. }
  146. #endif /* CONFIG_PPC64 */
  147. #ifdef CONFIG_PPC_BARRIER_NOSPEC
  148. . = ALIGN(8);
  149. __spec_barrier_fixup : AT(ADDR(__spec_barrier_fixup) - LOAD_OFFSET) {
  150. __start___barrier_nospec_fixup = .;
  151. *(__barrier_nospec_fixup)
  152. __stop___barrier_nospec_fixup = .;
  153. }
  154. #endif /* CONFIG_PPC_BARRIER_NOSPEC */
  155. #ifdef CONFIG_PPC_FSL_BOOK3E
  156. . = ALIGN(8);
  157. __spec_btb_flush_fixup : AT(ADDR(__spec_btb_flush_fixup) - LOAD_OFFSET) {
  158. __start__btb_flush_fixup = .;
  159. *(__btb_flush_fixup)
  160. __stop__btb_flush_fixup = .;
  161. }
  162. #endif
  163. /*
  164. * Init sections discarded at runtime
  165. */
  166. . = ALIGN(STRICT_ALIGN_SIZE);
  167. __init_begin = .;
  168. . = ALIGN(PAGE_SIZE);
  169. .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) {
  170. _sinittext = .;
  171. INIT_TEXT
  172. /*
  173. *.init.text might be RO so we must ensure this section ends on
  174. * a page boundary.
  175. */
  176. . = ALIGN(PAGE_SIZE);
  177. _einittext = .;
  178. #ifdef CONFIG_PPC64
  179. *(.tramp.ftrace.init);
  180. #endif
  181. } :text
  182. /* .exit.text is discarded at runtime, not link time,
  183. * to deal with references from __bug_table
  184. */
  185. .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) {
  186. EXIT_TEXT
  187. }
  188. . = ALIGN(PAGE_SIZE);
  189. INIT_DATA_SECTION(16)
  190. . = ALIGN(8);
  191. __ftr_fixup : AT(ADDR(__ftr_fixup) - LOAD_OFFSET) {
  192. __start___ftr_fixup = .;
  193. KEEP(*(__ftr_fixup))
  194. __stop___ftr_fixup = .;
  195. }
  196. . = ALIGN(8);
  197. __mmu_ftr_fixup : AT(ADDR(__mmu_ftr_fixup) - LOAD_OFFSET) {
  198. __start___mmu_ftr_fixup = .;
  199. KEEP(*(__mmu_ftr_fixup))
  200. __stop___mmu_ftr_fixup = .;
  201. }
  202. . = ALIGN(8);
  203. __lwsync_fixup : AT(ADDR(__lwsync_fixup) - LOAD_OFFSET) {
  204. __start___lwsync_fixup = .;
  205. KEEP(*(__lwsync_fixup))
  206. __stop___lwsync_fixup = .;
  207. }
  208. #ifdef CONFIG_PPC64
  209. . = ALIGN(8);
  210. __fw_ftr_fixup : AT(ADDR(__fw_ftr_fixup) - LOAD_OFFSET) {
  211. __start___fw_ftr_fixup = .;
  212. KEEP(*(__fw_ftr_fixup))
  213. __stop___fw_ftr_fixup = .;
  214. }
  215. #endif
  216. PERCPU_SECTION(L1_CACHE_BYTES)
  217. . = ALIGN(8);
  218. .machine.desc : AT(ADDR(.machine.desc) - LOAD_OFFSET) {
  219. __machine_desc_start = . ;
  220. KEEP(*(.machine.desc))
  221. __machine_desc_end = . ;
  222. }
  223. #ifdef CONFIG_RELOCATABLE
  224. . = ALIGN(8);
  225. .dynsym : AT(ADDR(.dynsym) - LOAD_OFFSET)
  226. {
  227. #ifdef CONFIG_PPC32
  228. __dynamic_symtab = .;
  229. #endif
  230. *(.dynsym)
  231. }
  232. .dynstr : AT(ADDR(.dynstr) - LOAD_OFFSET) { *(.dynstr) }
  233. .dynamic : AT(ADDR(.dynamic) - LOAD_OFFSET)
  234. {
  235. __dynamic_start = .;
  236. *(.dynamic)
  237. }
  238. .hash : AT(ADDR(.hash) - LOAD_OFFSET) { *(.hash) }
  239. .gnu.hash : AT(ADDR(.gnu.hash) - LOAD_OFFSET) { *(.gnu.hash) }
  240. .interp : AT(ADDR(.interp) - LOAD_OFFSET) { *(.interp) }
  241. .rela.dyn : AT(ADDR(.rela.dyn) - LOAD_OFFSET)
  242. {
  243. __rela_dyn_start = .;
  244. *(.rela*)
  245. }
  246. #endif
  247. /* .exit.data is discarded at runtime, not link time,
  248. * to deal with references from .exit.text
  249. */
  250. .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) {
  251. EXIT_DATA
  252. }
  253. /* freed after init ends here */
  254. . = ALIGN(PAGE_SIZE);
  255. __init_end = .;
  256. /*
  257. * And now the various read/write data
  258. */
  259. . = ALIGN(PAGE_SIZE);
  260. _sdata = .;
  261. #ifdef CONFIG_PPC32
  262. .data : AT(ADDR(.data) - LOAD_OFFSET) {
  263. DATA_DATA
  264. #ifdef CONFIG_UBSAN
  265. *(.data..Lubsan_data*)
  266. *(.data..Lubsan_type*)
  267. #endif
  268. *(.data.rel*)
  269. *(SDATA_MAIN)
  270. *(.sdata2)
  271. *(.got.plt) *(.got)
  272. *(.plt)
  273. *(.branch_lt)
  274. }
  275. #else
  276. .data : AT(ADDR(.data) - LOAD_OFFSET) {
  277. DATA_DATA
  278. #ifdef CONFIG_UBSAN
  279. *(.data..Lubsan_data*)
  280. *(.data..Lubsan_type*)
  281. #endif
  282. *(.data.rel*)
  283. *(.toc1)
  284. *(.branch_lt)
  285. }
  286. .opd : AT(ADDR(.opd) - LOAD_OFFSET) {
  287. __start_opd = .;
  288. KEEP(*(.opd))
  289. __end_opd = .;
  290. }
  291. . = ALIGN(256);
  292. .got : AT(ADDR(.got) - LOAD_OFFSET) {
  293. __toc_start = .;
  294. #ifndef CONFIG_RELOCATABLE
  295. __prom_init_toc_start = .;
  296. arch/powerpc/kernel/prom_init.o*(.toc .got)
  297. __prom_init_toc_end = .;
  298. #endif
  299. *(.got)
  300. *(.toc)
  301. }
  302. #endif
  303. /* The initial task and kernel stack */
  304. INIT_TASK_DATA_SECTION(THREAD_ALIGN)
  305. .data..page_aligned : AT(ADDR(.data..page_aligned) - LOAD_OFFSET) {
  306. PAGE_ALIGNED_DATA(PAGE_SIZE)
  307. }
  308. .data..cacheline_aligned : AT(ADDR(.data..cacheline_aligned) - LOAD_OFFSET) {
  309. CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
  310. }
  311. .data..read_mostly : AT(ADDR(.data..read_mostly) - LOAD_OFFSET) {
  312. READ_MOSTLY_DATA(L1_CACHE_BYTES)
  313. }
  314. . = ALIGN(PAGE_SIZE);
  315. .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) {
  316. NOSAVE_DATA
  317. }
  318. BUG_TABLE
  319. . = ALIGN(PAGE_SIZE);
  320. _edata = .;
  321. PROVIDE32 (edata = .);
  322. /*
  323. * And finally the bss
  324. */
  325. BSS_SECTION(0, 0, 0)
  326. . = ALIGN(PAGE_SIZE);
  327. _end = . ;
  328. PROVIDE32 (end = .);
  329. STABS_DEBUG
  330. DWARF_DEBUG
  331. ELF_DETAILS
  332. DISCARDS
  333. /DISCARD/ : {
  334. *(*.EMB.apuinfo)
  335. *(.glink .iplt .plt .rela* .comment)
  336. *(.gnu.version*)
  337. *(.gnu.attributes)
  338. *(.eh_frame)
  339. }
  340. }