llvm_git.bb 6.7 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190
  1. # Copyright (C) 2017 Khem Raj <raj.khem@gmail.com>
  2. # Released under the MIT license (see COPYING.MIT for the terms)
  3. DESCRIPTION = "The LLVM Compiler Infrastructure"
  4. HOMEPAGE = "http://llvm.org"
  5. LICENSE = "Apache-2.0-with-LLVM-exception"
  6. SECTION = "devel"
  7. LIC_FILES_CHKSUM = "file://LICENSE.TXT;md5=8a15a0759ef07f2682d2ba4b893c9afe"
  8. DEPENDS = "libffi libxml2 zlib libedit ninja-native llvm-native"
  9. RDEPENDS:${PN}:append:class-target = " ncurses-terminfo"
  10. inherit cmake pkgconfig
  11. PROVIDES += "llvm${PV}"
  12. PV = "14.0.0"
  13. MAJOR_VERSION = "${@oe.utils.trim_version("${PV}", 1)}"
  14. LLVM_RELEASE = "${PV}"
  15. LLVM_DIR = "llvm${LLVM_RELEASE}"
  16. FILES:${PN}:class-nativesdk += "/usr/local/oe-sdk-hardcoded-buildpath/sysroots/x86_64-oesdk-linux/usr/lib/llvm14.0.0/libLLVM-14git.so \
  17. /usr/local/oe-sdk-hardcoded-buildpath/sysroots/x86_64-oesdk-linux/usr/lib/llvm14.0.0/libLLVM-14.0.0git.so \
  18. /usr/local/oe-sdk-hardcoded-buildpath/sysroots/x86_64-oesdk-linux/usr/bin/llvm14.0.0/* \
  19. "
  20. BRANCH = "main"
  21. SRCREV = "afab3c488f0c86af87e262cc7454e04de18e3e6a"
  22. SRC_URI = "git://github.com/llvm/llvm-project.git;branch=${BRANCH};protocol=https \
  23. file://0006-llvm-TargetLibraryInfo-Undefine-libc-functions-if-th.patch;striplevel=2 \
  24. file://0007-llvm-allow-env-override-of-exe-path.patch;striplevel=2 \
  25. file://0001-AsmMatcherEmitter-sort-ClassInfo-lists-by-name-as-we.patch;striplevel=2 \
  26. "
  27. UPSTREAM_CHECK_GITTAGREGEX = "llvmorg-(?P<pver>\d+(\.\d+)+)"
  28. S = "${WORKDIR}/git/llvm"
  29. LLVM_INSTALL_DIR = "${WORKDIR}/llvm-install"
  30. def get_llvm_arch(bb, d, arch_var):
  31. import re
  32. a = d.getVar(arch_var)
  33. if re.match(r'(i.86|athlon|x86.64)$', a): return 'X86'
  34. elif re.match(r'arm$', a): return 'ARM'
  35. elif re.match(r'armeb$', a): return 'ARM'
  36. elif re.match(r'aarch64$', a): return 'AArch64'
  37. elif re.match(r'aarch64_be$', a): return 'AArch64'
  38. elif re.match(r'mips(isa|)(32|64|)(r6|)(el|)$', a): return 'Mips'
  39. elif re.match(r'riscv(32|64)(eb|)$', a): return 'RISCV'
  40. elif re.match(r'p(pc|owerpc)(|64)', a): return 'PowerPC'
  41. else:
  42. raise bb.parse.SkipRecipe("Cannot map '%s' to a supported LLVM architecture" % a)
  43. def get_llvm_host_arch(bb, d):
  44. return get_llvm_arch(bb, d, 'HOST_ARCH')
  45. #
  46. # Default to build all OE-Core supported target arches (user overridable).
  47. #
  48. LLVM_TARGETS ?= "AMDGPU;${@get_llvm_host_arch(bb, d)}"
  49. ARM_INSTRUCTION_SET:armv5 = "arm"
  50. ARM_INSTRUCTION_SET:armv4t = "arm"
  51. EXTRA_OECMAKE += "-DLLVM_ENABLE_ASSERTIONS=OFF \
  52. -DLLVM_ENABLE_EXPENSIVE_CHECKS=OFF \
  53. -DLLVM_ENABLE_PIC=ON \
  54. -DLLVM_BINDINGS_LIST='' \
  55. -DLLVM_LINK_LLVM_DYLIB=ON \
  56. -DLLVM_ENABLE_FFI=ON \
  57. -DLLVM_ENABLE_RTTI=ON \
  58. -DFFI_INCLUDE_DIR=$(pkg-config --variable=includedir libffi) \
  59. -DLLVM_OPTIMIZED_TABLEGEN=ON \
  60. -DLLVM_TARGETS_TO_BUILD='${LLVM_TARGETS}' \
  61. -DLLVM_TEMPORARILY_ALLOW_OLD_TOOLCHAIN=ON \
  62. -DPYTHON_EXECUTABLE=${HOSTTOOLS_DIR}/python3 \
  63. -G Ninja"
  64. EXTRA_OECMAKE:append:class-target = "\
  65. -DCMAKE_CROSSCOMPILING:BOOL=ON \
  66. -DLLVM_TABLEGEN=${STAGING_BINDIR_NATIVE}/llvm-tblgen${PV} \
  67. -DLLVM_CONFIG_PATH=${STAGING_BINDIR_NATIVE}/llvm-config${PV} \
  68. "
  69. EXTRA_OECMAKE:append:class-nativesdk = "\
  70. -DCMAKE_CROSSCOMPILING:BOOL=ON \
  71. -DLLVM_TABLEGEN=${STAGING_BINDIR_NATIVE}/llvm-tblgen${PV} \
  72. -DLLVM_CONFIG_PATH=${STAGING_BINDIR_NATIVE}/llvm-config${PV} \
  73. "
  74. do_configure:prepend() {
  75. # Fix paths in llvm-config
  76. sed -i "s|sys::path::parent_path(CurrentPath))\.str()|sys::path::parent_path(sys::path::parent_path(CurrentPath))).str()|g" ${S}/tools/llvm-config/llvm-config.cpp
  77. sed -ri "s#/(bin|include|lib)(/?\")#/\1/${LLVM_DIR}\2#g" ${S}/tools/llvm-config/llvm-config.cpp
  78. sed -ri "s#lib/${LLVM_DIR}#${baselib}/${LLVM_DIR}#g" ${S}/tools/llvm-config/llvm-config.cpp
  79. }
  80. # patch out build host paths for reproducibility
  81. do_compile:prepend:class-target() {
  82. sed -i -e "s,${WORKDIR},,g" ${B}/tools/llvm-config/BuildVariables.inc
  83. }
  84. do_compile() {
  85. ninja -v ${PARALLEL_MAKE}
  86. }
  87. do_compile:class-native() {
  88. ninja -v ${PARALLEL_MAKE} llvm-config llvm-tblgen
  89. }
  90. do_install() {
  91. DESTDIR=${LLVM_INSTALL_DIR} ninja -v install
  92. install -D -m 0755 ${B}/bin/llvm-config ${D}${libdir}/${LLVM_DIR}/llvm-config
  93. install -d ${D}${bindir}/${LLVM_DIR}
  94. cp -r ${LLVM_INSTALL_DIR}${bindir}/* ${D}${bindir}/${LLVM_DIR}/
  95. install -d ${D}${includedir}/${LLVM_DIR}
  96. cp -r ${LLVM_INSTALL_DIR}${includedir}/* ${D}${includedir}/${LLVM_DIR}/
  97. install -d ${D}${libdir}/${LLVM_DIR}
  98. # The LLVM sources have "/lib" embedded and so we cannot completely rely on the ${libdir} variable
  99. if [ -d ${LLVM_INSTALL_DIR}${libdir}/ ]; then
  100. cp -r ${LLVM_INSTALL_DIR}${libdir}/* ${D}${libdir}/${LLVM_DIR}/
  101. elif [ -d ${LLVM_INSTALL_DIR}${prefix}/lib ]; then
  102. cp -r ${LLVM_INSTALL_DIR}${prefix}/lib/* ${D}${libdir}/${LLVM_DIR}/
  103. elif [ -d ${LLVM_INSTALL_DIR}${prefix}/lib64 ]; then
  104. cp -r ${LLVM_INSTALL_DIR}${prefix}/lib64/* ${D}${libdir}/${LLVM_DIR}/
  105. fi
  106. # Remove unnecessary cmake files
  107. rm -rf ${D}${libdir}/${LLVM_DIR}/cmake
  108. ln -s ${LLVM_DIR}/libLLVM-${MAJOR_VERSION}${SOLIBSDEV} ${D}${libdir}/libLLVM-${MAJOR_VERSION}${SOLIBSDEV}
  109. # We'll have to delete the libLLVM.so due to multiple reasons...
  110. rm -rf ${D}${libdir}/${LLVM_DIR}/libLLVM.so
  111. rm -rf ${D}${libdir}/${LLVM_DIR}/libLTO.so
  112. }
  113. do_install:class-native() {
  114. install -D -m 0755 ${B}/bin/llvm-tblgen ${D}${bindir}/llvm-tblgen${PV}
  115. install -D -m 0755 ${B}/bin/llvm-config ${D}${bindir}/llvm-config${PV}
  116. install -D -m 0755 ${B}/lib/libLLVM-${MAJOR_VERSION}.so ${D}${libdir}/libLLVM-${MAJOR_VERSION}.so
  117. }
  118. PACKAGES =+ "${PN}-bugpointpasses ${PN}-llvmhello ${PN}-libllvm ${PN}-liboptremarks ${PN}-liblto"
  119. RRECOMMENDS:${PN}-dev += "${PN}-bugpointpasses ${PN}-llvmhello ${PN}-liboptremarks"
  120. FILES:${PN}-bugpointpasses = "\
  121. ${libdir}/${LLVM_DIR}/BugpointPasses.so \
  122. "
  123. FILES:${PN}-libllvm = "\
  124. ${libdir}/${LLVM_DIR}/libLLVM-${MAJOR_VERSION}.so \
  125. ${libdir}/libLLVM-${MAJOR_VERSION}.so \
  126. "
  127. FILES:${PN}-liblto += "\
  128. ${libdir}/${LLVM_DIR}/libLTO.so.* \
  129. "
  130. FILES:${PN}-liboptremarks += "\
  131. ${libdir}/${LLVM_DIR}/libRemarks.so.* \
  132. "
  133. FILES:${PN}-llvmhello = "\
  134. ${libdir}/${LLVM_DIR}/LLVMHello.so \
  135. "
  136. FILES:${PN}-dev += " \
  137. ${libdir}/${LLVM_DIR}/llvm-config \
  138. ${libdir}/${LLVM_DIR}/libRemarks.so \
  139. ${libdir}/${LLVM_DIR}/libLLVM-${PV}.so \
  140. "
  141. FILES:${PN}-staticdev += "\
  142. ${libdir}/${LLVM_DIR}/*.a \
  143. "
  144. INSANE_SKIP:${PN}-libllvm += "dev-so"
  145. BBCLASSEXTEND = "native nativesdk"