llvm_git.bb 6.0 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181
  1. # Copyright (C) 2017 Khem Raj <raj.khem@gmail.com>
  2. # Released under the MIT license (see COPYING.MIT for the terms)
  3. DESCRIPTION = "The LLVM Compiler Infrastructure"
  4. HOMEPAGE = "http://llvm.org"
  5. LICENSE = "Apache-2.0-with-LLVM-exception"
  6. SECTION = "devel"
  7. LIC_FILES_CHKSUM = "file://LICENSE.TXT;md5=8a15a0759ef07f2682d2ba4b893c9afe"
  8. DEPENDS = "libffi libxml2 zlib libedit ninja-native llvm-native"
  9. RDEPENDS_${PN}_append_class-target = " ncurses-terminfo"
  10. inherit cmake pkgconfig
  11. PROVIDES += "llvm${PV}"
  12. MAJOR_VERSION = "14"
  13. MINOR_VERSION = "0"
  14. PATCH_VERSION = "0"
  15. PV = "${MAJOR_VERSION}.${MINOR_VERSION}.${PATCH_VERSION}"
  16. LLVM_RELEASE = "${PV}"
  17. LLVM_DIR = "llvm${LLVM_RELEASE}"
  18. BRANCH = "main"
  19. SRCREV = "afab3c488f0c86af87e262cc7454e04de18e3e6a"
  20. SRC_URI = "git://github.com/llvm/llvm-project.git;branch=${BRANCH} \
  21. "
  22. UPSTREAM_CHECK_GITTAGREGEX = "llvmorg-(?P<pver>\d+(\.\d+)+)"
  23. S = "${WORKDIR}/git/llvm"
  24. LLVM_INSTALL_DIR = "${WORKDIR}/llvm-install"
  25. def get_llvm_arch(bb, d, arch_var):
  26. import re
  27. a = d.getVar(arch_var)
  28. if re.match(r'(i.86|athlon|x86.64)$', a): return 'X86'
  29. elif re.match(r'arm$', a): return 'ARM'
  30. elif re.match(r'armeb$', a): return 'ARM'
  31. elif re.match(r'aarch64$', a): return 'AArch64'
  32. elif re.match(r'aarch64_be$', a): return 'AArch64'
  33. elif re.match(r'mips(isa|)(32|64|)(r6|)(el|)$', a): return 'Mips'
  34. elif re.match(r'riscv(32|64)(eb|)$', a): return 'RISCV'
  35. elif re.match(r'p(pc|owerpc)(|64)', a): return 'PowerPC'
  36. else:
  37. raise bb.parse.SkipRecipe("Cannot map '%s' to a supported LLVM architecture" % a)
  38. def get_llvm_host_arch(bb, d):
  39. return get_llvm_arch(bb, d, 'HOST_ARCH')
  40. #
  41. # Default to build all OE-Core supported target arches (user overridable).
  42. #
  43. LLVM_TARGETS ?= "AMDGPU;${@get_llvm_host_arch(bb, d)}"
  44. ARM_INSTRUCTION_SET_armv5 = "arm"
  45. ARM_INSTRUCTION_SET_armv4t = "arm"
  46. EXTRA_OECMAKE += "-DLLVM_ENABLE_ASSERTIONS=OFF \
  47. -DLLVM_ENABLE_EXPENSIVE_CHECKS=OFF \
  48. -DLLVM_ENABLE_PIC=ON \
  49. -DLLVM_BINDINGS_LIST='' \
  50. -DLLVM_LINK_LLVM_DYLIB=ON \
  51. -DLLVM_ENABLE_FFI=ON \
  52. -DLLVM_ENABLE_RTTI=ON \
  53. -DFFI_INCLUDE_DIR=$(pkg-config --variable=includedir libffi) \
  54. -DLLVM_OPTIMIZED_TABLEGEN=ON \
  55. -DLLVM_TARGETS_TO_BUILD='${LLVM_TARGETS}' \
  56. -DLLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN=ON \
  57. -DPYTHON_EXECUTABLE=${HOSTTOOLS_DIR}/python3 \
  58. -G Ninja"
  59. EXTRA_OECMAKE_append_class-target = "\
  60. -DCMAKE_CROSSCOMPILING:BOOL=ON \
  61. -DLLVM_TABLEGEN=${STAGING_BINDIR_NATIVE}/llvm-tblgen${PV} \
  62. -DLLVM_CONFIG_PATH=${STAGING_BINDIR_NATIVE}/llvm-config${PV} \
  63. "
  64. EXTRA_OECMAKE_append_class-nativesdk = "\
  65. -DCMAKE_CROSSCOMPILING:BOOL=ON \
  66. -DLLVM_TABLEGEN=${STAGING_BINDIR_NATIVE}/llvm-tblgen${PV} \
  67. -DLLVM_CONFIG_PATH=${STAGING_BINDIR_NATIVE}/llvm-config${PV} \
  68. "
  69. CFLAGS += "-fcommon"
  70. do_configure_prepend() {
  71. # Fix paths in llvm-config
  72. sed -i "s|sys::path::parent_path(CurrentPath))\.str()|sys::path::parent_path(sys::path::parent_path(CurrentPath))).str()|g" ${S}/tools/llvm-config/llvm-config.cpp
  73. sed -ri "s#/(bin|include|lib)(/?\")#/\1/${LLVM_DIR}\2#g" ${S}/tools/llvm-config/llvm-config.cpp
  74. sed -ri "s#lib/${LLVM_DIR}#${baselib}/${LLVM_DIR}#g" ${S}/tools/llvm-config/llvm-config.cpp
  75. }
  76. do_compile() {
  77. ninja -v ${PARALLEL_MAKE}
  78. }
  79. do_compile_class-native() {
  80. ninja -v ${PARALLEL_MAKE} llvm-config llvm-tblgen
  81. }
  82. do_install() {
  83. DESTDIR=${LLVM_INSTALL_DIR} ninja -v install
  84. install -D -m 0755 ${B}/bin/llvm-config ${D}${libdir}/${LLVM_DIR}/llvm-config
  85. install -d ${D}${bindir}/${LLVM_DIR}
  86. cp -r ${LLVM_INSTALL_DIR}${bindir}/* ${D}${bindir}/${LLVM_DIR}/
  87. install -d ${D}${includedir}/${LLVM_DIR}
  88. cp -r ${LLVM_INSTALL_DIR}${includedir}/* ${D}${includedir}/${LLVM_DIR}/
  89. install -d ${D}${libdir}/${LLVM_DIR}
  90. # The LLVM sources have "/lib" embedded and so we cannot completely rely on the ${libdir} variable
  91. if [ -d ${LLVM_INSTALL_DIR}${libdir}/ ]; then
  92. cp -r ${LLVM_INSTALL_DIR}${libdir}/* ${D}${libdir}/${LLVM_DIR}/
  93. elif [ -d ${LLVM_INSTALL_DIR}${prefix}/lib ]; then
  94. cp -r ${LLVM_INSTALL_DIR}${prefix}/lib/* ${D}${libdir}/${LLVM_DIR}/
  95. elif [ -d ${LLVM_INSTALL_DIR}${prefix}/lib64 ]; then
  96. cp -r ${LLVM_INSTALL_DIR}${prefix}/lib64/* ${D}${libdir}/${LLVM_DIR}/
  97. fi
  98. # Remove unnecessary cmake files
  99. rm -rf ${D}${libdir}/${LLVM_DIR}/cmake
  100. ln -s ${LLVM_DIR}/libLLVM-${MAJOR_VERSION}${SOLIBSDEV} ${D}${libdir}/libLLVM-${MAJOR_VERSION}${SOLIBSDEV}
  101. # We'll have to delete the libLLVM.so due to multiple reasons...
  102. rm -rf ${D}${libdir}/${LLVM_DIR}/libLLVM.so
  103. rm -rf ${D}${libdir}/${LLVM_DIR}/libLTO.so
  104. }
  105. do_install_class-native() {
  106. install -D -m 0755 ${B}/bin/llvm-tblgen ${D}${bindir}/llvm-tblgen${PV}
  107. install -D -m 0755 ${B}/bin/llvm-config ${D}${bindir}/llvm-config${PV}
  108. install -D -m 0755 ${B}/lib/libLLVM-${MAJOR_VERSION}.so ${D}${libdir}/libLLVM-${MAJOR_VERSION}.so
  109. }
  110. PACKAGES =+ "${PN}-bugpointpasses ${PN}-llvmhello ${PN}-libllvm ${PN}-liboptremarks ${PN}-liblto"
  111. RRECOMMENDS_${PN}-dev += "${PN}-bugpointpasses ${PN}-llvmhello ${PN}-liboptremarks"
  112. FILES_${PN}-bugpointpasses = "\
  113. ${libdir}/${LLVM_DIR}/BugpointPasses.so \
  114. "
  115. FILES_${PN}-libllvm = "\
  116. ${libdir}/${LLVM_DIR}/libLLVM-${MAJOR_VERSION}.so \
  117. ${libdir}/libLLVM-${MAJOR_VERSION}.so \
  118. "
  119. FILES_${PN}-liblto += "\
  120. ${libdir}/${LLVM_DIR}/libLTO.so.* \
  121. "
  122. FILES_${PN}-liboptremarks += "\
  123. ${libdir}/${LLVM_DIR}/libRemarks.so.* \
  124. "
  125. FILES_${PN}-llvmhello = "\
  126. ${libdir}/${LLVM_DIR}/LLVMHello.so \
  127. "
  128. FILES_${PN}-dev += " \
  129. ${libdir}/${LLVM_DIR}/llvm-config \
  130. ${libdir}/${LLVM_DIR}/libRemarks.so \
  131. ${libdir}/${LLVM_DIR}/libLLVM-${MAJOR_VERSION}.${MINOR_VERSION}.${PATCH_VERSION}.so \
  132. "
  133. FILES_${PN}-staticdev += "\
  134. ${libdir}/${LLVM_DIR}/*.a \
  135. "
  136. INSANE_SKIP_${PN}-libllvm += "dev-so"
  137. BBCLASSEXTEND = "native nativesdk"