BUILD.gn 2.2 KB

1234567891011121314151617181920212223242526272829303132333435363738394041424344454647484950515253545556575859606162636465666768697071727374757677787980818283848586
  1. # Copyright 2018 The Chromium Authors. All rights reserved.
  2. # Use of this source code is governed by a BSD-style license that can be
  3. # found in the LICENSE file.
  4. if (is_android) {
  5. import("//build/config/android/config.gni")
  6. import("//build/config/android/rules.gni")
  7. }
  8. static_library("network") {
  9. sources = [
  10. "download_http_utils.cc",
  11. "download_http_utils.h",
  12. "network_status_listener.cc",
  13. "network_status_listener.h",
  14. "network_status_listener_impl.cc",
  15. "network_status_listener_impl.h",
  16. ]
  17. deps = [
  18. "//base",
  19. "//net",
  20. "//services/network/public/cpp",
  21. ]
  22. if (is_android) {
  23. sources += [
  24. "android/network_status_listener_android.cc",
  25. "android/network_status_listener_android.h",
  26. ]
  27. deps += [ ":jni_headers" ]
  28. }
  29. }
  30. source_set("unit_tests") {
  31. testonly = true
  32. sources = [ "download_http_utils_unittest.cc" ]
  33. deps = [
  34. ":network",
  35. "//net",
  36. "//testing/gtest",
  37. ]
  38. }
  39. if (is_android) {
  40. android_library("network_java") {
  41. sources = [
  42. "android/java/src/org/chromium/components/download/BackgroundNetworkStatusListener.java",
  43. "android/java/src/org/chromium/components/download/NetworkStatusListenerAndroid.java",
  44. ]
  45. deps = [
  46. "//base:base_java",
  47. "//base:jni_java",
  48. "//build/android:build_java",
  49. "//net/android:net_java",
  50. "//third_party/androidx:androidx_annotation_annotation_java",
  51. ]
  52. annotation_processor_deps = [ "//base/android/jni_generator:jni_processor" ]
  53. }
  54. generate_jni("jni_headers") {
  55. visibility = [ ":*" ]
  56. sources = [ "android/java/src/org/chromium/components/download/NetworkStatusListenerAndroid.java" ]
  57. }
  58. robolectric_library("junit") {
  59. testonly = true
  60. sources = [ "android/junit/src/org/chromium/components/download/NetworkStatusListenerAndroidTest.java" ]
  61. deps = [
  62. ":network_java",
  63. "//base:base_java",
  64. "//base:base_java_test_support",
  65. "//base:base_junit_test_support",
  66. "//net/android:net_java",
  67. "//third_party/android_deps:robolectric_all_java",
  68. "//third_party/androidx:androidx_test_runner_java",
  69. "//third_party/junit",
  70. "//third_party/mockito:mockito_java",
  71. ]
  72. }
  73. }