getuser.S 3.4 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167
  1. /* SPDX-License-Identifier: GPL-2.0-only */
  2. /*
  3. * linux/arch/arm/lib/getuser.S
  4. *
  5. * Copyright (C) 2001 Russell King
  6. *
  7. * Idea from x86 version, (C) Copyright 1998 Linus Torvalds
  8. *
  9. * These functions have a non-standard call interface to make them more
  10. * efficient, especially as they return an error value in addition to
  11. * the "real" return value.
  12. *
  13. * __get_user_X
  14. *
  15. * Inputs: r0 contains the address
  16. * r1 contains the address limit, which must be preserved
  17. * Outputs: r0 is the error code
  18. * r2, r3 contains the zero-extended value
  19. * lr corrupted
  20. *
  21. * No other registers must be altered. (see <asm/uaccess.h>
  22. * for specific ASM register usage).
  23. *
  24. * Note that ADDR_LIMIT is either 0 or 0xc0000000.
  25. * Note also that it is intended that __get_user_bad is not global.
  26. */
  27. #include <linux/linkage.h>
  28. #include <asm/assembler.h>
  29. #include <asm/errno.h>
  30. #include <asm/domain.h>
  31. ENTRY(__get_user_1)
  32. check_uaccess r0, 1, r1, r2, __get_user_bad
  33. 1: TUSER(ldrb) r2, [r0]
  34. mov r0, #0
  35. ret lr
  36. ENDPROC(__get_user_1)
  37. _ASM_NOKPROBE(__get_user_1)
  38. ENTRY(__get_user_2)
  39. check_uaccess r0, 2, r1, r2, __get_user_bad
  40. #if __LINUX_ARM_ARCH__ >= 6
  41. 2: TUSER(ldrh) r2, [r0]
  42. #else
  43. #ifdef CONFIG_CPU_USE_DOMAINS
  44. rb .req ip
  45. 2: ldrbt r2, [r0], #1
  46. 3: ldrbt rb, [r0], #0
  47. #else
  48. rb .req r0
  49. 2: ldrb r2, [r0]
  50. 3: ldrb rb, [r0, #1]
  51. #endif
  52. #ifndef __ARMEB__
  53. orr r2, r2, rb, lsl #8
  54. #else
  55. orr r2, rb, r2, lsl #8
  56. #endif
  57. #endif /* __LINUX_ARM_ARCH__ >= 6 */
  58. mov r0, #0
  59. ret lr
  60. ENDPROC(__get_user_2)
  61. _ASM_NOKPROBE(__get_user_2)
  62. ENTRY(__get_user_4)
  63. check_uaccess r0, 4, r1, r2, __get_user_bad
  64. 4: TUSER(ldr) r2, [r0]
  65. mov r0, #0
  66. ret lr
  67. ENDPROC(__get_user_4)
  68. _ASM_NOKPROBE(__get_user_4)
  69. ENTRY(__get_user_8)
  70. check_uaccess r0, 8, r1, r2, __get_user_bad8
  71. #ifdef CONFIG_THUMB2_KERNEL
  72. 5: TUSER(ldr) r2, [r0]
  73. 6: TUSER(ldr) r3, [r0, #4]
  74. #else
  75. 5: TUSER(ldr) r2, [r0], #4
  76. 6: TUSER(ldr) r3, [r0]
  77. #endif
  78. mov r0, #0
  79. ret lr
  80. ENDPROC(__get_user_8)
  81. _ASM_NOKPROBE(__get_user_8)
  82. #ifdef __ARMEB__
  83. ENTRY(__get_user_32t_8)
  84. check_uaccess r0, 8, r1, r2, __get_user_bad
  85. #ifdef CONFIG_CPU_USE_DOMAINS
  86. add r0, r0, #4
  87. 7: ldrt r2, [r0]
  88. #else
  89. 7: ldr r2, [r0, #4]
  90. #endif
  91. mov r0, #0
  92. ret lr
  93. ENDPROC(__get_user_32t_8)
  94. _ASM_NOKPROBE(__get_user_32t_8)
  95. ENTRY(__get_user_64t_1)
  96. check_uaccess r0, 1, r1, r2, __get_user_bad8
  97. 8: TUSER(ldrb) r3, [r0]
  98. mov r0, #0
  99. ret lr
  100. ENDPROC(__get_user_64t_1)
  101. _ASM_NOKPROBE(__get_user_64t_1)
  102. ENTRY(__get_user_64t_2)
  103. check_uaccess r0, 2, r1, r2, __get_user_bad8
  104. #ifdef CONFIG_CPU_USE_DOMAINS
  105. rb .req ip
  106. 9: ldrbt r3, [r0], #1
  107. 10: ldrbt rb, [r0], #0
  108. #else
  109. rb .req r0
  110. 9: ldrb r3, [r0]
  111. 10: ldrb rb, [r0, #1]
  112. #endif
  113. orr r3, rb, r3, lsl #8
  114. mov r0, #0
  115. ret lr
  116. ENDPROC(__get_user_64t_2)
  117. _ASM_NOKPROBE(__get_user_64t_2)
  118. ENTRY(__get_user_64t_4)
  119. check_uaccess r0, 4, r1, r2, __get_user_bad8
  120. 11: TUSER(ldr) r3, [r0]
  121. mov r0, #0
  122. ret lr
  123. ENDPROC(__get_user_64t_4)
  124. _ASM_NOKPROBE(__get_user_64t_4)
  125. #endif
  126. __get_user_bad8:
  127. mov r3, #0
  128. __get_user_bad:
  129. mov r2, #0
  130. mov r0, #-EFAULT
  131. ret lr
  132. ENDPROC(__get_user_bad)
  133. ENDPROC(__get_user_bad8)
  134. _ASM_NOKPROBE(__get_user_bad)
  135. _ASM_NOKPROBE(__get_user_bad8)
  136. .pushsection __ex_table, "a"
  137. .long 1b, __get_user_bad
  138. .long 2b, __get_user_bad
  139. #if __LINUX_ARM_ARCH__ < 6
  140. .long 3b, __get_user_bad
  141. #endif
  142. .long 4b, __get_user_bad
  143. .long 5b, __get_user_bad8
  144. .long 6b, __get_user_bad8
  145. #ifdef __ARMEB__
  146. .long 7b, __get_user_bad
  147. .long 8b, __get_user_bad8
  148. .long 9b, __get_user_bad8
  149. .long 10b, __get_user_bad8
  150. .long 11b, __get_user_bad8
  151. #endif
  152. .popsection