gdb-cross-canadian.inc 1.5 KB

123456789101112131415161718192021222324252627282930313233343536373839404142
  1. inherit cross-canadian
  2. inherit python3-dir
  3. SUMMARY = "GNU debugger (cross-canadian gdb for ${TARGET_ARCH} target)"
  4. PN = "gdb-cross-canadian-${TRANSLATED_TARGET_ARCH}"
  5. BPN = "gdb"
  6. DEPENDS = "nativesdk-ncurses nativesdk-expat nativesdk-gettext \
  7. virtual/${HOST_PREFIX}gcc-crosssdk virtual/${HOST_PREFIX}binutils-crosssdk virtual/nativesdk-libc bison-native"
  8. GDBPROPREFIX = "--program-prefix='${TARGET_PREFIX}'"
  9. # Overrides PACKAGECONFIG variables in gdb-common.inc
  10. PACKAGECONFIG ??= "python readline"
  11. PACKAGECONFIG[python] = "--with-python=${WORKDIR}/python,--without-python,nativesdk-python3, \
  12. nativesdk-python3-core \
  13. nativesdk-python3-codecs nativesdk-python3-netclient \
  14. "
  15. PACKAGECONFIG[readline] = "--with-system-readline,--without-system-readline,nativesdk-readline"
  16. SSTATE_ALLOW_OVERLAP_FILES += "${STAGING_DATADIR}/gdb"
  17. do_configure:prepend() {
  18. cat > ${WORKDIR}/python << EOF
  19. #! /bin/sh
  20. case "\$2" in
  21. --includes) echo "-I${STAGING_INCDIR}/${PYTHON_DIR}${PYTHON_ABI}/" ;;
  22. --ldflags) echo "-Wl,-rpath-link,${STAGING_LIBDIR}/.. -Wl,-rpath,${libdir}/.. -lpthread -ldl -lutil -lm -lpython${PYTHON_BASEVERSION}${PYTHON_ABI}" ;;
  23. --exec-prefix) echo "${exec_prefix}" ;;
  24. *) exit 1 ;;
  25. esac
  26. exit 0
  27. EOF
  28. chmod +x ${WORKDIR}/python
  29. }
  30. # we don't want gdb to provide bfd/iberty/opcodes, which instead will override the
  31. # right bits installed by binutils.
  32. do_install:append() {
  33. rm -rf ${D}${exec_prefix}/lib
  34. cross_canadian_bindirlinks
  35. }