u-boot-spl-da850evm.lds 1.1 KB

1234567891011121314151617181920212223242526272829303132333435363738394041424344454647484950515253545556575859606162636465
  1. /* SPDX-License-Identifier: GPL-2.0+ */
  2. /*
  3. * (C) Copyright 2002
  4. * Gary Jennejohn, DENX Software Engineering, <garyj@denx.de>
  5. *
  6. * (C) Copyright 2008
  7. * Guennadi Liakhovetki, DENX Software Engineering, <lg@denx.de>
  8. */
  9. MEMORY { .sram : ORIGIN = IMAGE_TEXT_BASE,\
  10. LENGTH = CONFIG_SPL_MAX_FOOTPRINT }
  11. MEMORY { .sdram : ORIGIN = CONFIG_SPL_BSS_START_ADDR, \
  12. LENGTH = CONFIG_SPL_BSS_MAX_SIZE }
  13. OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
  14. OUTPUT_ARCH(arm)
  15. ENTRY(_start)
  16. SECTIONS
  17. {
  18. . = 0x00000000;
  19. . = ALIGN(4);
  20. .text :
  21. {
  22. __start = .;
  23. *(.vectors)
  24. arch/arm/cpu/arm926ejs/start.o (.text*)
  25. *(.text*)
  26. } >.sram
  27. . = ALIGN(4);
  28. .rodata : { *(SORT_BY_ALIGNMENT(.rodata*)) } >.sram
  29. . = ALIGN(4);
  30. .data : { *(SORT_BY_ALIGNMENT(.data*)) } >.sram
  31. . = ALIGN(4);
  32. .u_boot_list : { KEEP(*(SORT(.u_boot_list*))); } >.sram
  33. . = ALIGN(4);
  34. .rel.dyn : {
  35. __rel_dyn_start = .;
  36. *(.rel*)
  37. __rel_dyn_end = .;
  38. } >.sram
  39. __image_copy_end = .;
  40. .end :
  41. {
  42. *(.__end)
  43. }
  44. _image_binary_end = .;
  45. .bss :
  46. {
  47. . = ALIGN(4);
  48. __bss_start = .;
  49. *(.bss*)
  50. . = ALIGN(4);
  51. __bss_end = .;
  52. } >.sdram
  53. }