start.S 2.3 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114
  1. /* SPDX-License-Identifier: GPL-2.0-or-later */
  2. /**
  3. ******************************************************************************
  4. * @file start.S
  5. * @author StarFive Technology
  6. * @version V1.0
  7. * @date 06/25/2020
  8. * @brief
  9. ******************************************************************************
  10. * @copy
  11. *
  12. * THE PRESENT SOFTWARE WHICH IS FOR GUIDANCE ONLY AIMS AT PROVIDING CUSTOMERS
  13. * WITH CODING INFORMATION REGARDING THEIR PRODUCTS IN ORDER FOR THEM TO SAVE
  14. * TIME. AS A RESULT, STARFIVE SHALL NOT BE HELD LIABLE FOR ANY
  15. * DIRECT, INDIRECT OR CONSEQUENTIAL DAMAGES WITH RESPECT TO ANY CLAIMS ARISING
  16. * FROM THE CONTENT OF SUCH SOFTWARE AND/OR THE USE MADE BY CUSTOMERS OF THE
  17. * CODING INFORMATION CONTAINED HEREIN IN CONNECTION WITH THEIR PRODUCTS.
  18. *
  19. * COPYRIGHT 2020 Shanghai StarFive Technology Co., Ltd.
  20. */
  21. #include "encoding.h"
  22. #include "platform.h"
  23. #include "sys.h"
  24. /* This is defined in sifive/platform.h, but that can't be included from
  25. * assembly. */
  26. .section .init
  27. .globl _start
  28. _start:
  29. la t0, trap_entry
  30. csrw mtvec, t0
  31. csrwi mstatus, 0
  32. csrwi mie, 0
  33. // Allocate 4 KiB stack for each hart
  34. csrr t0, mhartid
  35. slli t0, t0, 12
  36. la sp, _sp
  37. sub sp, sp, t0
  38. li a1, NONSMP_HART;
  39. csrr a0, mhartid;
  40. bne a0, a1, .LbootOtherHart //other hart
  41. // Load data section
  42. la t0, _data_lma
  43. la t1, _data
  44. beq t0, t1, 2f
  45. la t2, _edata
  46. bgeu t1, t2, 2f
  47. 1:
  48. ld t3, 0(t0)
  49. sd t3, 0(t1)
  50. addi t0, t0, 8
  51. addi t1, t1, 8
  52. bltu t1, t2, 1b
  53. 2:
  54. /* Clear bss section */
  55. la t1, _bss_start
  56. la t2, _bss_end
  57. bgeu t1, t2, 4f
  58. 3:
  59. sd x0, 0(t1)
  60. addi t1, t1, 8
  61. blt t1, t2, 3b
  62. 4:
  63. /*only hart 0*/
  64. call BootMain
  65. j .enter_uboot
  66. .LbootOtherHart:
  67. li s1, CLINT_CTRL_ADDR
  68. csrr a0, mhartid
  69. slli s2, a0, 2
  70. add s2, s2, s1
  71. sw zero, 0(s2)
  72. fence
  73. csrw mip, 0
  74. # core 1 jumps to main_other_hart
  75. # Set MSIE bit to receive IPI
  76. li a2, MIP_MSIP
  77. csrw mie, a2
  78. .LwaitOtherHart:
  79. # Wait for an IPI to signal that its safe to boot
  80. // call second_hart
  81. wfi
  82. # Only start if MIP_MSIP is set
  83. csrr a2, mip
  84. andi a2, a2, MIP_MSIP
  85. beqz a2, .LwaitOtherHart
  86. li s1, CLINT_CTRL_ADDR
  87. csrr a0, mhartid
  88. slli s2, a0, 2
  89. add s2, s2, s1
  90. sw zero, 0(s2)
  91. fence
  92. csrw mip, 0
  93. li a2, NUM_CORES
  94. bltu a0, a2, .enter_uboot
  95. j .LwaitOtherHart
  96. .enter_uboot:
  97. li t0, DEFAULT_DDR_ADDR
  98. csrr a0, mhartid
  99. la a1, 0
  100. jr t0