lowlevel_init_ca15.S 1.7 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990
  1. /* SPDX-License-Identifier: GPL-2.0 */
  2. /*
  3. * arch/arm/cpu/armv7/rmobile/lowlevel_init_ca15.S
  4. * This file is lager low level initialize.
  5. *
  6. * Copyright (C) 2013, 2014 Renesas Electronics Corporation
  7. */
  8. #include <config.h>
  9. #include <linux/linkage.h>
  10. ENTRY(lowlevel_init)
  11. #ifndef CONFIG_SPL_BUILD
  12. mrc p15, 0, r4, c0, c0, 5 /* mpidr */
  13. orr r4, r4, r4, lsr #6
  14. and r4, r4, #7 /* id 0-3 = ca15.0,1,2,3 */
  15. b do_lowlevel_init
  16. .pool
  17. /*
  18. * CPU ID #1-#3 come here
  19. */
  20. .align 4
  21. do_cpu_waiting:
  22. ldr r1, =0xe6180000 /* sysc */
  23. 1: ldr r0, [r1, #0x20] /* sbar */
  24. tst r0, r0
  25. beq 1b
  26. bx r0
  27. /*
  28. * Only CPU ID #0 comes here
  29. */
  30. .align 4
  31. do_lowlevel_init:
  32. ldr r2, =0xFF000044 /* PRR */
  33. ldr r1, [r2]
  34. and r1, r1, #0x7F00
  35. lsrs r1, r1, #8
  36. cmp r1, #0x4C /* 0x4C is ID of r8a7794 */
  37. beq _enable_actlr_smp
  38. /* surpress wfe if ca15 */
  39. tst r4, #4
  40. mrceq p15, 0, r0, c1, c0, 1 /* actlr */
  41. orreq r0, r0, #(1<<7)
  42. mcreq p15, 0, r0, c1, c0, 1
  43. /* and set l2 latency */
  44. mrc p15, 0, r0, c0, c0, 5 /* r0 = MPIDR */
  45. and r0, r0, #0xf00
  46. lsr r0, r0, #8
  47. tst r0, #1 /* only need for cluster 0 */
  48. bne _exit_init_l2_a15
  49. mrc p15, 1, r0, c9, c0, 2 /* r0 = L2CTLR */
  50. and r1, r0, #7
  51. cmp r1, #3 /* has already been set up */
  52. bicne r0, r0, #0xe7
  53. orrne r0, r0, #0x83 /* L2CTLR[7:6] + L2CTLR[2:0] */
  54. #if defined(CONFIG_R8A7790)
  55. orrne r0, r0, #0x20 /* L2CTLR[5] */
  56. #endif
  57. mcrne p15, 1, r0, c9, c0, 2
  58. b _exit_init_l2_a15
  59. _enable_actlr_smp: /* R8A7794 only (CA7) */
  60. #ifndef CONFIG_DCACHE_OFF
  61. mrc p15, 0, r0, c1, c0, 1
  62. orr r0, r0, #0x40
  63. mcr p15, 0, r0, c1, c0, 1
  64. #endif
  65. _exit_init_l2_a15:
  66. ldr r3, =(CONFIG_SYS_INIT_SP_ADDR)
  67. sub sp, r3, #4
  68. str lr, [sp]
  69. /* initialize system */
  70. bl s_init
  71. ldr lr, [sp]
  72. #endif
  73. mov pc, lr
  74. nop
  75. ENDPROC(lowlevel_init)
  76. .ltorg