ktigcc.pro 3.6 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145
  1. TEMPLATE = app
  2. LANGUAGE = C++
  3. CONFIG += qt warn_on debug
  4. LIBS += -lktexteditor -lqassistantclient -lkutils
  5. HEADERS += tpr.h \
  6. ktigcc.h \
  7. preferences.h \
  8. srcfile.h
  9. SOURCES += ktigcc.cpp \
  10. preferences.cpp \
  11. tpr.cpp
  12. FORMS = srcfilewin.ui \
  13. projectoptions.ui \
  14. programoptions.ui \
  15. preferencesdlg.ui \
  16. mainform.ui
  17. IMAGES = images/00 \
  18. images/01 \
  19. images/02 \
  20. images/03 \
  21. images/04 \
  22. images/05 \
  23. images/06 \
  24. images/07 \
  25. images/08 \
  26. images/09 \
  27. images/10 \
  28. images/11 \
  29. images/12 \
  30. images/13 \
  31. images/14 \
  32. images/15 \
  33. images/16 \
  34. images/17 \
  35. images/18 \
  36. images/19 \
  37. images/20 \
  38. images/21 \
  39. images/22 \
  40. images/23 \
  41. images/24 \
  42. images/25 \
  43. images/26 \
  44. images/27 \
  45. images/tpr.png \
  46. images/folder1.png \
  47. images/folder2.png \
  48. images/filec.png \
  49. images/fileh.png \
  50. images/fileo.png \
  51. images/files.png \
  52. images/filet.png \
  53. images/filex.png \
  54. images/icon.png \
  55. images/filereplace.png
  56. # If this is not used, a build from /usr/.... will generate
  57. # Makefiles with relative paths for install. This totally
  58. # fucks up using INSTALL_ROOT for a staged install.
  59. # See http://bugs.debian.org/180240
  60. # (Thanks to Debian for the fix for this qmake stupidity.)
  61. QMAKE_PROJECT_DEPTH=1
  62. unix {
  63. UI_DIR = .ui
  64. MOC_DIR = .moc
  65. OBJECTS_DIR = .obj
  66. }
  67. KDEPREFIX = $$system(kde-config --prefix)
  68. isEmpty(KDEPREFIX):error(KDE 3 kdelibs required.)
  69. exists($$KDEPREFIX/include/kde3) {
  70. INCLUDEPATH += $$KDEPREFIX/include/kde3
  71. } else:exists($$KDEPREFIX/include/kde) {
  72. INCLUDEPATH += $$KDEPREFIX/include/kde
  73. } else {
  74. INCLUDEPATH += $$KDEPREFIX/include
  75. }
  76. KDELIBDIR = $$KDEPREFIX/lib$$system(kde-config --libsuffix)
  77. !equals(KDELIBDIR,/usr/lib):!equals(KDELIBDIR,/usr/lib64) {
  78. LIBS += -L"$$KDELIBDIR" -Wl,--rpath,"$$KDELIBDIR"
  79. }
  80. GLIB2_MINVERSION = 2.0.0
  81. HAVE_GLIB2 = $$system(pkg-config --atleast-version=$$GLIB2_MINVERSION glib-2.0 && echo yes || echo no)
  82. !equals(HAVE_GLIB2,yes):error(glib2 $$GLIB2_MINVERSION or higher required.)
  83. PKGCONFIG_CFLAGS += $$system(pkg-config --cflags glib-2.0)
  84. LIBS += $$system(pkg-config --libs glib-2.0)
  85. TICONV_MINVERSION = 0.0.1
  86. HAVE_TICONV = $$system(pkg-config --atleast-version=$$TICONV_MINVERSION ticonv && echo yes || echo no)
  87. !equals(HAVE_TICONV,yes):error(libticonv $$TICONV_MINVERSION or higher required.)
  88. PKGCONFIG_CFLAGS += $$system(pkg-config --cflags ticonv)
  89. LIBS += $$system(pkg-config --libs ticonv)
  90. TICABLES_MINVERSION = 0.0.1
  91. HAVE_TICABLES = $$system(pkg-config --atleast-version=$$TICABLES_MINVERSION ticables2 && echo yes || echo no)
  92. !equals(HAVE_TICABLES,yes):error(libticables2 $$TICABLES_MINVERSION or higher required.)
  93. PKGCONFIG_CFLAGS += $$system(pkg-config --cflags ticables2)
  94. LIBS += $$system(pkg-config --libs ticables2)
  95. syntaxfiles.path = /usr/share/apps/katepart/syntax/
  96. syntaxfiles.files = gnuasm68k.xml masm68k.xml
  97. INSTALLS += syntaxfiles
  98. TIGCC = $$(TIGCC)
  99. isEmpty(TIGCC) {
  100. TIGCC = /usr/local/tigcc
  101. }
  102. target.path = $$TIGCC/bin
  103. documentation.path = $$TIGCC/doc/ktigcc
  104. documentation.files = COPYING
  105. INSTALLS += target documentation
  106. CXXFLAGS = $$(CXXFLAGS)
  107. isEmpty(CXXFLAGS) {
  108. debug {
  109. CXXFLAGS = -Os -g
  110. } else {
  111. CXXFLAGS = -Os -s -fomit-frame-pointer
  112. }
  113. }
  114. QMAKE_CXXFLAGS_DEBUG = $$CXXFLAGS -Wno-non-virtual-dtor $$PKGCONFIG_CFLAGS
  115. QMAKE_CXXFLAGS_RELEASE = $$CXXFLAGS -Wno-non-virtual-dtor $$PKGCONFIG_CFLAGS
  116. QMAKE_LFLAGS_RELEASE = -s
  117. DISTFILES += $${syntaxfiles.files} $${documentation.files} configure KTIGCC.prj fedora/ktigcc.spec images/copyright.txt
  118. distbz2.target = dist-bzip2
  119. distbz2.commands = zcat ktigcc.tar.gz | bzip2 --best -c > ktigcc.tar.bz2
  120. distbz2.depends = dist
  121. rpm.target = rpm
  122. rpm.commands = rpmbuild -ta ktigcc.tar.bz2
  123. rpm.depends = distbz2
  124. QMAKE_EXTRA_UNIX_TARGETS += distbz2 rpm