gcc-runtime.inc 12 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318
  1. require gcc-configure-common.inc
  2. SUMMARY = "Runtime libraries from GCC"
  3. # Over-ride the LICENSE set by gcc-${PV}.inc to remove "& GPLv3"
  4. # All gcc-runtime packages are now covered by the runtime exception.
  5. LICENSE = "GPL-3.0-with-GCC-exception"
  6. CXXFLAGS:remove = "-fvisibility-inlines-hidden"
  7. EXTRA_OECONF_PATHS = "\
  8. --with-gxx-include-dir=${includedir}/c++/${BINV} \
  9. --with-sysroot=/not/exist \
  10. --with-build-sysroot=${STAGING_DIR_TARGET} \
  11. "
  12. EXTRA_OECONF:append:linuxstdbase = " --enable-clocale=gnu"
  13. EXTRA_OECONF:append = " --cache-file=${B}/config.cache"
  14. EXTRA_OECONF:append:libc-newlib = " --with-newlib"
  15. # Disable ifuncs for libatomic on arm conflicts -march/-mcpu
  16. EXTRA_OECONF:append:arm = " libat_cv_have_ifunc=no "
  17. EXTRA_OECONF:append:armeb = " libat_cv_have_ifunc=no "
  18. DISABLE_STATIC:class-nativesdk ?= ""
  19. # Newlib does not support symbol versioning on libsdtcc++
  20. SYMVERS_CONF:libc-newlib = ""
  21. # Building with thumb enabled on armv6t fails
  22. ARM_INSTRUCTION_SET:armv6 = "arm"
  23. RUNTIMELIBITM = "libitm"
  24. RUNTIMELIBITM:arc = ""
  25. RUNTIMELIBITM:mipsarch = ""
  26. RUNTIMELIBITM:nios2 = ""
  27. RUNTIMELIBITM:microblaze = ""
  28. RUNTIMELIBITM:riscv32 = ""
  29. RUNTIMELIBITM:riscv64 = ""
  30. RUNTIMELIBSSP ?= ""
  31. RUNTIMELIBSSP:mingw32 ?= "libssp"
  32. RUNTIMETARGET = "${RUNTIMELIBSSP} libstdc++-v3 libgomp libatomic ${RUNTIMELIBITM} \
  33. ${@bb.utils.contains_any('FORTRAN', [',fortran',',f77'], 'libquadmath', '', d)} \
  34. "
  35. # Only build libstdc++ for newlib
  36. RUNTIMETARGET:libc-newlib = "libstdc++-v3"
  37. # libiberty
  38. # libgfortran needs separate recipe due to libquadmath dependency
  39. # Relative path to be repaced into debug info
  40. REL_S = "/usr/src/debug/${PN}/${EXTENDPE}${PV}-${PR}"
  41. DEBUG_PREFIX_MAP:class-target = " \
  42. -fdebug-prefix-map=${WORKDIR}/recipe-sysroot= \
  43. -fdebug-prefix-map=${WORKDIR}/recipe-sysroot-native= \
  44. -fdebug-prefix-map=${S}=${REL_S} \
  45. -fdebug-prefix-map=${S}/include=${REL_S}/libstdc++-v3/../include \
  46. -fdebug-prefix-map=${S}/libiberty=${REL_S}/libstdc++-v3/../libiberty \
  47. -fdebug-prefix-map=${S}/libgcc=${REL_S}/libstdc++-v3/../libgcc \
  48. -fdebug-prefix-map=${B}=${REL_S} \
  49. -ffile-prefix-map=${B}/${HOST_SYS}/libstdc++-v3/include=${includedir}/c++/${BINV} \
  50. "
  51. do_configure () {
  52. export CXX="${CXX} -nostdinc++ -nostdlib++"
  53. for d in libgcc ${RUNTIMETARGET}; do
  54. echo "Configuring $d"
  55. rm -rf ${B}/${TARGET_SYS}/$d/
  56. mkdir -p ${B}/${TARGET_SYS}/$d/
  57. cd ${B}/${TARGET_SYS}/$d/
  58. chmod a+x ${S}/$d/configure
  59. relpath=${@os.path.relpath("${S}/$d", "${B}/${TARGET_SYS}/$d")}
  60. $relpath/configure ${CONFIGUREOPTS} ${EXTRA_OECONF}
  61. if [ "$d" = "libgcc" ]; then
  62. (cd ${B}/${TARGET_SYS}/libgcc; oe_runmake enable-execute-stack.c unwind.h md-unwind-support.h sfp-machine.h gthr-default.h)
  63. fi
  64. done
  65. }
  66. EXTRACONFFUNCS += "extract_stashed_builddir"
  67. do_configure[depends] += "${COMPILERDEP}"
  68. do_compile () {
  69. for d in libgcc ${RUNTIMETARGET}; do
  70. cd ${B}/${TARGET_SYS}/$d/
  71. oe_runmake MULTIBUILDTOP=${B}/${TARGET_SYS}/$d/
  72. done
  73. }
  74. do_install () {
  75. for d in ${RUNTIMETARGET}; do
  76. cd ${B}/${TARGET_SYS}/$d/
  77. oe_runmake 'DESTDIR=${D}' MULTIBUILDTOP=${B}/${TARGET_SYS}/$d/ install
  78. done
  79. if [ -d ${D}${libdir}/gcc/${TARGET_SYS}/${BINV}/include ]; then
  80. install -d ${D}${libdir}/${TARGET_SYS}/${BINV}/include
  81. mv ${D}${libdir}/gcc/${TARGET_SYS}/${BINV}/include/* ${D}${libdir}/${TARGET_SYS}/${BINV}/include
  82. rmdir --ignore-fail-on-non-empty -p ${D}${libdir}/gcc/${TARGET_SYS}/${BINV}/include
  83. fi
  84. rm -rf ${D}${infodir}/libgomp.info ${D}${infodir}/dir
  85. rm -rf ${D}${infodir}/libitm.info ${D}${infodir}/dir
  86. rm -rf ${D}${infodir}/libquadmath.info ${D}${infodir}/dir
  87. if [ -d ${D}${libdir}/gcc/${TARGET_SYS}/${BINV}/finclude ]; then
  88. rmdir --ignore-fail-on-non-empty -p ${D}${libdir}/gcc/${TARGET_SYS}/${BINV}/finclude
  89. fi
  90. if [ -d ${D}${infodir} ]; then
  91. rmdir --ignore-fail-on-non-empty -p ${D}${infodir}
  92. fi
  93. }
  94. do_install:append:class-target () {
  95. if [ "${TARGET_OS}" = "linux-gnuspe" ]; then
  96. ln -s ${TARGET_SYS} ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR}-linux
  97. fi
  98. if [ "${TARGET_OS}" = "linux-gnun32" ]; then
  99. if [ "${TARGET_VENDOR_MULTILIB_ORIGINAL}" != "" -a "${TARGET_VENDOR}" != "${TARGET_VENDOR_MULTILIB_ORIGINAL}" ]; then
  100. mkdir ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR_MULTILIB_ORIGINAL}-linux
  101. ln -s ../${TARGET_SYS} ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR_MULTILIB_ORIGINAL}-linux/32
  102. elif [ "${MULTILIB_VARIANTS}" != "" ]; then
  103. mkdir ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR}-linux
  104. ln -s ../${TARGET_SYS} ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR}-linux/32
  105. else
  106. ln -s ${TARGET_SYS} ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR}-linux
  107. fi
  108. elif [ "${TARGET_OS}" = "linux-gnux32" ]; then
  109. if [ "${TARGET_VENDOR_MULTILIB_ORIGINAL}" != "" -a "${TARGET_VENDOR}" != "${TARGET_VENDOR_MULTILIB_ORIGINAL}" ]; then
  110. mkdir ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR_MULTILIB_ORIGINAL}-linux
  111. ln -s ../${TARGET_SYS} ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR_MULTILIB_ORIGINAL}-linux/x32
  112. elif [ "${MULTILIB_VARIANTS}" != "" ]; then
  113. mkdir ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR}-linux
  114. ln -s ../${TARGET_SYS} ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR}-linux/32
  115. else
  116. ln -s ${TARGET_SYS} ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR}-linux
  117. fi
  118. elif [ "${TARGET_VENDOR_MULTILIB_ORIGINAL}" != "" -a "${TARGET_VENDOR}" != "${TARGET_VENDOR_MULTILIB_ORIGINAL}" ]; then
  119. mkdir ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR_MULTILIB_ORIGINAL}-${TARGET_OS}
  120. ln -s ../${TARGET_SYS}/bits ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR_MULTILIB_ORIGINAL}-${TARGET_OS}/bits
  121. ln -s ../${TARGET_SYS}/ext ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR_MULTILIB_ORIGINAL}-${TARGET_OS}/ext
  122. fi
  123. if [ "${TARGET_ARCH}" == "x86_64" -a "${MULTILIB_VARIANTS}" != "" ];then
  124. ln -sf ../${X86ARCH32}${TARGET_VENDOR}-${TARGET_OS} ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR}-${TARGET_OS}/32
  125. fi
  126. if [ "${TCLIBC}" != "glibc" ]; then
  127. case "${TARGET_OS}" in
  128. "linux-musl" | "linux-*spe") extra_target_os="linux";;
  129. "linux-musleabi") extra_target_os="linux-gnueabi";;
  130. *) extra_target_os="linux";;
  131. esac
  132. ln -s ${TARGET_SYS} ${D}${includedir}/c++/${BINV}/${TARGET_ARCH}${TARGET_VENDOR}-$extra_target_os
  133. fi
  134. chown -R root:root ${D}
  135. }
  136. INHIBIT_DEFAULT_DEPS = "1"
  137. DEPENDS = "virtual/${TARGET_PREFIX}gcc virtual/${TARGET_PREFIX}g++ libgcc virtual/${MLPREFIX}libc"
  138. PROVIDES = "virtual/${TARGET_PREFIX}compilerlibs"
  139. BBCLASSEXTEND = "nativesdk"
  140. PACKAGES = "\
  141. ${PN}-dbg \
  142. libstdc++ \
  143. libstdc++-precompile-dev \
  144. libstdc++-dev \
  145. libstdc++-staticdev \
  146. libg2c \
  147. libg2c-dev \
  148. libssp \
  149. libssp-dev \
  150. libssp-staticdev \
  151. libquadmath \
  152. libquadmath-dev \
  153. libquadmath-staticdev \
  154. libgomp \
  155. libgomp-dev \
  156. libgomp-staticdev \
  157. libatomic \
  158. libatomic-dev \
  159. libatomic-staticdev \
  160. libitm \
  161. libitm-dev \
  162. libitm-staticdev \
  163. "
  164. # The base package doesn't exist, so we clear the recommends.
  165. RRECOMMENDS:${PN}-dbg = ""
  166. # include python debugging scripts
  167. FILES:${PN}-dbg += "\
  168. ${libdir}/libstdc++.*-gdb.py \
  169. ${datadir}/gcc-${BINV}/python/libstdcxx \
  170. "
  171. FILES:libg2c = "${target_libdir}/libg2c.so.*"
  172. SUMMARY:libg2c = "Companion runtime library for g77"
  173. FILES:libg2c-dev = "\
  174. ${libdir}/libg2c.so \
  175. ${libdir}/libg2c.a \
  176. ${libdir}/libfrtbegin.a \
  177. "
  178. SUMMARY:libg2c-dev = "Companion runtime library for g77 - development files"
  179. FILES:libstdc++ = "${libdir}/libstdc++.so.*"
  180. SUMMARY:libstdc++ = "GNU standard C++ library"
  181. FILES:libstdc++-dev = "\
  182. ${includedir}/c++/ \
  183. ${libdir}/libstdc++.so \
  184. ${libdir}/libstdc++*.la \
  185. ${libdir}/libsupc++.la \
  186. "
  187. SUMMARY:libstdc++-dev = "GNU standard C++ library - development files"
  188. FILES:libstdc++-staticdev = "\
  189. ${libdir}/libstdc++*.a \
  190. ${libdir}/libsupc++.a \
  191. "
  192. SUMMARY:libstdc++-staticdev = "GNU standard C++ library - static development files"
  193. FILES:libstdc++-precompile-dev = "${includedir}/c++/${TARGET_SYS}/bits/*.gch"
  194. SUMMARY:libstdc++-precompile-dev = "GNU standard C++ library - precompiled header files"
  195. FILES:libssp = "${libdir}/libssp.so.*"
  196. SUMMARY:libssp = "GNU stack smashing protection library"
  197. FILES:libssp-dev = "\
  198. ${libdir}/libssp*.so \
  199. ${libdir}/libssp*_nonshared.a \
  200. ${libdir}/libssp*.la \
  201. ${libdir}/${TARGET_SYS}/${BINV}/include/ssp \
  202. "
  203. SUMMARY:libssp-dev = "GNU stack smashing protection library - development files"
  204. FILES:libssp-staticdev = "${libdir}/libssp*.a"
  205. SUMMARY:libssp-staticdev = "GNU stack smashing protection library - static development files"
  206. FILES:libquadmath = "${libdir}/libquadmath*.so.*"
  207. SUMMARY:libquadmath = "GNU quad-precision math library"
  208. FILES:libquadmath-dev = "\
  209. ${libdir}/${TARGET_SYS}/${BINV}/include/quadmath* \
  210. ${libdir}/libquadmath*.so \
  211. ${libdir}/libquadmath.la \
  212. "
  213. SUMMARY:libquadmath-dev = "GNU quad-precision math library - development files"
  214. FILES:libquadmath-staticdev = "${libdir}/libquadmath.a"
  215. SUMMARY:libquadmath-staticdev = "GNU quad-precision math library - static development files"
  216. FILES:libgomp = "${libdir}/libgomp*${SOLIBS}"
  217. SUMMARY:libgomp = "GNU OpenMP parallel programming library"
  218. FILES:libgomp-dev = "\
  219. ${libdir}/libgomp*${SOLIBSDEV} \
  220. ${libdir}/libgomp*.la \
  221. ${libdir}/libgomp.spec \
  222. ${libdir}/${TARGET_SYS}/${BINV}/include/acc_prof.h \
  223. ${libdir}/${TARGET_SYS}/${BINV}/include/omp.h \
  224. ${libdir}/${TARGET_SYS}/${BINV}/include/openacc.h \
  225. "
  226. SUMMARY:libgomp-dev = "GNU OpenMP parallel programming library - development files"
  227. FILES:libgomp-staticdev = "${libdir}/libgomp*.a"
  228. SUMMARY:libgomp-staticdev = "GNU OpenMP parallel programming library - static development files"
  229. FILES:libatomic = "${libdir}/libatomic.so.*"
  230. SUMMARY:libatomic = "GNU C++11 atomics support library"
  231. FILES:libatomic-dev = "\
  232. ${libdir}/libatomic.so \
  233. ${libdir}/libatomic.la \
  234. "
  235. SUMMARY:libatomic-dev = "GNU C++11 atomics support library - development files"
  236. FILES:libatomic-staticdev = "${libdir}/libatomic.a"
  237. SUMMARY:libatomic-staticdev = "GNU C++11 atomics support library - static development files"
  238. FILES:libitm = "${libdir}/libitm.so.*"
  239. SUMMARY:libitm = "GNU transactional memory support library"
  240. FILES:libitm-dev = "\
  241. ${libdir}/libitm.so \
  242. ${libdir}/libitm.la \
  243. ${libdir}/libitm.spec \
  244. "
  245. SUMMARY:libitm-dev = "GNU transactional memory support library - development files"
  246. FILES:libitm-staticdev = "${libdir}/libitm.a"
  247. SUMMARY:libitm-staticdev = "GNU transactional memory support library - static development files"
  248. require gcc-testsuite.inc
  249. EXTRA_OEMAKE:prepend:task-check = "${PARALLEL_MAKE} "
  250. MAKE_CHECK_TARGETS ??= "check-gcc ${@" ".join("check-target-" + i for i in d.getVar("RUNTIMETARGET").split())}"
  251. # prettyprinters and xmethods require gdb tooling
  252. MAKE_CHECK_IGNORE ??= "prettyprinters.exp xmethods.exp"
  253. MAKE_CHECK_RUNTESTFLAGS ??= "${MAKE_CHECK_BOARDARGS} --ignore '${MAKE_CHECK_IGNORE}'"
  254. # specific host and target dependencies required for test suite running
  255. do_check[depends] += "dejagnu-native:do_populate_sysroot expect-native:do_populate_sysroot"
  256. do_check[depends] += "virtual/libc:do_populate_sysroot"
  257. # only depend on qemu if targeting linux user execution
  258. do_check[depends] += "${@'qemu-native:do_populate_sysroot' if "user" in d.getVar('TOOLCHAIN_TEST_TARGET') else ''}"
  259. # extend the recipe sysroot to include the built libraries (for qemu usermode)
  260. do_check[prefuncs] += "extend_recipe_sysroot"
  261. do_check[prefuncs] += "check_prepare"
  262. do_check[dirs] = "${WORKDIR}/dejagnu ${B}"
  263. do_check[nostamp] = "1"
  264. do_check() {
  265. export DEJAGNU="${WORKDIR}/dejagnu/site.exp"
  266. # HACK: this works around the configure setting CXX with -nostd* args
  267. sed -i 's/-nostdinc++ -nostdlib++//g' $(find ${B} -name testsuite_flags | head -1)
  268. if [ "${TOOLCHAIN_TEST_TARGET}" = "user" ]; then
  269. # qemu user has issues allocating large amounts of memory
  270. export G_SLICE=always-malloc
  271. # no test should need more that 10G of memory, this prevents tests like pthread7-rope from leaking memory
  272. ulimit -m 4194304
  273. ulimit -v 10485760
  274. fi
  275. oe_runmake -i ${MAKE_CHECK_TARGETS} RUNTESTFLAGS="${MAKE_CHECK_RUNTESTFLAGS}"
  276. }
  277. addtask check after do_compile do_populate_sysroot