event_monitor_mac.mm 2.3 KB

1234567891011121314151617181920212223242526272829303132333435363738394041424344454647484950515253545556575859606162636465666768697071
  1. // Copyright 2014 The Chromium Authors. All rights reserved.
  2. // Use of this source code is governed by a BSD-style license that can be
  3. // found in the LICENSE file.
  4. #import "ui/views/event_monitor_mac.h"
  5. #import <Cocoa/Cocoa.h>
  6. #include "base/check.h"
  7. #include "base/memory/ptr_util.h"
  8. #include "ui/display/screen.h"
  9. #include "ui/events/event.h"
  10. #include "ui/events/event_observer.h"
  11. #include "ui/events/event_utils.h"
  12. namespace views {
  13. // static
  14. std::unique_ptr<EventMonitor> EventMonitor::CreateApplicationMonitor(
  15. ui::EventObserver* event_observer,
  16. gfx::NativeWindow context,
  17. const std::set<ui::EventType>& types) {
  18. // |context| is not needed on Mac.
  19. return std::make_unique<EventMonitorMac>(event_observer, nullptr, types);
  20. }
  21. // static
  22. std::unique_ptr<EventMonitor> EventMonitor::CreateWindowMonitor(
  23. ui::EventObserver* event_observer,
  24. gfx::NativeWindow target_window,
  25. const std::set<ui::EventType>& types) {
  26. return std::make_unique<EventMonitorMac>(event_observer, target_window,
  27. types);
  28. }
  29. EventMonitorMac::EventMonitorMac(ui::EventObserver* event_observer,
  30. gfx::NativeWindow target_native_window,
  31. const std::set<ui::EventType>& types)
  32. : factory_(this), types_(types) {
  33. DCHECK(event_observer);
  34. NSWindow* target_window = target_native_window.GetNativeNSWindow();
  35. // Capture a WeakPtr via NSObject. This allows the block to detect another
  36. // event monitor for the same event deleting |this|.
  37. WeakPtrNSObject* handle = factory_.handle();
  38. auto block = ^NSEvent*(NSEvent* event) {
  39. if (!ui::WeakPtrNSObjectFactory<EventMonitorMac>::Get(handle))
  40. return event;
  41. if (!target_window || [event window] == target_window) {
  42. std::unique_ptr<ui::Event> ui_event = ui::EventFromNative(event);
  43. if (ui_event && types_.find(ui_event->type()) != types_.end())
  44. event_observer->OnEvent(*ui_event);
  45. }
  46. return event;
  47. };
  48. monitor_ = [NSEvent addLocalMonitorForEventsMatchingMask:NSEventMaskAny
  49. handler:block];
  50. }
  51. EventMonitorMac::~EventMonitorMac() {
  52. [NSEvent removeMonitor:monitor_];
  53. }
  54. gfx::Point EventMonitorMac::GetLastMouseLocation() {
  55. return display::Screen::GetScreen()->GetCursorScreenPoint();
  56. }
  57. } // namespace views