libxml2-config.cmake.in 4.6 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115
  1. # libxml2-config.cmake
  2. # --------------------
  3. #
  4. # Libxml2 cmake module.
  5. # This module sets the following variables:
  6. #
  7. # ::
  8. #
  9. # LIBXML2_INCLUDE_DIR - Directory where LibXml2 headers are located.
  10. # LIBXML2_INCLUDE_DIRS - list of the include directories needed to use LibXml2.
  11. # LIBXML2_LIBRARY - path to the LibXml2 library.
  12. # LIBXML2_LIBRARIES - xml2 libraries to link against.
  13. # LIBXML2_DEFINITIONS - the compiler switches required for using LibXml2.
  14. # LIBXML2_VERSION_MAJOR - The major version of libxml2.
  15. # LIBXML2_VERSION_MINOR - The minor version of libxml2.
  16. # LIBXML2_VERSION_PATCH - The patch version of libxml2.
  17. # LIBXML2_VERSION_STRING - version number as a string (ex: "2.3.4")
  18. # LIBXML2_MODULES - whether libxml2 has dso support
  19. # LIBXML2_XMLLINT_EXECUTABLE - path to the XML checking tool xmllint coming with LibXml2
  20. #
  21. # The following targets are defined:
  22. #
  23. # LibXml2::LibXml2 - the LibXml2 library
  24. # LibXml2::xmllint - the xmllint command-line executable
  25. get_filename_component(_libxml2_rootdir ${CMAKE_CURRENT_LIST_DIR}/../../../ ABSOLUTE)
  26. set(LIBXML2_VERSION_MAJOR @LIBXML_MAJOR_VERSION@)
  27. set(LIBXML2_VERSION_MINOR @LIBXML_MINOR_VERSION@)
  28. set(LIBXML2_VERSION_MICRO @LIBXML_MICRO_VERSION@)
  29. set(LIBXML2_VERSION_STRING "@VERSION@")
  30. set(LIBXML2_DEFINITIONS "@XML_CFLAGS@")
  31. set(LIBXML2_INSTALL_PREFIX ${_libxml2_rootdir})
  32. set(LIBXML2_INCLUDE_DIR ${_libxml2_rootdir}/include/libxml2)
  33. set(LIBXML2_LIBRARY_DIR ${_libxml2_rootdir}/lib)
  34. find_library(LIBXML2_LIBRARY NAMES xml2 HINTS ${LIBXML2_LIBRARY_DIR} NO_DEFAULT_PATH)
  35. find_program(LIBXML2_XMLCATALOG_EXECUTABLE NAMES xmlcatalog HINTS ${_libxml2_rootdir}/bin NO_DEFAULT_PATH)
  36. find_program(LIBXML2_XMLLINT_EXECUTABLE NAMES xmllint HINTS ${_libxml2_rootdir}/bin NO_DEFAULT_PATH)
  37. set(LIBXML2_LIBRARIES ${LIBXML2_LIBRARY})
  38. set(LIBXML2_INCLUDE_DIRS ${LIBXML2_INCLUDE_DIR})
  39. unset(LIBXML2_INTERFACE_LINK_LIBRARIES)
  40. include(CMakeFindDependencyMacro)
  41. set(LIBXML2_WITH_ICONV @WITH_ICONV@)
  42. set(LIBXML2_WITH_THREADS @WITH_THREADS@)
  43. set(LIBXML2_WITH_ICU @WITH_ICU@)
  44. set(LIBXML2_WITH_LZMA @WITH_LZMA@)
  45. set(LIBXML2_WITH_ZLIB @WITH_ZLIB@)
  46. if(LIBXML2_WITH_ICONV)
  47. find_dependency(Iconv)
  48. list(APPEND LIBXML2_LIBRARIES ${Iconv_LIBRARIES})
  49. list(APPEND LIBXML2_INCLUDE_DIRS ${Iconv_INCLUDE_DIRS})
  50. list(APPEND LIBXML2_INTERFACE_LINK_LIBRARIES "Iconv::Iconv")
  51. endif()
  52. if(LIBXML2_WITH_THREADS)
  53. find_dependency(Threads)
  54. list(APPEND LIBXML2_LIBRARIES ${CMAKE_THREAD_LIBS_INIT})
  55. list(APPEND LIBXML2_INTERFACE_LINK_LIBRARIES "\$<LINK_ONLY:Threads::Threads>")
  56. endif()
  57. if(LIBXML2_WITH_ICU)
  58. find_dependency(ICU COMPONENTS data i18n uc)
  59. list(APPEND LIBXML2_LIBRARIES ${ICU_LIBRARIES})
  60. list(APPEND LIBXML2_INTERFACE_LINK_LIBRARIES "\$<LINK_ONLY:ICU::data>;\$<LINK_ONLY:ICU::i18n>;\$<LINK_ONLY:ICU::uc>")
  61. endif()
  62. if(LIBXML2_WITH_LZMA)
  63. find_dependency(LibLZMA)
  64. list(APPEND LIBXML2_LIBRARIES ${LIBLZMA_LIBRARIES})
  65. list(APPEND LIBXML2_INTERFACE_LINK_LIBRARIES "\$<LINK_ONLY:LibLZMA::LibLZMA>")
  66. endif()
  67. if(LIBXML2_WITH_ZLIB)
  68. find_dependency(ZLIB)
  69. list(APPEND LIBXML2_LIBRARIES ${ZLIB_LIBRARIES})
  70. list(APPEND LIBXML2_INTERFACE_LINK_LIBRARIES "\$<LINK_ONLY:ZLIB::ZLIB>")
  71. endif()
  72. if(UNIX)
  73. list(APPEND LIBXML2_LIBRARIES m)
  74. list(APPEND LIBXML2_INTERFACE_LINK_LIBRARIES "\$<LINK_ONLY:m>")
  75. endif()
  76. if(WIN32)
  77. list(APPEND LIBXML2_LIBRARIES ws2_32)
  78. list(APPEND LIBXML2_INTERFACE_LINK_LIBRARIES "\$<LINK_ONLY:ws2_32>")
  79. endif()
  80. # whether libxml2 has dso support
  81. set(LIBXML2_MODULES @WITH_MODULES@)
  82. mark_as_advanced(LIBXML2_LIBRARY LIBXML2_XMLCATALOG_EXECUTABLE LIBXML2_XMLLINT_EXECUTABLE)
  83. if(NOT TARGET LibXml2::LibXml2 AND DEFINED LIBXML2_LIBRARY AND DEFINED LIBXML2_INCLUDE_DIRS)
  84. add_library(LibXml2::LibXml2 UNKNOWN IMPORTED)
  85. set_target_properties(LibXml2::LibXml2 PROPERTIES IMPORTED_LOCATION "${LIBXML2_LIBRARY}")
  86. set_target_properties(LibXml2::LibXml2 PROPERTIES INTERFACE_COMPILE_OPTIONS "${LIBXML2_DEFINITIONS}")
  87. set_target_properties(LibXml2::LibXml2 PROPERTIES INTERFACE_INCLUDE_DIRECTORIES "${LIBXML2_INCLUDE_DIRS}")
  88. set_target_properties(LibXml2::LibXml2 PROPERTIES INTERFACE_LINK_LIBRARIES "${LIBXML2_INTERFACE_LINK_LIBRARIES}")
  89. endif()
  90. if(NOT TARGET LibXml2::xmlcatalog AND DEFINED LIBXML2_XMLCATALOG_EXECUTABLE)
  91. add_executable(LibXml2::xmlcatalog IMPORTED)
  92. set_target_properties(LibXml2::xmlcatalog PROPERTIES IMPORTED_LOCATION "${LIBXML2_XMLCATALOG_EXECUTABLE}")
  93. endif()
  94. if(NOT TARGET LibXml2::xmllint AND DEFINED LIBXML2_XMLLINT_EXECUTABLE)
  95. add_executable(LibXml2::xmllint IMPORTED)
  96. set_target_properties(LibXml2::xmllint PROPERTIES IMPORTED_LOCATION "${LIBXML2_XMLLINT_EXECUTABLE}")
  97. endif()