bitops.h 2.1 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107
  1. /* SPDX-License-Identifier: GPL-2.0 */
  2. #include <asm/assembler.h>
  3. #include <asm/unwind.h>
  4. #if __LINUX_ARM_ARCH__ >= 6
  5. .macro bitop, name, instr
  6. ENTRY( \name )
  7. UNWIND( .fnstart )
  8. ands ip, r1, #3
  9. strbne r1, [ip] @ assert word-aligned
  10. mov r2, #1
  11. and r3, r0, #31 @ Get bit offset
  12. mov r0, r0, lsr #5
  13. add r1, r1, r0, lsl #2 @ Get word offset
  14. #if __LINUX_ARM_ARCH__ >= 7 && defined(CONFIG_SMP)
  15. .arch_extension mp
  16. ALT_SMP(W(pldw) [r1])
  17. ALT_UP(W(nop))
  18. #endif
  19. mov r3, r2, lsl r3
  20. 1: ldrex r2, [r1]
  21. \instr r2, r2, r3
  22. strex r0, r2, [r1]
  23. cmp r0, #0
  24. bne 1b
  25. bx lr
  26. UNWIND( .fnend )
  27. ENDPROC(\name )
  28. .endm
  29. .macro testop, name, instr, store
  30. ENTRY( \name )
  31. UNWIND( .fnstart )
  32. ands ip, r1, #3
  33. strbne r1, [ip] @ assert word-aligned
  34. mov r2, #1
  35. and r3, r0, #31 @ Get bit offset
  36. mov r0, r0, lsr #5
  37. add r1, r1, r0, lsl #2 @ Get word offset
  38. mov r3, r2, lsl r3 @ create mask
  39. smp_dmb
  40. #if __LINUX_ARM_ARCH__ >= 7 && defined(CONFIG_SMP)
  41. .arch_extension mp
  42. ALT_SMP(W(pldw) [r1])
  43. ALT_UP(W(nop))
  44. #endif
  45. 1: ldrex r2, [r1]
  46. ands r0, r2, r3 @ save old value of bit
  47. \instr r2, r2, r3 @ toggle bit
  48. strex ip, r2, [r1]
  49. cmp ip, #0
  50. bne 1b
  51. smp_dmb
  52. cmp r0, #0
  53. movne r0, #1
  54. 2: bx lr
  55. UNWIND( .fnend )
  56. ENDPROC(\name )
  57. .endm
  58. #else
  59. .macro bitop, name, instr
  60. ENTRY( \name )
  61. UNWIND( .fnstart )
  62. ands ip, r1, #3
  63. strbne r1, [ip] @ assert word-aligned
  64. and r2, r0, #31
  65. mov r0, r0, lsr #5
  66. mov r3, #1
  67. mov r3, r3, lsl r2
  68. save_and_disable_irqs ip
  69. ldr r2, [r1, r0, lsl #2]
  70. \instr r2, r2, r3
  71. str r2, [r1, r0, lsl #2]
  72. restore_irqs ip
  73. ret lr
  74. UNWIND( .fnend )
  75. ENDPROC(\name )
  76. .endm
  77. /**
  78. * testop - implement a test_and_xxx_bit operation.
  79. * @instr: operational instruction
  80. * @store: store instruction
  81. *
  82. * Note: we can trivially conditionalise the store instruction
  83. * to avoid dirtying the data cache.
  84. */
  85. .macro testop, name, instr, store
  86. ENTRY( \name )
  87. UNWIND( .fnstart )
  88. ands ip, r1, #3
  89. strbne r1, [ip] @ assert word-aligned
  90. and r3, r0, #31
  91. mov r0, r0, lsr #5
  92. save_and_disable_irqs ip
  93. ldr r2, [r1, r0, lsl #2]!
  94. mov r0, #1
  95. tst r2, r0, lsl r3
  96. \instr r2, r2, r0, lsl r3
  97. \store r2, [r1]
  98. moveq r0, #0
  99. restore_irqs ip
  100. ret lr
  101. UNWIND( .fnend )
  102. ENDPROC(\name )
  103. .endm
  104. #endif