123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175 |
- # Copyright 2020 The Chromium Authors. All rights reserved.
- # Use of this source code is governed by a BSD-style license that can be
- # found in the LICENSE file.
- if (is_android) {
- import("//build/config/android/config.gni")
- import("//build/config/android/rules.gni")
- }
- if (is_android) {
- java_group("java") {
- deps = [
- ":public_java",
- ":query_tile_java",
- ]
- }
- }
- group("query_tiles") {
- public_deps = [
- ":factory",
- ":public",
- ]
- deps = [ "internal" ]
- }
- source_set("public") {
- sources = [
- "logger.h",
- "switches.cc",
- "switches.h",
- "tile.cc",
- "tile.h",
- "tile_service.h",
- "tile_service_prefs.cc",
- "tile_service_prefs.h",
- ]
- deps = [ "//ui/gfx" ]
- public_deps = [
- "//base",
- "//components/keyed_service/core",
- "//components/prefs",
- "//url:url",
- ]
- if (is_android) {
- sources += [
- "android/tile_conversion_bridge.cc",
- "android/tile_conversion_bridge.h",
- "android/tile_provider_bridge.cc",
- "android/tile_provider_bridge.h",
- ]
- deps += [
- ":jni_headers",
- "//url:gurl_android",
- ]
- }
- }
- source_set("factory") {
- sources = [
- "tile_service_factory_helper.cc",
- "tile_service_factory_helper.h",
- ]
- deps = [
- ":public",
- "internal:internal",
- "//components/background_task_scheduler:public",
- "//components/leveldb_proto",
- "//components/query_tiles/proto",
- ]
- }
- if (is_android) {
- android_library("query_tile_java") {
- sources = [
- "android/java/src/org/chromium/components/query_tiles/QueryTile.java",
- ]
- deps = [
- "//components/browser_ui/widget/android:java",
- "//third_party/androidx:androidx_annotation_annotation_java",
- "//url:gurl_java",
- ]
- }
- android_library("public_java") {
- sources = [
- "android/java/src/org/chromium/components/query_tiles/QueryTileConstants.java",
- "android/java/src/org/chromium/components/query_tiles/TileProvider.java",
- "android/java/src/org/chromium/components/query_tiles/TileUmaLogger.java",
- "android/java/src/org/chromium/components/query_tiles/bridges/TileConversionBridge.java",
- "android/java/src/org/chromium/components/query_tiles/bridges/TileProviderBridge.java",
- ]
- deps = [
- ":query_tile_java",
- "//base:base_java",
- "//base:jni_java",
- "//build/android:build_java",
- "//components/browser_ui/widget/android:java",
- "//third_party/androidx:androidx_annotation_annotation_java",
- "//ui/android:ui_java",
- "//url:gurl_java",
- ]
- annotation_processor_deps = [ "//base/android/jni_generator:jni_processor" ]
- }
- generate_jni("jni_headers") {
- visibility = [ ":*" ]
- sources = [
- "android/java/src/org/chromium/components/query_tiles/bridges/TileConversionBridge.java",
- "android/java/src/org/chromium/components/query_tiles/bridges/TileProviderBridge.java",
- ]
- }
- android_library("test_support_java") {
- testonly = true
- sources = [ "android/java/src/org/chromium/components/query_tiles/TestTileProvider.java" ]
- deps = [
- ":java",
- "//base:base_java",
- "//url:gurl_java",
- "//url:gurl_junit_test_support",
- ]
- }
- robolectric_library("query_tiles_junit_tests") {
- sources = [ "android/java/src/org/chromium/components/query_tiles/TileUmaLoggerTest.java" ]
- deps = [
- ":java",
- ":test_support_java",
- "//base:base_java",
- "//base:base_junit_test_support",
- "//third_party/junit",
- ]
- }
- }
- group("unit_tests") {
- testonly = true
- deps = [
- ":query_tiles_unit_tests",
- "internal:unit_tests",
- ]
- data_deps = [ ":components_unittests_gtest_filter" ]
- }
- source_set("components_unittests_gtest_filter") {
- testonly = true
- data = [ "components_unittests.filter" ]
- }
- source_set("query_tiles_unit_tests") {
- testonly = true
- sources = [ "tile_unittest.cc" ]
- deps = [
- ":public",
- "test:test_lib",
- "//base/test:test_support",
- "//testing/gtest",
- ]
- }
|