chrome_repack_locales.gni 4.6 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126
  1. # Copyright 2014 The Chromium Authors. All rights reserved.
  2. # Use of this source code is governed by a BSD-style license that can be
  3. # found in the LICENSE file.
  4. import("//build/config/chrome_build.gni")
  5. import("//build/config/chromeos/ui_mode.gni")
  6. import("//build/config/features.gni")
  7. import("//build/config/ui.gni")
  8. import("//extensions/buildflags/buildflags.gni")
  9. import("//tools/grit/repack.gni")
  10. assert(!is_ios, "Chromium/iOS shouldn't use anything in //chrome")
  11. # Wraps repack_locales(), setting the source_patterns and deps required for
  12. # Chrome.
  13. #
  14. # Extra Parameters:
  15. #
  16. # additional_source_patterns [optional]
  17. # Extra source_patterns for repack_locales().
  18. template("chrome_repack_locales") {
  19. repack_locales(target_name) {
  20. forward_variables_from(invoker, "*", [ "additional_source_patterns" ])
  21. # Each input pak file should also have a deps line.
  22. source_patterns = [
  23. "${root_gen_dir}/chrome/generated_resources_",
  24. "${root_gen_dir}/chrome/locale_settings_",
  25. "${root_gen_dir}/chrome/platform_locale_settings_",
  26. "${root_gen_dir}/components/omnibox/resources/omnibox_pedal_synonyms_",
  27. "${root_gen_dir}/components/omnibox/resources/omnibox_resources_",
  28. "${root_gen_dir}/components/strings/components_locale_settings_",
  29. "${root_gen_dir}/components/strings/components_strings_",
  30. "${root_gen_dir}/third_party/blink/public/strings/blink_accessibility_strings_",
  31. "${root_gen_dir}/third_party/blink/public/strings/blink_strings_",
  32. "${root_gen_dir}/device/bluetooth/strings/bluetooth_strings_",
  33. "${root_gen_dir}/device/fido/strings/fido_strings_",
  34. "${root_gen_dir}/services/strings/services_strings_",
  35. "${root_gen_dir}/third_party/libaddressinput/address_input_strings_",
  36. "${root_gen_dir}/ui/strings/app_locale_settings_",
  37. "${root_gen_dir}/ui/strings/ax_strings_",
  38. "${root_gen_dir}/ui/strings/ui_strings_",
  39. ]
  40. if (!defined(deps)) {
  41. deps = []
  42. }
  43. deps += [
  44. "//chrome/app:generated_resources",
  45. "//chrome/app/resources:locale_settings",
  46. "//chrome/app/resources:platform_locale_settings",
  47. "//components/omnibox/resources:omnibox_pedal_synonyms",
  48. "//components/omnibox/resources:omnibox_resources",
  49. "//components/strings:components_locale_settings",
  50. "//components/strings:components_strings",
  51. "//device/bluetooth/strings",
  52. "//device/fido/strings",
  53. "//services/strings",
  54. "//third_party/blink/public/strings",
  55. "//third_party/blink/public/strings:accessibility_strings",
  56. "//third_party/libaddressinput:strings",
  57. "//ui/strings:app_locale_settings",
  58. "//ui/strings:ax_strings",
  59. "//ui/strings:ui_strings",
  60. ]
  61. if (defined(invoker.deps)) {
  62. deps += invoker.deps
  63. }
  64. if (is_chromeos) {
  65. source_patterns +=
  66. [ "${root_gen_dir}/ui/chromeos/strings/ui_chromeos_strings_" ]
  67. deps += [ "//ui/chromeos/strings" ]
  68. }
  69. if (is_chromeos_ash) {
  70. source_patterns += [
  71. "${root_gen_dir}/ash/shortcut_viewer/strings/shortcut_viewer_strings_",
  72. "${root_gen_dir}/ash/strings/ash_strings_",
  73. "${root_gen_dir}/ash/webui/camera_app_ui/resources/strings/ash_camera_app_strings_",
  74. "${root_gen_dir}/chromeos/strings/chromeos_strings_",
  75. "${root_gen_dir}/remoting/resources/",
  76. ]
  77. deps += [
  78. "//ash/shortcut_viewer/strings",
  79. "//ash/strings",
  80. "//ash/webui/camera_app_ui/resources/strings",
  81. "//chromeos/strings",
  82. "//remoting/resources",
  83. ]
  84. compress = true
  85. }
  86. if (is_chromeos_lacros) {
  87. source_patterns +=
  88. [ "${root_gen_dir}/chromeos/strings/chromeos_strings_" ]
  89. deps += [ "//chromeos/strings" ]
  90. }
  91. if (enable_extensions) {
  92. source_patterns +=
  93. [ "${root_gen_dir}/extensions/strings/extensions_strings_" ]
  94. deps += [ "//extensions/strings" ]
  95. }
  96. if (is_chrome_branded) {
  97. source_patterns += [
  98. "${root_gen_dir}/chrome/google_chrome_strings_",
  99. "${root_gen_dir}/components/strings/components_google_chrome_strings_",
  100. ]
  101. deps += [
  102. "//chrome/app:google_chrome_strings",
  103. "//components/strings:components_google_chrome_strings",
  104. ]
  105. } else {
  106. source_patterns += [
  107. "${root_gen_dir}/chrome/chromium_strings_",
  108. "${root_gen_dir}/components/strings/components_chromium_strings_",
  109. ]
  110. deps += [
  111. "//chrome/app:chromium_strings",
  112. "//components/strings:components_chromium_strings",
  113. ]
  114. }
  115. if (defined(invoker.additional_source_patterns)) {
  116. source_patterns += invoker.additional_source_patterns
  117. }
  118. }
  119. }