binutils_2.39.bb 3.0 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475
  1. require binutils.inc
  2. require binutils-${PV}.inc
  3. DEPENDS += "zlib"
  4. EXTRA_OECONF += "--with-sysroot=/ \
  5. --enable-install-libbfd \
  6. --enable-install-libiberty \
  7. --enable-shared \
  8. --with-system-zlib \
  9. "
  10. EXTRA_OEMAKE:append:libc-musl = "\
  11. gt_cv_func_gnugettext1_libc=yes \
  12. gt_cv_func_gnugettext2_libc=yes \
  13. "
  14. # libcollector/collector.c:547:15: error: no member named '__fprintf_chk' in 'struct CollectorUtilFuncs'
  15. EXTRA_OECONF:append:toolchain-clang = " --disable-gprofng"
  16. # | ../../../gprofng/libcollector/../src/collector_module.h:78:13: error: duplicate member 'pwrite'
  17. # | ../../../gprofng/libcollector/dispatcher.c:578:8: error: 'struct sigevent' has no member named '_sigev_un'
  18. EXTRA_OECONF:append:libc-musl = " --disable-gprofng"
  19. EXTRA_OECONF:class-native = "--enable-targets=all \
  20. --enable-64-bit-bfd \
  21. --enable-install-libiberty \
  22. --enable-install-libbfd \
  23. --disable-gdb \
  24. --disable-gdbserver \
  25. --disable-libdecnumber \
  26. --disable-readline \
  27. --disable-sim \
  28. --disable-werror"
  29. PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'debuginfod', d)}"
  30. PACKAGECONFIG[debuginfod] = "--with-debuginfod, --without-debuginfod, elfutils"
  31. do_install:class-native () {
  32. autotools_do_install
  33. # Install the libiberty header
  34. install -d ${D}${includedir}
  35. install -m 644 ${S}/include/ansidecl.h ${D}${includedir}
  36. install -m 644 ${S}/include/libiberty.h ${D}${includedir}
  37. # We only want libiberty, libbfd and libopcodes
  38. rm -rf ${D}${bindir}
  39. rm -rf ${D}${prefix}/${TARGET_SYS}
  40. rm -rf ${D}${prefix}/lib/ldscripts
  41. rm -rf ${D}${prefix}/share/info
  42. rm -rf ${D}${prefix}/share/locale
  43. rm -rf ${D}${prefix}/share/man
  44. rmdir ${D}${prefix}/share || :
  45. rmdir ${D}/${libdir}/gcc-lib || :
  46. rmdir ${D}/${libdir}64/gcc-lib || :
  47. rmdir ${D}/${libdir} || :
  48. rmdir ${D}/${libdir}64 || :
  49. }
  50. # libctf races with libbfd
  51. PARALLEL_MAKEINST:class-target = ""
  52. PARALLEL_MAKEINST:class-nativesdk = ""
  53. # Split out libbfd-*.so and libopcodes-*.so so including perf doesn't include
  54. # extra stuff
  55. PACKAGE_BEFORE_PN += "libbfd libopcodes gprofng"
  56. FILES:libbfd = "${libdir}/libbfd-*.so.* ${libdir}/libbfd-*.so"
  57. FILES:libopcodes = "${libdir}/libopcodes-*.so.* ${libdir}/libopcodes-*.so"
  58. FILES:gprofng = "${sysconfdir}/gprofng.rc ${libdir}/gprofng/libgp-*.so ${libdir}/gprofng/libgprofng.so.* ${bindir}/gp-* ${bindir}/gprofng"
  59. FILES:${PN}-dev += "${libdir}/gprofng/libgprofng.so"
  60. SRC_URI:append:class-nativesdk = " file://0003-binutils-nativesdk-Search-for-alternative-ld.so.conf.patch "
  61. USE_ALTERNATIVES_FOR:class-nativesdk = ""
  62. FILES:${PN}:append:class-nativesdk = " ${bindir}"
  63. BBCLASSEXTEND = "native nativesdk"