chrome_paks.gni 25 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400401402403404405406407408409410411412413414415416417418419420421422423424425426427428429430431432433434435436437438439440441442443444445446447448449450451452453454455456457458459460461462463464465466467468469470471472473474475476477478479480481482483484485486487488489490491492493494495496497498499500501502503504505506507508509510511512513514515516517518519520521522523524525526527528529530531532533534535536537538539540541542543544545546547548549550551552553554555556557558559560561562
  1. # Copyright 2016 The Chromium Authors. All rights reserved.
  2. # Use of this source code is governed by a BSD-style license that can be
  3. # found in the LICENSE file.
  4. import("//ash/ambient/resources/resources.gni")
  5. import("//build/config/chromebox_for_meetings/buildflags.gni")
  6. import("//build/config/chromeos/ui_mode.gni")
  7. import("//build/config/locales.gni")
  8. import("//chrome/browser/buildflags.gni")
  9. import("//chrome/common/features.gni")
  10. import("//extensions/buildflags/buildflags.gni")
  11. import("//pdf/features.gni")
  12. import("//ui/base/ui_features.gni")
  13. import("chrome_repack_locales.gni")
  14. # Generates a rule to repack a set of resources, substituting a given string
  15. # in for the percentage (e.g. "100", "200"). It generates the repacked files in
  16. # the "gen" directory, and then introduces a copy rule to copy it to the root
  17. # build directory.
  18. #
  19. # Argument:
  20. # percent [required]
  21. # String to substitute for the percentage.
  22. template("chrome_repack_percent") {
  23. percent = invoker.percent
  24. repack(target_name) {
  25. forward_variables_from(invoker,
  26. [
  27. "copy_data_to_bundle",
  28. "mark_as_data",
  29. "repack_allowlist",
  30. "visibility",
  31. ])
  32. # All sources should also have deps for completeness.
  33. sources = [
  34. "$root_gen_dir/chrome/renderer_resources_${percent}_percent.pak",
  35. "$root_gen_dir/chrome/theme_resources_${percent}_percent.pak",
  36. "$root_gen_dir/components/components_resources_${percent}_percent.pak",
  37. "$root_gen_dir/third_party/blink/public/resources/blink_scaled_resources_${percent}_percent.pak",
  38. "$root_gen_dir/ui/resources/ui_resources_${percent}_percent.pak",
  39. ]
  40. deps = [
  41. "//chrome/app/theme:theme_resources",
  42. "//chrome/renderer:resources",
  43. "//components/resources",
  44. "//components/strings",
  45. "//net:net_resources",
  46. "//third_party/blink/public:scaled_resources_${percent}_percent",
  47. "//ui/resources",
  48. ]
  49. if (defined(invoker.deps)) {
  50. deps += invoker.deps
  51. }
  52. if (toolkit_views) {
  53. sources += [ "$root_gen_dir/ui/views/resources/views_resources_${percent}_percent.pak" ]
  54. deps += [ "//ui/views/resources" ]
  55. }
  56. if (is_chromeos_ash) {
  57. sources += [
  58. "$root_gen_dir/ash/login/resources/login_resources_${percent}_percent.pak",
  59. "$root_gen_dir/chrome/app_icon_resources_${percent}_percent.pak",
  60. "$root_gen_dir/ui/chromeos/resources/ui_chromeos_resources_${percent}_percent.pak",
  61. ]
  62. deps += [
  63. "//ash/login/resources",
  64. "//chrome/browser/resources/chromeos:app_icon_resources",
  65. "//ui/chromeos/resources",
  66. ]
  67. }
  68. if (enable_extensions) {
  69. sources += [ "$root_gen_dir/extensions/extensions_browser_resources_${percent}_percent.pak" ]
  70. deps += [ "//extensions:extensions_browser_resources" ]
  71. }
  72. output = "${invoker.output_dir}/chrome_${percent}_percent.pak"
  73. }
  74. }
  75. template("chrome_extra_paks") {
  76. repack(target_name) {
  77. forward_variables_from(invoker,
  78. [
  79. "copy_data_to_bundle",
  80. "mark_as_data",
  81. "repack_allowlist",
  82. "visibility",
  83. ])
  84. output = "${invoker.output_dir}/resources.pak"
  85. sources = [
  86. "$root_gen_dir/base/tracing/protos/tracing_proto_resources.pak",
  87. "$root_gen_dir/chrome/browser_resources.pak",
  88. "$root_gen_dir/chrome/chrome_unscaled_resources.pak",
  89. "$root_gen_dir/chrome/common_resources.pak",
  90. "$root_gen_dir/chrome/segmentation_internals_resources.pak",
  91. "$root_gen_dir/components/autofill/core/browser/autofill_address_rewriter_resources.pak",
  92. "$root_gen_dir/components/components_resources.pak",
  93. "$root_gen_dir/content/content_resources.pak",
  94. "$root_gen_dir/content/quota_internals_resources.pak",
  95. "$root_gen_dir/mojo/public/js/mojo_bindings_resources.pak",
  96. "$root_gen_dir/net/net_resources.pak",
  97. "$root_gen_dir/skia/skia_resources.pak",
  98. "$root_gen_dir/third_party/blink/public/resources/blink_resources.pak",
  99. "$root_gen_dir/third_party/blink/public/resources/inspector_overlay_resources.pak",
  100. "$root_gen_dir/ui/resources/webui_generated_resources.pak",
  101. ]
  102. deps = [
  103. "//base/tracing/protos:chrome_track_event_resources",
  104. "//chrome/app/theme:chrome_unscaled_resources",
  105. "//chrome/browser:resources",
  106. "//chrome/browser/resources/segmentation_internals:resources",
  107. "//chrome/common:resources",
  108. "//components/autofill/core/browser:autofill_address_rewriter_resources",
  109. "//components/history_clusters/history_clusters_internals/resources",
  110. "//components/optimization_guide/optimization_guide_internals/resources",
  111. "//components/resources",
  112. "//content:content_resources",
  113. "//content/browser/resources/quota:resources",
  114. "//mojo/public/js:resources",
  115. "//net:net_resources",
  116. "//skia:skia_resources",
  117. "//third_party/blink/public:devtools_inspector_resources",
  118. "//third_party/blink/public:resources",
  119. "//ui/resources",
  120. ]
  121. if (defined(invoker.deps)) {
  122. deps += invoker.deps
  123. }
  124. if (defined(invoker.additional_paks)) {
  125. sources += invoker.additional_paks
  126. }
  127. if (!is_android) {
  128. # New paks should be added here by default.
  129. sources += [
  130. "$root_gen_dir/chrome/access_code_cast_resources.pak",
  131. "$root_gen_dir/chrome/app_service_internals_resources.pak",
  132. "$root_gen_dir/chrome/bookmarks_resources.pak",
  133. "$root_gen_dir/chrome/commander_resources.pak",
  134. "$root_gen_dir/chrome/component_extension_resources.pak",
  135. "$root_gen_dir/chrome/dev_ui_resources.pak",
  136. "$root_gen_dir/chrome/downloads_resources.pak",
  137. "$root_gen_dir/chrome/feed_resources.pak",
  138. "$root_gen_dir/chrome/feedback_resources.pak",
  139. "$root_gen_dir/chrome/gaia_auth_host_resources.pak",
  140. "$root_gen_dir/chrome/history_resources.pak",
  141. "$root_gen_dir/chrome/identity_internals_resources.pak",
  142. "$root_gen_dir/chrome/image_editor_resources.pak",
  143. "$root_gen_dir/chrome/image_editor_untrusted_resources.pak",
  144. "$root_gen_dir/chrome/management_resources.pak",
  145. "$root_gen_dir/chrome/new_tab_page_instant_resources.pak",
  146. "$root_gen_dir/chrome/new_tab_page_resources.pak",
  147. "$root_gen_dir/chrome/new_tab_page_third_party_resources.pak",
  148. "$root_gen_dir/chrome/password_manager_resources.pak",
  149. "$root_gen_dir/chrome/privacy_sandbox_resources.pak",
  150. "$root_gen_dir/chrome/profile_internals_resources.pak",
  151. "$root_gen_dir/chrome/settings_resources.pak",
  152. "$root_gen_dir/chrome/side_panel_customize_chrome_resources.pak",
  153. "$root_gen_dir/chrome/side_panel_resources.pak",
  154. "$root_gen_dir/chrome/signin_resources.pak",
  155. "$root_gen_dir/chrome/support_tool_resources.pak",
  156. "$root_gen_dir/chrome/tab_search_resources.pak",
  157. "$root_gen_dir/chrome/webid_resources_100_percent.pak",
  158. "$root_gen_dir/chrome/webui_gallery_resources.pak",
  159. "$root_gen_dir/chrome/whats_new_resources.pak",
  160. "$root_gen_dir/content/browser/devtools/devtools_resources.pak",
  161. "$root_gen_dir/content/browser/tracing/tracing_resources.pak",
  162. ]
  163. deps += [
  164. "//chrome/browser/resources:component_extension_resources",
  165. "//chrome/browser/resources:dev_ui_paks",
  166. "//chrome/browser/resources:webid_resources",
  167. "//chrome/browser/resources/access_code_cast:resources",
  168. "//chrome/browser/resources/app_service_internals:resources",
  169. "//chrome/browser/resources/bookmarks:resources",
  170. "//chrome/browser/resources/commander:resources",
  171. "//chrome/browser/resources/downloads:resources",
  172. "//chrome/browser/resources/feed:resources",
  173. "//chrome/browser/resources/feedback:resources",
  174. "//chrome/browser/resources/gaia_auth_host:resources",
  175. "//chrome/browser/resources/history:resources",
  176. "//chrome/browser/resources/identity_internals:resources",
  177. "//chrome/browser/resources/image_editor:trusted_resources",
  178. "//chrome/browser/resources/image_editor:untrusted_resources",
  179. "//chrome/browser/resources/management:resources",
  180. "//chrome/browser/resources/new_tab_page:resources",
  181. "//chrome/browser/resources/new_tab_page_instant:resources",
  182. "//chrome/browser/resources/new_tab_page_third_party:resources",
  183. "//chrome/browser/resources/password_manager:resources",
  184. "//chrome/browser/resources/privacy_sandbox:resources",
  185. "//chrome/browser/resources/profile_internals:resources",
  186. "//chrome/browser/resources/settings:resources",
  187. "//chrome/browser/resources/side_panel:resources",
  188. "//chrome/browser/resources/side_panel/customize_chrome:resources",
  189. "//chrome/browser/resources/signin:resources",
  190. "//chrome/browser/resources/support_tool:resources",
  191. "//chrome/browser/resources/tab_search:resources",
  192. "//chrome/browser/resources/webui_gallery:resources",
  193. "//chrome/browser/resources/whats_new:resources",
  194. "//content/browser/devtools:devtools_resources",
  195. "//content/browser/tracing:resources",
  196. ]
  197. if (is_chrome_branded) {
  198. sources += [
  199. "$root_gen_dir/chrome/media_router_feedback_resources.pak",
  200. "$root_gen_dir/chrome/preinstalled_web_apps_resources.pak",
  201. ]
  202. deps += [
  203. "//chrome/browser/resources:preinstalled_web_apps_resources",
  204. "//chrome/browser/resources/media_router/cast_feedback:resources",
  205. ]
  206. }
  207. }
  208. if (is_chromeos_ash) {
  209. sources += [
  210. "$root_gen_dir/ash/public/cpp/resources/ash_public_unscaled_resources.pak",
  211. "$root_gen_dir/ash/webui/ash_camera_app_resources.pak",
  212. "$root_gen_dir/ash/webui/ash_color_internals_resources.pak",
  213. "$root_gen_dir/ash/webui/ash_diagnostics_app_resources.pak",
  214. "$root_gen_dir/ash/webui/ash_eche_app_resources.pak",
  215. "$root_gen_dir/ash/webui/ash_eche_bundle_resources.pak",
  216. "$root_gen_dir/ash/webui/ash_firmware_update_app_resources.pak",
  217. "$root_gen_dir/ash/webui/ash_guest_os_installer_resources.pak",
  218. "$root_gen_dir/ash/webui/ash_help_app_resources.pak",
  219. "$root_gen_dir/ash/webui/ash_media_app_resources.pak",
  220. "$root_gen_dir/ash/webui/ash_multidevice_debug_resources.pak",
  221. "$root_gen_dir/ash/webui/ash_os_feedback_resources.pak",
  222. "$root_gen_dir/ash/webui/ash_os_feedback_untrusted_resources.pak",
  223. "$root_gen_dir/ash/webui/ash_personalization_app_resources.pak",
  224. "$root_gen_dir/ash/webui/ash_print_management_resources.pak",
  225. "$root_gen_dir/ash/webui/ash_projector_app_trusted_resources.pak",
  226. "$root_gen_dir/ash/webui/ash_projector_app_untrusted_resources.pak",
  227. "$root_gen_dir/ash/webui/ash_scanning_app_resources.pak",
  228. "$root_gen_dir/ash/webui/ash_shimless_rma_resources.pak",
  229. "$root_gen_dir/ash/webui/ash_shortcut_customization_app_resources.pak",
  230. "$root_gen_dir/ash/webui/ash_system_extensions_internals_resources.pak",
  231. "$root_gen_dir/ash/webui/connectivity_diagnostics_resources.pak",
  232. "$root_gen_dir/ash/webui/file_manager/resources/file_manager_swa_resources.pak",
  233. "$root_gen_dir/ash/webui/file_manager/untrusted_resources/file_manager_untrusted_resources.pak",
  234. "$root_gen_dir/chrome/arc_account_picker_resources.pak",
  235. "$root_gen_dir/chrome/assistant_optin_resources.pak",
  236. "$root_gen_dir/chrome/audio_resources.pak",
  237. "$root_gen_dir/chrome/bluetooth_pairing_dialog_resources.pak",
  238. "$root_gen_dir/chrome/browser/supervised_user/supervised_user_unscaled_resources.pak",
  239. "$root_gen_dir/chrome/cloud_upload_resources.pak",
  240. "$root_gen_dir/chrome/emoji_picker_resources.pak",
  241. "$root_gen_dir/chrome/gaia_action_buttons_resources.pak",
  242. "$root_gen_dir/chrome/internet_config_dialog_resources.pak",
  243. "$root_gen_dir/chrome/internet_detail_dialog_resources.pak",
  244. "$root_gen_dir/chrome/launcher_internals_resources.pak",
  245. "$root_gen_dir/chrome/manage_mirrorsync_resources.pak",
  246. "$root_gen_dir/chrome/multidevice_internals_resources.pak",
  247. "$root_gen_dir/chrome/multidevice_setup_resources.pak",
  248. "$root_gen_dir/chrome/nearby_internals_resources.pak",
  249. "$root_gen_dir/chrome/nearby_share_dialog_resources.pak",
  250. "$root_gen_dir/chrome/network_ui_resources.pak",
  251. "$root_gen_dir/chrome/notification_tester_resources.pak",
  252. "$root_gen_dir/chrome/oobe_conditional_resources.pak",
  253. "$root_gen_dir/chrome/oobe_unconditional_resources.pak",
  254. "$root_gen_dir/chrome/os_settings_resources.pak",
  255. "$root_gen_dir/chromeos/ash/ash_resources.pak",
  256. "$root_gen_dir/chromeos/chromeos_help_app_bundle_resources.pak",
  257. "$root_gen_dir/chromeos/chromeos_help_app_kids_magazine_bundle_resources.pak",
  258. "$root_gen_dir/chromeos/chromeos_media_app_bundle_resources.pak",
  259. "$root_gen_dir/chromeos/chromeos_projector_app_bundle_resources.pak",
  260. "$root_gen_dir/chromeos/chromeos_resources.pak",
  261. "$root_gen_dir/components/arc/input_overlay_resources.pak",
  262. "$root_gen_dir/ui/file_manager/file_manager_gen_resources.pak",
  263. "$root_gen_dir/ui/file_manager/file_manager_resources.pak",
  264. ]
  265. deps += [
  266. "//ash/components/arc/input_overlay/resources",
  267. "//ash/public/cpp/resources:ash_public_unscaled_resources",
  268. "//ash/webui/file_manager/resources:file_manager_swa_resources",
  269. "//ash/webui/file_manager/untrusted_resources:file_manager_untrusted_resources",
  270. "//ash/webui/resources:camera_app_resources",
  271. "//ash/webui/resources:color_internals_resources",
  272. "//ash/webui/resources:connectivity_diagnostics_resources",
  273. "//ash/webui/resources:diagnostics_app_resources",
  274. "//ash/webui/resources:eche_app_resources",
  275. "//ash/webui/resources:eche_bundle_resources",
  276. "//ash/webui/resources:firmware_update_app_resources",
  277. "//ash/webui/resources:guest_os_installer_resources",
  278. "//ash/webui/resources:help_app_bundle_resources",
  279. "//ash/webui/resources:help_app_kids_magazine_bundle_resources",
  280. "//ash/webui/resources:help_app_resources",
  281. "//ash/webui/resources:media_app_bundle_resources",
  282. "//ash/webui/resources:media_app_resources",
  283. "//ash/webui/resources:multidevice_debug_resources",
  284. "//ash/webui/resources:os_feedback_resources",
  285. "//ash/webui/resources:os_feedback_untrusted_resources",
  286. "//ash/webui/resources:personalization_app_resources",
  287. "//ash/webui/resources:print_management_resources",
  288. "//ash/webui/resources:projector_app_bundle_resources",
  289. "//ash/webui/resources:projector_app_trusted_resources",
  290. "//ash/webui/resources:projector_app_untrusted_resources",
  291. "//ash/webui/resources:scanning_app_resources",
  292. "//ash/webui/resources:shimless_rma_resources",
  293. "//ash/webui/resources:shortcut_customization_app_resources",
  294. "//ash/webui/resources:system_extensions_internals_resources",
  295. "//chrome/browser/resources:bluetooth_pairing_dialog_resources",
  296. "//chrome/browser/resources:internet_config_dialog_resources",
  297. "//chrome/browser/resources:internet_detail_dialog_resources",
  298. "//chrome/browser/resources/chromeos:multidevice_setup_resources",
  299. "//chrome/browser/resources/chromeos/arc_account_picker:resources",
  300. "//chrome/browser/resources/chromeos/assistant_optin:resources",
  301. "//chrome/browser/resources/chromeos/audio:resources",
  302. "//chrome/browser/resources/chromeos/cloud_upload:resources",
  303. "//chrome/browser/resources/chromeos/emoji_picker:resources",
  304. "//chrome/browser/resources/chromeos/gaia_action_buttons:resources",
  305. "//chrome/browser/resources/chromeos/launcher_internals:resources",
  306. "//chrome/browser/resources/chromeos/login:conditional_resources",
  307. "//chrome/browser/resources/chromeos/login:unconditional_resources",
  308. "//chrome/browser/resources/chromeos/manage_mirrorsync:resources",
  309. "//chrome/browser/resources/chromeos/multidevice_internals:resources",
  310. "//chrome/browser/resources/chromeos/network_ui:resources",
  311. "//chrome/browser/resources/chromeos/notification_tester:resources",
  312. "//chrome/browser/resources/nearby_internals:resources",
  313. "//chrome/browser/resources/nearby_share:resources",
  314. "//chrome/browser/resources/settings/chromeos:resources",
  315. "//chrome/browser/supervised_user:supervised_user_unscaled_resources",
  316. "//chromeos/ash/resources",
  317. "//chromeos/resources",
  318. "//ui/file_manager:file_manager_gen_resources",
  319. "//ui/file_manager:resources",
  320. ]
  321. if (!is_official_build) {
  322. sources += [
  323. "$root_gen_dir/ash/webui/ash_demo_mode_app_resources.pak",
  324. "$root_gen_dir/ash/webui/ash_facial_ml_app_resources.pak",
  325. "$root_gen_dir/ash/webui/ash_sample_system_web_app_resources.pak",
  326. "$root_gen_dir/ash/webui/ash_sample_system_web_app_untrusted_resources.pak",
  327. ]
  328. deps += [
  329. "//ash/webui/resources:demo_mode_app_resources",
  330. "//ash/webui/resources:facial_ml_app_resources",
  331. "//ash/webui/resources:sample_system_web_app_resources",
  332. "//ash/webui/resources:sample_system_web_app_untrusted_resources",
  333. ]
  334. }
  335. if (include_ash_ambient_animation_resources) {
  336. sources += [ "$root_gen_dir/ash/ambient/resources/ash_ambient_lottie_resources.pak" ]
  337. deps += [ "//ash/ambient/resources:lottie_resources" ]
  338. }
  339. }
  340. if (is_chromeos) {
  341. sources += [ "$root_gen_dir/chrome/common/chromeos/extensions/chromeos_system_extensions_resources.pak" ]
  342. deps += [ "//chrome/common/chromeos/extensions:resources" ]
  343. }
  344. if (is_linux || is_chromeos) {
  345. sources += [ "$root_gen_dir/chrome/webui_js_error_resources.pak" ]
  346. deps += [ "//chrome/browser/resources/webui_js_error:resources" ]
  347. }
  348. if (!is_android && !is_chromeos_ash) {
  349. sources += [
  350. "$root_gen_dir/chrome/intro_resources.pak",
  351. "$root_gen_dir/chrome/profile_picker_resources.pak",
  352. "$root_gen_dir/chrome/welcome_resources.pak",
  353. ]
  354. deps += [
  355. "//chrome/browser/resources/intro:resources",
  356. "//chrome/browser/resources/signin/profile_picker:resources",
  357. "//chrome/browser/resources/welcome:resources",
  358. ]
  359. }
  360. if (is_win || is_mac || is_linux || is_fuchsia) {
  361. sources += [ "$root_gen_dir/chrome/apps_resources.pak" ]
  362. deps += [ "//chrome/browser/resources/ntp4:apps_resources" ]
  363. }
  364. if (is_win || is_mac || is_linux) {
  365. sources += [ "$root_gen_dir/chrome/app_settings_resources.pak" ]
  366. deps += [ "//chrome/browser/resources/app_settings:resources" ]
  367. }
  368. if (is_win || is_mac || is_linux || is_chromeos_ash) {
  369. sources += [ "$root_gen_dir/chrome/connectors_internals_resources.pak" ]
  370. deps += [ "//chrome/browser/resources/connectors_internals:resources" ]
  371. }
  372. if (is_win || is_mac || is_linux || is_chromeos_lacros || is_fuchsia) {
  373. sources += [ "$root_gen_dir/chrome/browser_switch_resources.pak" ]
  374. deps += [ "//chrome/browser/resources/browser_switch:resources" ]
  375. }
  376. if (is_win || is_mac || is_linux || is_chromeos || is_fuchsia) {
  377. sources += [ "$root_gen_dir/chrome/discards_resources.pak" ]
  378. deps += [ "//chrome/browser/resources/discards:resources" ]
  379. }
  380. if (enable_extensions) {
  381. sources += [
  382. "$root_gen_dir/chrome/extensions_resources.pak",
  383. "$root_gen_dir/chrome/sync_file_system_internals_resources.pak",
  384. "$root_gen_dir/extensions/extensions_renderer_resources.pak",
  385. "$root_gen_dir/extensions/extensions_resources.pak",
  386. ]
  387. deps += [
  388. "//chrome/browser/resources/extensions:resources",
  389. "//chrome/browser/resources/sync_file_system_internals:resources",
  390. "//extensions:extensions_resources",
  391. ]
  392. }
  393. if (enable_pdf) {
  394. sources += [ "$root_gen_dir/chrome/pdf_resources.pak" ]
  395. deps += [ "//chrome/browser/resources/pdf:resources" ]
  396. }
  397. if (enable_print_preview) {
  398. sources += [ "$root_gen_dir/chrome/print_preview_resources.pak" ]
  399. deps += [ "//chrome/browser/resources/print_preview:resources" ]
  400. }
  401. if (enable_webui_tab_strip) {
  402. sources += [ "$root_gen_dir/chrome/tab_strip_resources.pak" ]
  403. deps += [ "//chrome/browser/resources/tab_strip:resources" ]
  404. }
  405. if (is_cfm) {
  406. sources += [ "$root_gen_dir/chrome/cfm_network_settings_resources.pak" ]
  407. deps += [
  408. "//chrome/browser/resources/chromeos/chromebox_for_meetings:resources",
  409. ]
  410. }
  411. }
  412. }
  413. # Defines repack() targets used by Chrome. Specifically:
  414. # * chrome_100_percent.pak
  415. # * chrome_200_percent.pak (optionally)
  416. # * resources.pak
  417. # * locale .pak files
  418. #
  419. # Parameters:
  420. # output_dir [required]: Directory to output .pak files. Locale .pak files
  421. # will always be place in $output_dir/locales
  422. # additional_extra_paks: List of extra .pak sources for resources.pak.
  423. # locale_allowlist: if set, override repack_allowlist for locale .pak files.
  424. # files_to_hash: if set, a list of pak file names to generate SHA256 hashes
  425. # for.
  426. # copy_data_to_bundle:
  427. # deps:
  428. # mark_as_data:
  429. # output_dir:
  430. # public_deps:
  431. # repack_allowlist:
  432. # visibility:
  433. # Normal meanings.
  434. #
  435. template("chrome_paks") {
  436. chrome_repack_percent("${target_name}_100_percent") {
  437. percent = "100"
  438. forward_variables_from(invoker,
  439. [
  440. "copy_data_to_bundle",
  441. "deps",
  442. "mark_as_data",
  443. "output_dir",
  444. "repack_allowlist",
  445. "visibility",
  446. ])
  447. }
  448. if (enable_hidpi) {
  449. chrome_repack_percent("${target_name}_200_percent") {
  450. percent = "200"
  451. forward_variables_from(invoker,
  452. [
  453. "copy_data_to_bundle",
  454. "deps",
  455. "mark_as_data",
  456. "output_dir",
  457. "repack_allowlist",
  458. "visibility",
  459. ])
  460. }
  461. }
  462. chrome_extra_paks("${target_name}_extra") {
  463. forward_variables_from(invoker,
  464. [
  465. "copy_data_to_bundle",
  466. "deps",
  467. "mark_as_data",
  468. "output_dir",
  469. "repack_allowlist",
  470. "visibility",
  471. ])
  472. if (defined(invoker.additional_extra_paks)) {
  473. additional_paks = invoker.additional_extra_paks
  474. }
  475. }
  476. chrome_repack_locales("${target_name}_locales") {
  477. forward_variables_from(invoker,
  478. [
  479. "copy_data_to_bundle",
  480. "deps",
  481. "mark_as_data",
  482. "visibility",
  483. ])
  484. if (defined(invoker.locale_allowlist)) {
  485. repack_allowlist = invoker.locale_allowlist
  486. } else if (defined(invoker.repack_allowlist)) {
  487. repack_allowlist = invoker.repack_allowlist
  488. }
  489. input_locales = platform_pak_locales
  490. output_dir = "${invoker.output_dir}/locales"
  491. if (is_mac) {
  492. output_locales = locales_as_apple_outputs
  493. } else {
  494. output_locales = platform_pak_locales
  495. }
  496. }
  497. group(target_name) {
  498. forward_variables_from(invoker, [ "deps" ])
  499. public_deps = [
  500. ":${target_name}_100_percent",
  501. ":${target_name}_extra",
  502. ":${target_name}_locales",
  503. ]
  504. if (enable_hidpi) {
  505. public_deps += [ ":${target_name}_200_percent" ]
  506. }
  507. if (defined(invoker.public_deps)) {
  508. public_deps += invoker.public_deps
  509. }
  510. }
  511. if (defined(invoker.files_to_hash)) {
  512. _prefix = "$target_gen_dir/app/${target_name}_integrity"
  513. _integrity_outputs = [
  514. "$_prefix.cc",
  515. "$_prefix.h",
  516. ]
  517. action("${target_name}_integrity_hash") {
  518. script = "tools/build/sha256_file.py"
  519. outputs = _integrity_outputs
  520. inputs = []
  521. foreach(file, invoker.files_to_hash) {
  522. inputs += [ "${invoker.output_dir}/$file" ]
  523. }
  524. args = rebase_path([ _prefix ] + inputs, root_build_dir)
  525. deps = [ ":${invoker.target_name}" ]
  526. }
  527. source_set("${target_name}_integrity") {
  528. sources = _integrity_outputs
  529. deps = [ ":${target_name}_hash" ]
  530. }
  531. }
  532. }