llvm_git.bb 5.8 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173
  1. # Copyright (C) 2017 Khem Raj <raj.khem@gmail.com>
  2. # Released under the MIT license (see COPYING.MIT for the terms)
  3. SUMMARY = "The LLVM Compiler Infrastructure"
  4. HOMEPAGE = "http://llvm.org"
  5. LICENSE = "Apache-2.0-with-LLVM-exception"
  6. SECTION = "devel"
  7. LIC_FILES_CHKSUM = "file://LICENSE.TXT;md5=8a15a0759ef07f2682d2ba4b893c9afe"
  8. DEPENDS = "libffi libxml2 zlib zstd libedit ninja-native llvm-native"
  9. RDEPENDS:${PN}:append:class-target = " ncurses-terminfo"
  10. inherit cmake pkgconfig
  11. PV = "17.0.0"
  12. MAJOR_VERSION = "${@oe.utils.trim_version("${PV}", 1)}"
  13. LLVM_RELEASE = "${PV}"
  14. BRANCH = "release/${MAJOR_VERSION}.x"
  15. SRCREV = "092b6c5ee3707ea10b9f10d0a674e8d12395369b"
  16. SRC_URI = "git://github.com/llvm/llvm-project.git;branch=${BRANCH};protocol=https \
  17. file://0007-llvm-allow-env-override-of-exe-path.patch;striplevel=2 \
  18. file://0001-AsmMatcherEmitter-sort-ClassInfo-lists-by-name-as-we.patch;striplevel=2 \
  19. file://llvm-config \
  20. "
  21. UPSTREAM_CHECK_GITTAGREGEX = "llvmorg-(?P<pver>\d+(\.\d+)+)"
  22. S = "${WORKDIR}/git/llvm"
  23. LLVM_INSTALL_DIR = "${WORKDIR}/llvm-install"
  24. def get_llvm_arch(bb, d, arch_var):
  25. import re
  26. a = d.getVar(arch_var)
  27. if re.match(r'(i.86|athlon|x86.64)$', a): return 'X86'
  28. elif re.match(r'arm$', a): return 'ARM'
  29. elif re.match(r'armeb$', a): return 'ARM'
  30. elif re.match(r'aarch64$', a): return 'AArch64'
  31. elif re.match(r'aarch64_be$', a): return 'AArch64'
  32. elif re.match(r'mips(isa|)(32|64|)(r6|)(el|)$', a): return 'Mips'
  33. elif re.match(r'riscv(32|64)(eb|)$', a): return 'RISCV'
  34. elif re.match(r'p(pc|owerpc)(|64)', a): return 'PowerPC'
  35. else:
  36. raise bb.parse.SkipRecipe("Cannot map '%s' to a supported LLVM architecture" % a)
  37. def get_llvm_host_arch(bb, d):
  38. return get_llvm_arch(bb, d, 'HOST_ARCH')
  39. PACKAGECONFIG ??= "libllvm"
  40. PACKAGECONFIG:class-native = "${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'libllvm', '', d)}"
  41. # if optviewer OFF, force the modules to be not found or the ones on the host would be found
  42. PACKAGECONFIG[optviewer] = ",-DPY_PYGMENTS_FOUND=OFF -DPY_PYGMENTS_LEXERS_C_CPP_FOUND=OFF -DPY_YAML_FOUND=OFF,python3-pygments python3-pyyaml,python3-pygments python3-pyyaml"
  43. PACKAGECONFIG[libllvm] = ""
  44. #
  45. # Default to build all OE-Core supported target arches (user overridable).
  46. #
  47. LLVM_TARGETS ?= "AMDGPU;${@get_llvm_host_arch(bb, d)}"
  48. ARM_INSTRUCTION_SET:armv5 = "arm"
  49. ARM_INSTRUCTION_SET:armv4t = "arm"
  50. EXTRA_OECMAKE += "-DLLVM_ENABLE_ASSERTIONS=OFF \
  51. -DLLVM_ENABLE_EXPENSIVE_CHECKS=OFF \
  52. -DLLVM_ENABLE_PIC=ON \
  53. -DLLVM_BINDINGS_LIST='' \
  54. -DLLVM_LINK_LLVM_DYLIB=ON \
  55. -DLLVM_ENABLE_FFI=ON \
  56. -DLLVM_ENABLE_RTTI=ON \
  57. -DFFI_INCLUDE_DIR=$(pkg-config --variable=includedir libffi) \
  58. -DLLVM_OPTIMIZED_TABLEGEN=ON \
  59. -DLLVM_TARGETS_TO_BUILD='${LLVM_TARGETS}' \
  60. -DLLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN=ON \
  61. -DCMAKE_BUILD_TYPE=Release \
  62. "
  63. EXTRA_OECMAKE:append:class-target = "\
  64. -DCMAKE_CROSSCOMPILING:BOOL=ON \
  65. -DLLVM_TABLEGEN=${STAGING_BINDIR_NATIVE}/llvm-tblgen${PV} \
  66. -DLLVM_CONFIG_PATH=${STAGING_BINDIR_NATIVE}/llvm-config${PV} \
  67. "
  68. EXTRA_OECMAKE:append:class-nativesdk = "\
  69. -DCMAKE_CROSSCOMPILING:BOOL=ON \
  70. -DLLVM_TABLEGEN=${STAGING_BINDIR_NATIVE}/llvm-tblgen${PV} \
  71. -DLLVM_CONFIG_PATH=${STAGING_BINDIR_NATIVE}/llvm-config${PV} \
  72. "
  73. # patch out build host paths for reproducibility
  74. do_compile:prepend:class-target() {
  75. sed -i -e "s,${WORKDIR},,g" ${B}/tools/llvm-config/BuildVariables.inc
  76. }
  77. do_compile() {
  78. if ${@bb.utils.contains('PACKAGECONFIG', 'libllvm', 'true', 'false', d)}; then
  79. ninja -v ${PARALLEL_MAKE}
  80. else
  81. ninja -v ${PARALLEL_MAKE} llvm-config llvm-tblgen
  82. fi
  83. }
  84. do_install() {
  85. if ${@bb.utils.contains('PACKAGECONFIG', 'libllvm', 'true', 'false', d)}; then
  86. DESTDIR=${D} ninja -v install
  87. # llvm harcodes usr/lib as install path, so this corrects it to actual libdir
  88. mv -T -n ${D}/${prefix}/lib ${D}/${libdir} || true
  89. # Remove opt-viewer: https://llvm.org/docs/Remarks.html
  90. rm -rf ${D}${datadir}/opt-viewer
  91. rmdir ${D}${datadir}
  92. # reproducibility
  93. sed -i -e 's,${WORKDIR},,g' ${D}/${libdir}/cmake/llvm/LLVMConfig.cmake
  94. fi
  95. }
  96. do_install:append:class-native() {
  97. install -D -m 0755 ${B}/bin/llvm-tblgen ${D}${bindir}/llvm-tblgen${PV}
  98. install -D -m 0755 ${B}/bin/llvm-config ${D}${bindir}/llvm-config${PV}
  99. ln -sf llvm-config${PV} ${D}${bindir}/llvm-config
  100. }
  101. SYSROOT_PREPROCESS_FUNCS:append:class-target = " llvm_sysroot_preprocess"
  102. llvm_sysroot_preprocess() {
  103. install -d ${SYSROOT_DESTDIR}${bindir_crossscripts}/
  104. install -m 0755 ${WORKDIR}/llvm-config ${SYSROOT_DESTDIR}${bindir_crossscripts}/
  105. ln -sf llvm-config ${SYSROOT_DESTDIR}${bindir_crossscripts}/llvm-config${PV}
  106. }
  107. PACKAGES =+ "${PN}-bugpointpasses ${PN}-llvmhello ${PN}-libllvm ${PN}-liboptremarks ${PN}-liblto"
  108. RRECOMMENDS:${PN}-dev += "${PN}-bugpointpasses ${PN}-llvmhello ${PN}-liboptremarks"
  109. FILES:${PN}-bugpointpasses = "\
  110. ${libdir}/BugpointPasses.so \
  111. "
  112. FILES:${PN}-libllvm = "\
  113. ${libdir}/libLLVM-${MAJOR_VERSION}.so \
  114. "
  115. FILES:${PN}-liblto += "\
  116. ${libdir}/libLTO.so.* \
  117. "
  118. FILES:${PN}-liboptremarks += "\
  119. ${libdir}/libRemarks.so.* \
  120. "
  121. FILES:${PN}-llvmhello = "\
  122. ${libdir}/LLVMHello.so \
  123. "
  124. FILES:${PN}-dev += " \
  125. ${libdir}/llvm-config \
  126. ${libdir}/libRemarks.so \
  127. ${libdir}/libLLVM-${PV}.so \
  128. "
  129. FILES:${PN}-staticdev += "\
  130. ${libdir}/*.a \
  131. "
  132. INSANE_SKIP:${PN}-libllvm += "dev-so"
  133. BBCLASSEXTEND = "native nativesdk"