libxml2-config.cmake.cmake.in 5.5 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136
  1. # libxml2-config.cmake
  2. # --------------------
  3. #
  4. # Libxml2 cmake module.
  5. # This module sets the following variables:
  6. #
  7. # ::
  8. #
  9. # LIBXML2_INCLUDE_DIR - Directory where LibXml2 headers are located.
  10. # LIBXML2_INCLUDE_DIRS - list of the include directories needed to use LibXml2.
  11. # LIBXML2_LIBRARY - path to the LibXml2 library.
  12. # LIBXML2_LIBRARIES - xml2 libraries to link against.
  13. # LIBXML2_DEFINITIONS - the compiler switches required for using LibXml2.
  14. # LIBXML2_VERSION_MAJOR - The major version of libxml2.
  15. # LIBXML2_VERSION_MINOR - The minor version of libxml2.
  16. # LIBXML2_VERSION_PATCH - The patch version of libxml2.
  17. # LIBXML2_VERSION_STRING - version number as a string (ex: "2.3.4")
  18. # LIBXML2_MODULES - whether libxml2 has dso support
  19. # LIBXML2_XMLLINT_EXECUTABLE - path to the XML checking tool xmllint coming with LibXml2
  20. include("${CMAKE_CURRENT_LIST_DIR}/libxml2-export.cmake")
  21. @PACKAGE_INIT@
  22. set(LIBXML2_VERSION_MAJOR @LIBXML_MAJOR_VERSION@)
  23. set(LIBXML2_VERSION_MINOR @LIBXML_MINOR_VERSION@)
  24. set(LIBXML2_VERSION_PATCH @LIBXML_MICRO_VERSION@)
  25. set(LIBXML2_VERSION_STRING "@VERSION@")
  26. set(LIBXML2_INSTALL_PREFIX ${PACKAGE_PREFIX_DIR})
  27. set(LIBXML2_INCLUDE_DIR ${PACKAGE_PREFIX_DIR}/@CMAKE_INSTALL_INCLUDEDIR@/libxml2)
  28. set(LIBXML2_LIBRARY_DIR ${PACKAGE_PREFIX_DIR}/@CMAKE_INSTALL_LIBDIR@)
  29. macro(select_library_location target basename)
  30. if(TARGET ${target})
  31. foreach(property IN ITEMS IMPORTED_LOCATION IMPORTED_IMPLIB)
  32. get_target_property(${basename}_${property}_DEBUG ${target} ${property}_DEBUG)
  33. get_target_property(${basename}_${property}_MINSIZEREL ${target} ${property}_MINSIZEREL)
  34. get_target_property(${basename}_${property}_RELEASE ${target} ${property}_RELEASE)
  35. get_target_property(${basename}_${property}_RELWITHDEBINFO ${target} ${property}_RELWITHDEBINFO)
  36. if(${basename}_${property}_DEBUG AND ${basename}_${property}_RELEASE)
  37. set(${basename}_LIBRARY debug ${${basename}_${property}_DEBUG} optimized ${${basename}_${property}_RELEASE})
  38. elseif(${basename}_${property}_DEBUG AND ${basename}_${property}_RELWITHDEBINFO)
  39. set(${basename}_LIBRARY debug ${${basename}_${property}_DEBUG} optimized ${${basename}_${property}_RELWITHDEBINFO})
  40. elseif(${basename}_${property}_DEBUG AND ${basename}_${property}_MINSIZEREL)
  41. set(${basename}_LIBRARY debug ${${basename}_${property}_DEBUG} optimized ${${basename}_${property}_MINSIZEREL})
  42. elseif(${basename}_${property}_RELEASE)
  43. set(${basename}_LIBRARY ${${basename}_${property}_RELEASE})
  44. elseif(${basename}_${property}_RELWITHDEBINFO)
  45. set(${basename}_LIBRARY ${${basename}_${property}_RELWITHDEBINFO})
  46. elseif(${basename}_${property}_MINSIZEREL)
  47. set(${basename}_LIBRARY ${${basename}_${property}_MINSIZEREL})
  48. elseif(${basename}_${property}_DEBUG)
  49. set(${basename}_LIBRARY ${${basename}_${property}_DEBUG})
  50. endif()
  51. endforeach()
  52. endif()
  53. endmacro()
  54. macro(select_executable_location target basename)
  55. if(TARGET ${target})
  56. get_target_property(${basename}_IMPORTED_LOCATION_DEBUG ${target} IMPORTED_LOCATION_DEBUG)
  57. get_target_property(${basename}_IMPORTED_LOCATION_MINSIZEREL ${target} IMPORTED_LOCATION_MINSIZEREL)
  58. get_target_property(${basename}_IMPORTED_LOCATION_RELEASE ${target} IMPORTED_LOCATION_RELEASE)
  59. get_target_property(${basename}_IMPORTED_LOCATION_RELWITHDEBINFO ${target} IMPORTED_LOCATION_RELWITHDEBINFO)
  60. if(${basename}_IMPORTED_LOCATION_RELEASE)
  61. set(${basename}_EXECUTABLE ${${basename}_IMPORTED_LOCATION_RELEASE})
  62. elseif(${basename}_IMPORTED_LOCATION_RELWITHDEBINFO)
  63. set(${basename}_EXECUTABLE ${${basename}_IMPORTED_LOCATION_RELWITHDEBINFO})
  64. elseif(${basename}_IMPORTED_LOCATION_MINSIZEREL)
  65. set(${basename}_EXECUTABLE ${${basename}_IMPORTED_LOCATION_MINSIZEREL})
  66. elseif(${basename}_IMPORTED_LOCATION_DEBUG)
  67. set(${basename}_EXECUTABLE ${${basename}_IMPORTED_LOCATION_DEBUG})
  68. endif()
  69. endif()
  70. endmacro()
  71. select_library_location(LibXml2::LibXml2 LIBXML2)
  72. select_executable_location(LibXml2::xmlcatalog LIBXML2_XMLCATALOG)
  73. select_executable_location(LibXml2::xmllint LIBXML2_XMLLINT)
  74. set(LIBXML2_LIBRARIES ${LIBXML2_LIBRARY})
  75. set(LIBXML2_INCLUDE_DIRS ${LIBXML2_INCLUDE_DIR})
  76. include(CMakeFindDependencyMacro)
  77. set(LIBXML2_SHARED @BUILD_SHARED_LIBS@)
  78. set(LIBXML2_WITH_ICONV @LIBXML2_WITH_ICONV@)
  79. set(LIBXML2_WITH_THREADS @LIBXML2_WITH_THREADS@)
  80. set(LIBXML2_WITH_ICU @LIBXML2_WITH_ICU@)
  81. set(LIBXML2_WITH_LZMA @LIBXML2_WITH_LZMA@)
  82. set(LIBXML2_WITH_ZLIB @LIBXML2_WITH_ZLIB@)
  83. if(LIBXML2_WITH_ICONV)
  84. find_dependency(Iconv)
  85. list(APPEND LIBXML2_LIBRARIES ${Iconv_LIBRARIES})
  86. list(APPEND LIBXML2_INCLUDE_DIRS ${Iconv_INCLUDE_DIRS})
  87. endif()
  88. if(NOT LIBXML2_SHARED)
  89. set(LIBXML2_DEFINITIONS -DLIBXML_STATIC)
  90. if(LIBXML2_WITH_THREADS)
  91. find_dependency(Threads)
  92. list(APPEND LIBXML2_LIBRARIES ${CMAKE_THREAD_LIBS_INIT})
  93. endif()
  94. if(LIBXML2_WITH_ICU)
  95. find_dependency(ICU COMPONENTS data i18n uc)
  96. list(APPEND LIBXML2_LIBRARIES ${ICU_LIBRARIES})
  97. endif()
  98. if(LIBXML2_WITH_LZMA)
  99. find_dependency(LibLZMA)
  100. list(APPEND LIBXML2_LIBRARIES ${LIBLZMA_LIBRARIES})
  101. endif()
  102. if(LIBXML2_WITH_ZLIB)
  103. find_dependency(ZLIB)
  104. list(APPEND LIBXML2_LIBRARIES ${ZLIB_LIBRARIES})
  105. endif()
  106. if(UNIX)
  107. list(APPEND LIBXML2_LIBRARIES m)
  108. endif()
  109. if(WIN32)
  110. list(APPEND LIBXML2_LIBRARIES ws2_32)
  111. endif()
  112. endif()
  113. # whether libxml2 has dso support
  114. set(LIBXML2_MODULES @LIBXML2_WITH_MODULES@)
  115. mark_as_advanced(LIBXML2_LIBRARY LIBXML2_XMLCATALOG_EXECUTABLE LIBXML2_XMLLINT_EXECUTABLE)