compiler-rt-sanitizers_16.0.5.bb 5.0 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116
  1. # Copyright (C) 2021 Khem Raj <raj.khem@gmail.com>
  2. # Released under the MIT license (see COPYING.MIT for the terms)
  3. DESCRIPTION = "LLVM based C/C++ compiler Runtime"
  4. HOMEPAGE = "http://compiler-rt.llvm.org/"
  5. SECTION = "base"
  6. require clang.inc
  7. require common-source.inc
  8. inherit cmake pkgconfig python3native
  9. LIC_FILES_CHKSUM = "file://compiler-rt/LICENSE.TXT;md5=d846d1d65baf322d4c485d6ee54e877a"
  10. TUNE_CCARGS:remove = "-no-integrated-as"
  11. DEPENDS += "ninja-native virtual/crypt"
  12. DEPENDS:append:class-native = " clang-native libxcrypt-native"
  13. DEPENDS:append:class-nativesdk = " clang-native clang-crosssdk-${SDK_ARCH} nativesdk-libxcrypt"
  14. PACKAGECONFIG ??= ""
  15. PACKAGECONFIG[crt] = "-DCOMPILER_RT_BUILD_CRT:BOOL=ON,-DCOMPILER_RT_BUILD_CRT:BOOL=OFF"
  16. PACKAGECONFIG[static-libcxx] = "-DSANITIZER_USE_STATIC_CXX_ABI=ON -DSANITIZER_USE_STATIC_LLVM_UNWINDER=ON -DCOMPILER_RT_ENABLE_STATIC_UNWINDER=ON,,"
  17. HF = ""
  18. HF:class-target = "${@ bb.utils.contains('TUNE_CCARGS_MFLOAT', 'hard', 'hf', '', d)}"
  19. HF[vardepvalue] = "${HF}"
  20. CXXFLAGS:append:libc-musl = " -D_LARGEFILE64_SOURCE"
  21. OECMAKE_TARGET_COMPILE = "compiler-rt"
  22. OECMAKE_TARGET_INSTALL = "install-compiler-rt install-compiler-rt-headers"
  23. OECMAKE_SOURCEPATH = "${S}/llvm"
  24. EXTRA_OECMAKE += "-DCMAKE_BUILD_TYPE=RelWithDebInfo \
  25. -DLLVM_ENABLE_PER_TARGET_RUNTIME_DIR=OFF \
  26. -DCOMPILER_RT_STANDALONE_BUILD=OFF \
  27. -DCOMPILER_RT_DEFAULT_TARGET_ONLY=ON \
  28. -DCOMPILER_RT_USE_BUILTINS_LIBRARY=ON \
  29. -DCMAKE_C_COMPILER_TARGET=${HOST_ARCH}${HF}${HOST_VENDOR}-${HOST_OS} \
  30. -DCOMPILER_RT_BUILD_BUILTINS=OFF \
  31. -DCOMPILER_RT_INCLUDE_TESTS=OFF \
  32. -DSANITIZER_CXX_ABI_LIBNAME=${@bb.utils.contains("RUNTIME", "llvm", "libc++", "libstdc++", d)} \
  33. -DCOMPILER_RT_BUILD_XRAY=ON \
  34. -DCOMPILER_RT_BUILD_SANITIZERS=ON \
  35. -DCOMPILER_RT_BUILD_LIBFUZZER=ON \
  36. -DCOMPILER_RT_BUILD_PROFILE=ON \
  37. -DCOMPILER_RT_BUILD_MEMPROF=ON \
  38. -DLLVM_ENABLE_PROJECTS='compiler-rt' \
  39. -DCMAKE_RANLIB=${STAGING_BINDIR_TOOLCHAIN}/${TARGET_PREFIX}llvm-ranlib \
  40. -DCMAKE_AR=${STAGING_BINDIR_TOOLCHAIN}/${TARGET_PREFIX}llvm-ar \
  41. -DCMAKE_NM=${STAGING_BINDIR_TOOLCHAIN}/${TARGET_PREFIX}llvm-nm \
  42. -DLLVM_LIBDIR_SUFFIX=${LLVM_LIBDIR_SUFFIX} \
  43. "
  44. EXTRA_OECMAKE:append:class-nativesdk = "\
  45. -DLLVM_TABLEGEN=${STAGING_BINDIR_NATIVE}/llvm-tblgen \
  46. -DCLANG_TABLEGEN=${STAGING_BINDIR_NATIVE}/clang-tblgen \
  47. "
  48. EXTRA_OECMAKE:append:class-target = "\
  49. -DCMAKE_POSITION_INDEPENDENT_CODE=ON \
  50. "
  51. EXTRA_OECMAKE:append:libc-musl = " -DLIBCXX_HAS_MUSL_LIBC=ON "
  52. EXTRA_OECMAKE:append:powerpc = " -DCOMPILER_RT_DEFAULT_TARGET_ARCH=powerpc "
  53. do_install:append () {
  54. if [ -n "${LLVM_LIBDIR_SUFFIX}" ]; then
  55. mkdir -p ${D}${nonarch_libdir}/clang
  56. mv ${D}${libdir}/clang/${MAJOR_VER} ${D}${nonarch_libdir}/clang/${MAJOR_VER}.${MINOR_VER}.${PATCH_VER}
  57. rmdir --ignore-fail-on-non-empty ${D}${libdir}
  58. else
  59. mv ${D}${libdir}/clang/${MAJOR_VER} ${D}${libdir}/clang/${MAJOR_VER}.${MINOR_VER}.${PATCH_VER}
  60. fi
  61. # Already shipped with compile-rt Orc support
  62. rm -rf ${D}${nonarch_libdir}/clang/${MAJOR_VER}.${MINOR_VER}.${PATCH_VER}/lib/linux/libclang_rt.orc-*.a
  63. rm -rf ${D}${nonarch_libdir}/clang/${MAJOR_VER}.${MINOR_VER}.${PATCH_VER}/include/orc/
  64. }
  65. FILES_SOLIBSDEV = ""
  66. FILES:${PN} += "${nonarch_libdir}/clang/${MAJOR_VER}.${MINOR_VER}.${PATCH_VER}/lib/linux/lib*${SOLIBSDEV} \
  67. ${nonarch_libdir}/clang/${MAJOR_VER}.${MINOR_VER}.${PATCH_VER}/*.txt \
  68. ${nonarch_libdir}/clang/${MAJOR_VER}.${MINOR_VER}.${PATCH_VER}/share/*.txt"
  69. FILES:${PN}-staticdev += "${nonarch_libdir}/clang/${MAJOR_VER}.${MINOR_VER}.${PATCH_VER}/lib/linux/*.a"
  70. FILES:${PN}-dev += "${datadir} ${nonarch_libdir}/clang/${MAJOR_VER}.${MINOR_VER}.${PATCH_VER}/lib/linux/*.syms \
  71. ${nonarch_libdir}/clang/${MAJOR_VER}.${MINOR_VER}.${PATCH_VER}/include \
  72. ${nonarch_libdir}/clang/${MAJOR_VER}.${MINOR_VER}.${PATCH_VER}/lib/linux/clang_rt.crt*.o \
  73. ${nonarch_libdir}/clang/${MAJOR_VER}.${MINOR_VER}.${PATCH_VER}/lib/linux/libclang_rt.asan-preinit*.a"
  74. INSANE_SKIP:${PN} = "dev-so libdir"
  75. INSANE_SKIP:${PN}-dbg = "libdir"
  76. #PROVIDES:append:class-target = "\
  77. # virtual/${TARGET_PREFIX}compilerlibs \
  78. # libgcc \
  79. # libgcc-initial \
  80. # libgcc-dev \
  81. # libgcc-initial-dev \
  82. # "
  83. #
  84. RDEPENDS:${PN}-dev += "${PN}-staticdev"
  85. BBCLASSEXTEND = "native nativesdk"
  86. ALLOW_EMPTY:${PN} = "1"
  87. ALLOW_EMPTY:${PN}-dev = "1"
  88. TOOLCHAIN:forcevariable = "clang"
  89. SYSROOT_DIRS:append:class-target = " ${nonarch_libdir}"
  90. # riscv and x86_64 Sanitizers work on musl too
  91. COMPATIBLE_HOST:libc-musl:x86-64 = "(.*)"
  92. COMPATIBLE_HOST:libc-musl:riscv64 = "(.*)"
  93. COMPATIBLE_HOST:libc-musl:riscv32 = "(.*)"
  94. COMPATIBLE_HOST:libc-musl = "null"