libgcc.inc 1.7 KB

1234567891011121314151617181920212223242526272829303132333435363738394041424344454647484950515253
  1. require libgcc-common.inc
  2. DEPENDS = "virtual/${TARGET_PREFIX}gcc virtual/${TARGET_PREFIX}g++ virtual/${MLPREFIX}libc"
  3. do_install:append:class-target () {
  4. if [ "${TCLIBC}" != "glibc" ]; then
  5. case "${TARGET_OS}" in
  6. "linux-musl" | "linux-*spe") extra_target_os="linux";;
  7. "linux-musleabi") extra_target_os="linux-gnueabi";;
  8. *) extra_target_os="linux";;
  9. esac
  10. if [ ! -e ${D}${libdir}/${TARGET_ARCH}${TARGET_VENDOR}-$extra_target_os ]; then
  11. ln -s ${TARGET_SYS} ${D}${libdir}/${TARGET_ARCH}${TARGET_VENDOR}-$extra_target_os
  12. fi
  13. fi
  14. if [ -n "${@ bb.utils.contains('TUNE_CCARGS_MFLOAT', 'hard', 'hf', '', d)}" ]; then
  15. case "${TARGET_OS}" in
  16. "linux-musleabi") extra_target_os="linux-musleabihf";;
  17. "linux-gnueabi") extra_target_os="linux-gnueabihf";;
  18. esac
  19. if [ ! -e ${D}${libdir}/${TARGET_ARCH}${TARGET_VENDOR}-$extra_target_os ]; then
  20. ln -s ${TARGET_SYS} ${D}${libdir}/${TARGET_ARCH}${TARGET_VENDOR}-$extra_target_os
  21. fi
  22. fi
  23. }
  24. PACKAGES = "\
  25. ${PN} \
  26. ${PN}-dev \
  27. ${PN}-dbg \
  28. "
  29. # All libgcc source is marked with the exception.
  30. #
  31. LICENSE:${PN} = "GPL-3.0-with-GCC-exception"
  32. LICENSE:${PN}-dev = "GPL-3.0-with-GCC-exception"
  33. LICENSE:${PN}-dbg = "GPL-3.0-with-GCC-exception"
  34. FILES:${PN}-dev = "\
  35. ${base_libdir}/libgcc*.so \
  36. ${@oe.utils.conditional('BASETARGET_SYS', '${TARGET_SYS}', '', '${libdir}/${BASETARGET_SYS}', d)} \
  37. ${libdir}/${TARGET_SYS}/${BINV}* \
  38. ${libdir}/${TARGET_ARCH}${TARGET_VENDOR}* \
  39. "
  40. do_package[depends] += "virtual/${MLPREFIX}libc:do_packagedata"
  41. do_package_write_ipk[depends] += "virtual/${MLPREFIX}libc:do_packagedata"
  42. do_package_write_deb[depends] += "virtual/${MLPREFIX}libc:do_packagedata"
  43. do_package_write_rpm[depends] += "virtual/${MLPREFIX}libc:do_packagedata"
  44. INSANE_SKIP:${PN}-dev = "staticdev"