ktigcc.pro 3.8 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150
  1. TEMPLATE = app
  2. LANGUAGE = C++
  3. CONFIG += qt warn_on debug
  4. LIBS += -lktexteditor -lqassistantclient -lkutils
  5. HEADERS += tpr.h \
  6. ktigcc.h \
  7. preferences.h \
  8. srcfile.h
  9. SOURCES += ktigcc.cpp \
  10. preferences.cpp \
  11. tpr.cpp
  12. FORMS = srcfilewin.ui \
  13. projectoptions.ui \
  14. programoptions.ui \
  15. preferencesdlg.ui \
  16. mainform.ui \
  17. errorlist.ui
  18. IMAGES = images/00 \
  19. images/01 \
  20. images/02 \
  21. images/03 \
  22. images/04 \
  23. images/05 \
  24. images/06 \
  25. images/07 \
  26. images/08 \
  27. images/09 \
  28. images/10 \
  29. images/11 \
  30. images/12 \
  31. images/13 \
  32. images/14 \
  33. images/15 \
  34. images/16 \
  35. images/17 \
  36. images/18 \
  37. images/19 \
  38. images/20 \
  39. images/21 \
  40. images/22 \
  41. images/23 \
  42. images/24 \
  43. images/25 \
  44. images/26 \
  45. images/27 \
  46. images/tpr.png \
  47. images/folder1.png \
  48. images/folder2.png \
  49. images/filec.png \
  50. images/fileh.png \
  51. images/fileo.png \
  52. images/files.png \
  53. images/filet.png \
  54. images/filex.png \
  55. images/icon.png \
  56. images/filereplace.png
  57. # If this is not used, a build from /usr/.... will generate
  58. # Makefiles with relative paths for install. This totally
  59. # fucks up using INSTALL_ROOT for a staged install.
  60. # See http://bugs.debian.org/180240
  61. # (Thanks to Debian for the fix for this qmake stupidity.)
  62. QMAKE_PROJECT_DEPTH=1
  63. unix {
  64. UI_DIR = .ui
  65. MOC_DIR = .moc
  66. OBJECTS_DIR = .obj
  67. }
  68. !exists($$[QT_INSTALL_PREFIX]/include/qassistantclient.h) {
  69. error("Qt Assistant 3 headers required, try installing qt3-apps-dev.")
  70. }
  71. KDEPREFIX = $$system(kde-config --prefix)
  72. isEmpty(KDEPREFIX):error(KDE 3 kdelibs required.)
  73. exists($$KDEPREFIX/include/kde3) {
  74. INCLUDEPATH += $$KDEPREFIX/include/kde3
  75. } else:exists($$KDEPREFIX/include/kde) {
  76. INCLUDEPATH += $$KDEPREFIX/include/kde
  77. } else {
  78. INCLUDEPATH += $$KDEPREFIX/include
  79. }
  80. KDELIBDIR = $$KDEPREFIX/lib$$system(kde-config --libsuffix)
  81. !equals(KDELIBDIR,/usr/lib):!equals(KDELIBDIR,/usr/lib64) {
  82. LIBS += -L"$$KDELIBDIR" -Wl,--rpath,"$$KDELIBDIR"
  83. }
  84. GLIB2_MINVERSION = 2.0.0
  85. HAVE_GLIB2 = $$system(pkg-config --atleast-version=$$GLIB2_MINVERSION glib-2.0 && echo yes || echo no)
  86. !equals(HAVE_GLIB2,yes):error(glib2 $$GLIB2_MINVERSION or higher required.)
  87. PKGCONFIG_CFLAGS += $$system(pkg-config --cflags glib-2.0)
  88. LIBS += $$system(pkg-config --libs glib-2.0)
  89. TICONV_MINVERSION = 0.0.1
  90. HAVE_TICONV = $$system(pkg-config --atleast-version=$$TICONV_MINVERSION ticonv && echo yes || echo no)
  91. !equals(HAVE_TICONV,yes):error(libticonv $$TICONV_MINVERSION or higher required.)
  92. PKGCONFIG_CFLAGS += $$system(pkg-config --cflags ticonv)
  93. LIBS += $$system(pkg-config --libs ticonv)
  94. TICABLES_MINVERSION = 0.0.1
  95. HAVE_TICABLES = $$system(pkg-config --atleast-version=$$TICABLES_MINVERSION ticables2 && echo yes || echo no)
  96. !equals(HAVE_TICABLES,yes):error(libticables2 $$TICABLES_MINVERSION or higher required.)
  97. PKGCONFIG_CFLAGS += $$system(pkg-config --cflags ticables2)
  98. LIBS += $$system(pkg-config --libs ticables2)
  99. syntaxfiles.path = /usr/share/apps/katepart/syntax/
  100. syntaxfiles.files = gnuasm68k.xml masm68k.xml
  101. INSTALLS += syntaxfiles
  102. TIGCC = $$(TIGCC)
  103. isEmpty(TIGCC) {
  104. TIGCC = /usr/local/tigcc
  105. }
  106. target.path = $$TIGCC/bin
  107. documentation.path = $$TIGCC/doc/ktigcc
  108. documentation.files = COPYING
  109. INSTALLS += target documentation
  110. CXXFLAGS = $$(CXXFLAGS)
  111. isEmpty(CXXFLAGS) {
  112. debug {
  113. CXXFLAGS = -Os -g
  114. } else {
  115. CXXFLAGS = -Os -s -fomit-frame-pointer
  116. }
  117. }
  118. QMAKE_CXXFLAGS_DEBUG = $$CXXFLAGS -Wno-non-virtual-dtor $$PKGCONFIG_CFLAGS
  119. QMAKE_CXXFLAGS_RELEASE = $$CXXFLAGS -Wno-non-virtual-dtor $$PKGCONFIG_CFLAGS
  120. QMAKE_LFLAGS_RELEASE = -s
  121. DISTFILES += $${syntaxfiles.files} $${documentation.files} INSTALL configure KTIGCC.prj fedora/ktigcc.spec images/copyright.txt
  122. distbz2.target = dist-bzip2
  123. distbz2.commands = zcat ktigcc.tar.gz | bzip2 --best -c > ktigcc.tar.bz2
  124. distbz2.depends = dist
  125. rpm.target = rpm
  126. rpm.commands = rpmbuild -ta ktigcc.tar.bz2
  127. rpm.depends = distbz2
  128. QMAKE_EXTRA_UNIX_TARGETS += distbz2 rpm