reloc_64.S 1.8 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384
  1. /* SPDX-License-Identifier: GPL-2.0-or-later */
  2. /*
  3. * Code to process dynamic relocations in the kernel.
  4. *
  5. * Copyright 2008 Paul Mackerras, IBM Corp.
  6. */
  7. #include <asm/ppc_asm.h>
  8. RELA = 7
  9. RELACOUNT = 0x6ffffff9
  10. R_PPC64_RELATIVE = 22
  11. /*
  12. * r3 = desired final address of kernel
  13. */
  14. _GLOBAL(relocate)
  15. mflr r0
  16. bcl 20,31,$+4
  17. 0: mflr r12 /* r12 has runtime addr of label 0 */
  18. mtlr r0
  19. ld r11,(p_dyn - 0b)(r12)
  20. add r11,r11,r12 /* r11 has runtime addr of .dynamic section */
  21. ld r9,(p_rela - 0b)(r12)
  22. add r9,r9,r12 /* r9 has runtime addr of .rela.dyn section */
  23. ld r10,(p_st - 0b)(r12)
  24. add r10,r10,r12 /* r10 has runtime addr of _stext */
  25. /*
  26. * Scan the dynamic section for the RELA and RELACOUNT entries.
  27. */
  28. li r7,0
  29. li r8,0
  30. 1: ld r6,0(r11) /* get tag */
  31. cmpdi r6,0
  32. beq 4f /* end of list */
  33. cmpdi r6,RELA
  34. bne 2f
  35. ld r7,8(r11) /* get RELA pointer in r7 */
  36. b 3f
  37. 2: addis r6,r6,(-RELACOUNT)@ha
  38. cmpdi r6,RELACOUNT@l
  39. bne 3f
  40. ld r8,8(r11) /* get RELACOUNT value in r8 */
  41. 3: addi r11,r11,16
  42. b 1b
  43. 4: cmpdi r7,0 /* check we have both RELA and RELACOUNT */
  44. cmpdi cr1,r8,0
  45. beq 6f
  46. beq cr1,6f
  47. /*
  48. * Work out linktime address of _stext and hence the
  49. * relocation offset to be applied.
  50. * cur_offset [r7] = rela.run [r9] - rela.link [r7]
  51. * _stext.link [r10] = _stext.run [r10] - cur_offset [r7]
  52. * final_offset [r3] = _stext.final [r3] - _stext.link [r10]
  53. */
  54. subf r7,r7,r9 /* cur_offset */
  55. subf r10,r7,r10
  56. subf r3,r10,r3 /* final_offset */
  57. /*
  58. * Run through the list of relocations and process the
  59. * R_PPC64_RELATIVE ones.
  60. */
  61. mtctr r8
  62. 5: ld r0,8(9) /* ELF64_R_TYPE(reloc->r_info) */
  63. cmpdi r0,R_PPC64_RELATIVE
  64. bne 6f
  65. ld r6,0(r9) /* reloc->r_offset */
  66. ld r0,16(r9) /* reloc->r_addend */
  67. add r0,r0,r3
  68. stdx r0,r7,r6
  69. addi r9,r9,24
  70. bdnz 5b
  71. 6: blr
  72. .balign 8
  73. p_dyn: .8byte __dynamic_start - 0b
  74. p_rela: .8byte __rela_dyn_start - 0b
  75. p_st: .8byte _stext - 0b