hardware_keyboard_util.mm 14 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400401402403404405406407408409410411412413414415416417418419420421422423424425426427428429430431432
  1. // Copyright 2019 The Chromium Authors. All rights reserved.
  2. // Use of this source code is governed by a BSD-style license that can be
  3. // found in the LICENSE file.
  4. #import "ios/testing/hardware_keyboard_util.h"
  5. #import "base/test/ios/wait_util.h"
  6. #if !defined(__has_feature) || !__has_feature(objc_arc)
  7. #error "This file requires ARC support."
  8. #endif
  9. #pragma mark - Private API from IOKit to support CreateHIDKeyEvent
  10. typedef UInt32 IOOptionBits;
  11. typedef struct __IOHIDEvent* IOHIDEventRef;
  12. extern "C" {
  13. // This function is privately defined in IOKit framework.
  14. IOHIDEventRef IOHIDEventCreateKeyboardEvent(CFAllocatorRef,
  15. uint64_t,
  16. uint32_t,
  17. uint32_t,
  18. boolean_t,
  19. IOOptionBits);
  20. }
  21. // This enum is defined in IOKit framework.
  22. typedef enum {
  23. kUIKeyboardInputRepeat = 1 << 0,
  24. kUIKeyboardInputPopupVariant = 1 << 1,
  25. kUIKeyboardInputMultitap = 1 << 2,
  26. kUIKeyboardInputSkipCandidateSelection = 1 << 3,
  27. kUIKeyboardInputDeadKey = 1 << 4,
  28. kUIKeyboardInputModifierFlagsChanged = 1 << 5,
  29. kUIKeyboardInputFlick = 1 << 6,
  30. kUIKeyboardInputPreProcessed = 1 << 7,
  31. } UIKeyboardInputFlags;
  32. // This enum is defined in IOKit framework.
  33. enum {
  34. kHIDUsage_KeyboardA = 0x04,
  35. kHIDUsage_Keyboard1 = 0x1E,
  36. kHIDUsage_Keyboard2 = 0x1F,
  37. kHIDUsage_Keyboard3 = 0x20,
  38. kHIDUsage_Keyboard4 = 0x21,
  39. kHIDUsage_Keyboard5 = 0x22,
  40. kHIDUsage_Keyboard6 = 0x23,
  41. kHIDUsage_Keyboard7 = 0x24,
  42. kHIDUsage_Keyboard8 = 0x25,
  43. kHIDUsage_Keyboard9 = 0x26,
  44. kHIDUsage_Keyboard0 = 0x27,
  45. kHIDUsage_KeyboardReturnOrEnter = 0x28,
  46. kHIDUsage_KeyboardEscape = 0x29,
  47. kHIDUsage_KeyboardDeleteOrBackspace = 0x2A,
  48. kHIDUsage_KeyboardTab = 0x2B,
  49. kHIDUsage_KeyboardSpacebar = 0x2C,
  50. kHIDUsage_KeyboardHyphen = 0x2D,
  51. kHIDUsage_KeyboardEqualSign = 0x2E,
  52. kHIDUsage_KeyboardOpenBracket = 0x2F,
  53. kHIDUsage_KeyboardCloseBracket = 0x30,
  54. kHIDUsage_KeyboardBackslash = 0x31,
  55. kHIDUsage_KeyboardSemicolon = 0x33,
  56. kHIDUsage_KeyboardQuote = 0x34,
  57. kHIDUsage_KeyboardGraveAccentAndTilde = 0x35,
  58. kHIDUsage_KeyboardComma = 0x36,
  59. kHIDUsage_KeyboardPeriod = 0x37,
  60. kHIDUsage_KeyboardSlash = 0x38,
  61. kHIDUsage_KeyboardCapsLock = 0x39,
  62. kHIDUsage_KeyboardF1 = 0x3A,
  63. kHIDUsage_KeyboardF12 = 0x45,
  64. kHIDUsage_KeyboardPrintScreen = 0x46,
  65. kHIDUsage_KeyboardInsert = 0x49,
  66. kHIDUsage_KeyboardHome = 0x4A,
  67. kHIDUsage_KeyboardPageUp = 0x4B,
  68. kHIDUsage_KeyboardDeleteForward = 0x4C,
  69. kHIDUsage_KeyboardEnd = 0x4D,
  70. kHIDUsage_KeyboardPageDown = 0x4E,
  71. kHIDUsage_KeyboardRightArrow = 0x4F,
  72. kHIDUsage_KeyboardLeftArrow = 0x50,
  73. kHIDUsage_KeyboardDownArrow = 0x51,
  74. kHIDUsage_KeyboardUpArrow = 0x52,
  75. kHIDUsage_KeypadNumLock = 0x53,
  76. kHIDUsage_KeyboardF13 = 0x68,
  77. kHIDUsage_KeyboardF24 = 0x73,
  78. kHIDUsage_KeyboardMenu = 0x76,
  79. kHIDUsage_KeypadComma = 0x85,
  80. kHIDUsage_KeyboardLeftControl = 0xE0,
  81. kHIDUsage_KeyboardLeftShift = 0xE1,
  82. kHIDUsage_KeyboardLeftAlt = 0xE2,
  83. kHIDUsage_KeyboardLeftGUI = 0xE3,
  84. kHIDUsage_KeyboardRightControl = 0xE4,
  85. kHIDUsage_KeyboardRightShift = 0xE5,
  86. kHIDUsage_KeyboardRightAlt = 0xE6,
  87. kHIDUsage_KeyboardRightGUI = 0xE7,
  88. };
  89. // This function is privately defined in IOKit framework.
  90. static uint32_t keyCodeForFunctionKey(NSString* key) {
  91. // Compare the input string with the function-key names (i.e. "F1",...,"F24").
  92. for (int i = 1; i <= 12; ++i) {
  93. if ([key isEqualToString:[NSString stringWithFormat:@"F%d", i]])
  94. return kHIDUsage_KeyboardF1 + i - 1;
  95. }
  96. for (int i = 13; i <= 24; ++i) {
  97. if ([key isEqualToString:[NSString stringWithFormat:@"F%d", i]])
  98. return kHIDUsage_KeyboardF13 + i - 13;
  99. }
  100. return 0;
  101. }
  102. // This function is privately defined in IOKit framework.
  103. static inline uint32_t hidUsageCodeForCharacter(NSString* key) {
  104. const int uppercaseAlphabeticOffset = 'A' - kHIDUsage_KeyboardA;
  105. const int lowercaseAlphabeticOffset = 'a' - kHIDUsage_KeyboardA;
  106. const int numericNonZeroOffset = '1' - kHIDUsage_Keyboard1;
  107. if (key.length == 1) {
  108. // Handle alphanumeric characters and basic symbols.
  109. int keyCode = [key characterAtIndex:0];
  110. if (97 <= keyCode && keyCode <= 122) // Handle a-z.
  111. return keyCode - lowercaseAlphabeticOffset;
  112. if (65 <= keyCode && keyCode <= 90) // Handle A-Z.
  113. return keyCode - uppercaseAlphabeticOffset;
  114. if (49 <= keyCode && keyCode <= 57) // Handle 1-9.
  115. return keyCode - numericNonZeroOffset;
  116. // Handle all other cases.
  117. switch (keyCode) {
  118. case '`':
  119. case '~':
  120. return kHIDUsage_KeyboardGraveAccentAndTilde;
  121. case '!':
  122. return kHIDUsage_Keyboard1;
  123. case '@':
  124. return kHIDUsage_Keyboard2;
  125. case '#':
  126. return kHIDUsage_Keyboard3;
  127. case '$':
  128. return kHIDUsage_Keyboard4;
  129. case '%':
  130. return kHIDUsage_Keyboard5;
  131. case '^':
  132. return kHIDUsage_Keyboard6;
  133. case '&':
  134. return kHIDUsage_Keyboard7;
  135. case '*':
  136. return kHIDUsage_Keyboard8;
  137. case '(':
  138. return kHIDUsage_Keyboard9;
  139. case ')':
  140. case '0':
  141. return kHIDUsage_Keyboard0;
  142. case '-':
  143. case '_':
  144. return kHIDUsage_KeyboardHyphen;
  145. case '=':
  146. case '+':
  147. return kHIDUsage_KeyboardEqualSign;
  148. case '\b':
  149. return kHIDUsage_KeyboardDeleteOrBackspace;
  150. case '\t':
  151. return kHIDUsage_KeyboardTab;
  152. case '[':
  153. case '{':
  154. return kHIDUsage_KeyboardOpenBracket;
  155. case ']':
  156. case '}':
  157. return kHIDUsage_KeyboardCloseBracket;
  158. case '\\':
  159. case '|':
  160. return kHIDUsage_KeyboardBackslash;
  161. case ';':
  162. case ':':
  163. return kHIDUsage_KeyboardSemicolon;
  164. case '\'':
  165. case '"':
  166. return kHIDUsage_KeyboardQuote;
  167. case '\r':
  168. case '\n':
  169. return kHIDUsage_KeyboardReturnOrEnter;
  170. case ',':
  171. case '<':
  172. return kHIDUsage_KeyboardComma;
  173. case '.':
  174. case '>':
  175. return kHIDUsage_KeyboardPeriod;
  176. case '/':
  177. case '?':
  178. return kHIDUsage_KeyboardSlash;
  179. case ' ':
  180. return kHIDUsage_KeyboardSpacebar;
  181. }
  182. }
  183. uint32_t keyCode = keyCodeForFunctionKey(key);
  184. if (keyCode)
  185. return keyCode;
  186. if ([key isEqualToString:@"capsLock"] || [key isEqualToString:@"capsLockKey"])
  187. return kHIDUsage_KeyboardCapsLock;
  188. if ([key isEqualToString:@"pageUp"])
  189. return kHIDUsage_KeyboardPageUp;
  190. if ([key isEqualToString:@"pageDown"])
  191. return kHIDUsage_KeyboardPageDown;
  192. if ([key isEqualToString:@"home"])
  193. return kHIDUsage_KeyboardHome;
  194. if ([key isEqualToString:@"insert"])
  195. return kHIDUsage_KeyboardInsert;
  196. if ([key isEqualToString:@"end"])
  197. return kHIDUsage_KeyboardEnd;
  198. if ([key isEqualToString:@"escape"])
  199. return kHIDUsage_KeyboardEscape;
  200. if ([key isEqualToString:@"return"] || [key isEqualToString:@"enter"])
  201. return kHIDUsage_KeyboardReturnOrEnter;
  202. if ([key isEqualToString:@"leftArrow"])
  203. return kHIDUsage_KeyboardLeftArrow;
  204. if ([key isEqualToString:@"rightArrow"])
  205. return kHIDUsage_KeyboardRightArrow;
  206. if ([key isEqualToString:@"upArrow"])
  207. return kHIDUsage_KeyboardUpArrow;
  208. if ([key isEqualToString:@"downArrow"])
  209. return kHIDUsage_KeyboardDownArrow;
  210. if ([key isEqualToString:@"delete"])
  211. return kHIDUsage_KeyboardDeleteOrBackspace;
  212. if ([key isEqualToString:@"forwardDelete"])
  213. return kHIDUsage_KeyboardDeleteForward;
  214. if ([key isEqualToString:@"leftCommand"] || [key isEqualToString:@"metaKey"])
  215. return kHIDUsage_KeyboardLeftGUI;
  216. if ([key isEqualToString:@"rightCommand"])
  217. return kHIDUsage_KeyboardRightGUI;
  218. if ([key isEqualToString:@"clear"]) // Num Lock / Clear
  219. return kHIDUsage_KeypadNumLock;
  220. if ([key isEqualToString:@"leftControl"] || [key isEqualToString:@"ctrlKey"])
  221. return kHIDUsage_KeyboardLeftControl;
  222. if ([key isEqualToString:@"rightControl"])
  223. return kHIDUsage_KeyboardRightControl;
  224. if ([key isEqualToString:@"leftShift"] || [key isEqualToString:@"shiftKey"])
  225. return kHIDUsage_KeyboardLeftShift;
  226. if ([key isEqualToString:@"rightShift"])
  227. return kHIDUsage_KeyboardRightShift;
  228. if ([key isEqualToString:@"leftAlt"] || [key isEqualToString:@"altKey"])
  229. return kHIDUsage_KeyboardLeftAlt;
  230. if ([key isEqualToString:@"rightAlt"])
  231. return kHIDUsage_KeyboardRightAlt;
  232. if ([key isEqualToString:@"numpadComma"])
  233. return kHIDUsage_KeypadComma;
  234. return 0;
  235. }
  236. // These are privately defined in IOKit framework.
  237. enum { kHIDPage_KeyboardOrKeypad = 0x07, kHIDPage_VendorDefinedStart = 0xFF00 };
  238. enum {
  239. kIOHIDEventOptionNone = 0,
  240. };
  241. #pragma mark - Private API to fake keyboard events.
  242. // Convenience wrapper for IOHIDEventCreateKeyboardEvent.
  243. IOHIDEventRef CreateHIDKeyEvent(NSString* character,
  244. uint64_t timestamp,
  245. bool isKeyDown) {
  246. return IOHIDEventCreateKeyboardEvent(
  247. kCFAllocatorDefault, timestamp, kHIDPage_KeyboardOrKeypad,
  248. hidUsageCodeForCharacter(character), isKeyDown, kIOHIDEventOptionNone);
  249. }
  250. // A fake class that mirrors UIPhysicalKeyboardEvent private class' fields.
  251. // This class is never used, but it allows to call UIPhysicalKeyboardEvent's API
  252. // by casting an instance of UIPhysicalKeyboardEvent to PhysicalKeyboardEvent.
  253. @interface PhysicalKeyboardEvent : UIEvent
  254. + (id)_eventWithInput:(id)arg1 inputFlags:(int)arg2;
  255. - (void)_setHIDEvent:(IOHIDEventRef)event keyboard:(void*)gsKeyboard;
  256. @property(nonatomic) UIKeyModifierFlags _modifierFlags;
  257. @end
  258. // Private API in UIKit.
  259. @interface UIApplication ()
  260. - (void)handleKeyUIEvent:(id)event;
  261. - (void)handleKeyHIDEvent:(id)event;
  262. @end
  263. #pragma mark - Implementation
  264. namespace {
  265. // Delay between simulated keyboard press events.
  266. const double kKeyPressDelay = 0.02;
  267. // Utility to describe modifier flags. Useful in debugging.
  268. [[maybe_unused]] NSString* DescribeFlags(UIKeyModifierFlags flags);
  269. NSString* DescribeFlags(UIKeyModifierFlags flags) {
  270. NSMutableString* s = [NSMutableString new];
  271. if (flags & UIKeyModifierAlphaShift) {
  272. [s appendString:@"CapsLock+"];
  273. }
  274. if (flags & UIKeyModifierShift) {
  275. [s appendString:@"Shift+"];
  276. }
  277. if (flags & UIKeyModifierControl) {
  278. [s appendString:@"Ctrl+"];
  279. }
  280. if (flags & UIKeyModifierAlternate) {
  281. [s appendString:@"Alt+"];
  282. }
  283. if (flags & UIKeyModifierCommand) {
  284. [s appendString:@"Command+"];
  285. }
  286. if (flags & UIKeyModifierNumericPad) {
  287. [s appendString:@"NumPad+"];
  288. }
  289. return s;
  290. }
  291. // Sends an individual keyboard press event.
  292. void SendKBEventWithModifiers(UIKeyModifierFlags flags, NSString* input) {
  293. // Fake up an event.
  294. PhysicalKeyboardEvent* keyboardEvent =
  295. [NSClassFromString(@"UIPhysicalKeyboardEvent") _eventWithInput:input
  296. inputFlags:0];
  297. keyboardEvent._modifierFlags = flags;
  298. IOHIDEventRef hidEvent =
  299. CreateHIDKeyEvent(input, keyboardEvent.timestamp, true);
  300. [keyboardEvent _setHIDEvent:hidEvent keyboard:0];
  301. [[UIApplication sharedApplication] handleKeyUIEvent:keyboardEvent];
  302. }
  303. // Lifts the keypresses one by one.
  304. // Once all keypresses are reversed, executes |completion| on the main thread.
  305. void UnwindFakeKeyboardPressWithFlags(UIKeyModifierFlags flags,
  306. NSString* input,
  307. void (^completion)()) {
  308. if (flags == 0 && input.length == 0) {
  309. if (completion) {
  310. completion();
  311. }
  312. return;
  313. }
  314. dispatch_after(
  315. dispatch_time(DISPATCH_TIME_NOW, kKeyPressDelay * NSEC_PER_SEC),
  316. dispatch_get_main_queue(), ^{
  317. // First release all the non-modifier keys.
  318. if (input.length > 0) {
  319. NSString* remainingInput = [input substringFromIndex:1];
  320. SendKBEventWithModifiers(flags, remainingInput);
  321. UnwindFakeKeyboardPressWithFlags(flags, remainingInput, completion);
  322. return;
  323. }
  324. // Unwind the modifier keys.
  325. for (int i = 16; i < 22; i++) {
  326. UIKeyModifierFlags flag = 1 << i;
  327. if (flags & flag) {
  328. SendKBEventWithModifiers(flags & ~flag, input);
  329. UnwindFakeKeyboardPressWithFlags(flags & ~flag, input, completion);
  330. }
  331. }
  332. });
  333. }
  334. // Programmatically simulates pressing the keys one by one, starting with
  335. // modifier keys and moving to input string through recursion, then calls
  336. // unwindFakeKeyboardPressWithFlags to release the pressed keys in reverse
  337. // order.
  338. // Once all key downs and key ups are simulated, executes |completion| on the
  339. // main thread.
  340. void SimulatePhysicalKeyboardEventInternal(UIKeyModifierFlags flags,
  341. NSString* input,
  342. UIKeyModifierFlags previousFlags,
  343. NSString* previousInput,
  344. void (^completion)()) {
  345. dispatch_after(
  346. dispatch_time(DISPATCH_TIME_NOW, kKeyPressDelay * NSEC_PER_SEC),
  347. dispatch_get_main_queue(), ^{
  348. // First dial in all the modifier keys.
  349. for (int i = 15; i < 25; i++) {
  350. UIKeyModifierFlags flag = 1 << i;
  351. if (flags & flag) {
  352. SendKBEventWithModifiers(previousFlags ^ flag, previousInput);
  353. SimulatePhysicalKeyboardEventInternal(flags & ~flag, input,
  354. previousFlags ^ flag,
  355. previousInput, completion);
  356. return;
  357. }
  358. }
  359. // Now add the next input char.
  360. if (input.length > 0) {
  361. NSString* pressedKey = [input substringToIndex:1];
  362. NSString* remainingInput = [input substringFromIndex:1];
  363. NSString* alreadyPressedString =
  364. [previousInput stringByAppendingString:pressedKey];
  365. SendKBEventWithModifiers(previousFlags, alreadyPressedString);
  366. SimulatePhysicalKeyboardEventInternal(
  367. flags, remainingInput, previousFlags, alreadyPressedString,
  368. completion);
  369. } else {
  370. // Time to unwind the presses.
  371. UnwindFakeKeyboardPressWithFlags(previousFlags, previousInput,
  372. completion);
  373. }
  374. });
  375. }
  376. } // namespace
  377. #pragma mark - Public
  378. namespace chrome_test_util {
  379. void SimulatePhysicalKeyboardEvent(UIKeyModifierFlags flags, NSString* input) {
  380. __block BOOL keyPressesFinished = NO;
  381. SimulatePhysicalKeyboardEventInternal(flags, input, 0, @"", ^{
  382. keyPressesFinished = YES;
  383. });
  384. BOOL __unused result = base::test::ios::WaitUntilConditionOrTimeout(1.0, ^{
  385. return keyPressesFinished;
  386. });
  387. }
  388. } // namespace chrome_test_util