ktigcc.pro 4.9 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178
  1. TEMPLATE = app
  2. LANGUAGE = C++
  3. CONFIG += qt warn_on debug
  4. LIBS += -lktexteditor -lqassistantclient -lkutils
  5. HEADERS += tpr.h \
  6. ktigcc.h \
  7. preferences.h \
  8. srcfile.h \
  9. tiemu.h \
  10. tiemu_stub.h \
  11. callbacks.h \
  12. parsing.h
  13. SOURCES += ktigcc.cpp \
  14. preferences.cpp \
  15. tpr.cpp \
  16. tiemu_stub.cpp \
  17. callbacks.cpp \
  18. parsing.cpp
  19. FORMS = srcfilewin.ui \
  20. projectoptions.ui \
  21. programoptions.ui \
  22. preferencesdlg.ui \
  23. mainform.ui \
  24. errorlist.ui \
  25. programoutput.ui \
  26. functions.ui
  27. IMAGES = images/00 \
  28. images/01 \
  29. images/02 \
  30. images/03 \
  31. images/04 \
  32. images/05 \
  33. images/06 \
  34. images/07 \
  35. images/08 \
  36. images/09 \
  37. images/10 \
  38. images/11 \
  39. images/12 \
  40. images/13 \
  41. images/14 \
  42. images/15 \
  43. images/16 \
  44. images/17 \
  45. images/18 \
  46. images/19 \
  47. images/20 \
  48. images/21 \
  49. images/22 \
  50. images/23 \
  51. images/24 \
  52. images/25 \
  53. images/26 \
  54. images/27 \
  55. images/tpr.png \
  56. images/folder1.png \
  57. images/folder2.png \
  58. images/filec.png \
  59. images/fileh.png \
  60. images/fileo.png \
  61. images/files.png \
  62. images/filet.png \
  63. images/filex.png \
  64. images/icon.png \
  65. images/filereplace.png \
  66. images/error.png \
  67. images/warning.png \
  68. images/info.png
  69. # If this is not used, a build from /usr/.... will generate
  70. # Makefiles with relative paths for install. This totally
  71. # fucks up using INSTALL_ROOT for a staged install.
  72. # See http://bugs.debian.org/180240
  73. # (Thanks to Debian for the fix for this qmake stupidity.)
  74. QMAKE_PROJECT_DEPTH=1
  75. unix {
  76. UI_DIR = .ui
  77. MOC_DIR = .moc
  78. OBJECTS_DIR = .obj
  79. }
  80. !exists($$[QT_INSTALL_PREFIX]/include/qassistantclient.h) {
  81. error("Qt Assistant 3 headers required, try installing qt3-apps-dev.")
  82. }
  83. KDEPREFIX = $$system(kde-config --prefix)
  84. isEmpty(KDEPREFIX):error(KDE 3 kdelibs required.)
  85. exists($$KDEPREFIX/include/kde3) {
  86. INCLUDEPATH += $$KDEPREFIX/include/kde3
  87. } else:exists($$KDEPREFIX/include/kde) {
  88. INCLUDEPATH += $$KDEPREFIX/include/kde
  89. } else {
  90. INCLUDEPATH += $$KDEPREFIX/include
  91. }
  92. KDELIBDIR = $$KDEPREFIX/lib$$system(kde-config --libsuffix)
  93. !equals(KDELIBDIR,/usr/lib):!equals(KDELIBDIR,/usr/lib64) {
  94. LIBS += -L"$$KDELIBDIR" -Wl,--rpath,"$$KDELIBDIR"
  95. }
  96. GLIB2_MINVERSION = 2.0.0
  97. HAVE_GLIB2 = $$system(pkg-config --atleast-version=$$GLIB2_MINVERSION glib-2.0 && echo yes || echo no)
  98. !equals(HAVE_GLIB2,yes):error(glib2 $$GLIB2_MINVERSION or higher required.)
  99. PKGCONFIG_CFLAGS += $$system(pkg-config --cflags glib-2.0)
  100. LIBS += $$system(pkg-config --libs glib-2.0)
  101. TICONV_MINVERSION = 0.0.1
  102. HAVE_TICONV = $$system(pkg-config --atleast-version=$$TICONV_MINVERSION ticonv && echo yes || echo no)
  103. !equals(HAVE_TICONV,yes):error(libticonv $$TICONV_MINVERSION or higher required.)
  104. PKGCONFIG_CFLAGS += $$system(pkg-config --cflags ticonv)
  105. LIBS += $$system(pkg-config --libs ticonv)
  106. TICABLES_MINVERSION = 0.0.1
  107. HAVE_TICABLES = $$system(pkg-config --atleast-version=$$TICABLES_MINVERSION ticables2 && echo yes || echo no)
  108. !equals(HAVE_TICABLES,yes):error(libticables2 $$TICABLES_MINVERSION or higher required.)
  109. PKGCONFIG_CFLAGS += $$system(pkg-config --cflags ticables2)
  110. LIBS += $$system(pkg-config --libs ticables2)
  111. # Minimum version for ticables_is_usb_enabled
  112. TICABLES_IS_USB_ENABLED_MINVERSION = 0.1.3
  113. HAVE_TICABLES_IS_USB_ENABLED = $$system(pkg-config --atleast-version=$$TICABLES_IS_USB_ENABLED_MINVERSION ticables2 && echo yes || echo no)
  114. equals(HAVE_TICABLES_IS_USB_ENABLED,yes):PKGCONFIG_CFLAGS += -DHAVE_TICABLES_IS_USB_ENABLED
  115. TIFILES_MINVERSION = 0.0.9
  116. HAVE_TIFILES = $$system(pkg-config --atleast-version=$$TIFILES_MINVERSION tifiles2 && echo yes || echo no)
  117. !equals(HAVE_TIFILES,yes):error(libtifiles2 $$TIFILES_MINVERSION or higher required.)
  118. PKGCONFIG_CFLAGS += $$system(pkg-config --cflags tifiles2)
  119. LIBS += $$system(pkg-config --libs tifiles2)
  120. TICALCS_MINVERSION = 0.1.0
  121. HAVE_TICALCS = $$system(pkg-config --atleast-version=$$TICALCS_MINVERSION ticalcs2 && echo yes || echo no)
  122. !equals(HAVE_TICALCS,yes):error(libticalcs2 $$TICALCS_MINVERSION or higher required.)
  123. PKGCONFIG_CFLAGS += $$system(pkg-config --cflags ticalcs2)
  124. LIBS += $$system(pkg-config --libs ticalcs2)
  125. syntaxfiles.path = /usr/share/apps/katepart/syntax/
  126. syntaxfiles.files = gnuasm68k.xml masm68k.xml
  127. INSTALLS += syntaxfiles
  128. TIGCC = $$(TIGCC)
  129. isEmpty(TIGCC) {
  130. TIGCC = /usr/local/tigcc
  131. }
  132. target.path = $$TIGCC/bin
  133. documentation.path = $$TIGCC/doc/ktigcc
  134. documentation.files = COPYING
  135. INSTALLS += target documentation
  136. CXXFLAGS = $$(CXXFLAGS)
  137. isEmpty(CXXFLAGS) {
  138. debug {
  139. CXXFLAGS = -Os -g
  140. } else {
  141. CXXFLAGS = -Os -s -fomit-frame-pointer
  142. }
  143. }
  144. QMAKE_CXXFLAGS_DEBUG = $$CXXFLAGS -Wno-non-virtual-dtor $$PKGCONFIG_CFLAGS
  145. QMAKE_CXXFLAGS_RELEASE = $$CXXFLAGS -Wno-non-virtual-dtor $$PKGCONFIG_CFLAGS
  146. QMAKE_LFLAGS_RELEASE = -s
  147. DISTFILES += $${syntaxfiles.files} $${documentation.files} INSTALL configure KTIGCC.prj fedora/ktigcc.spec images/copyright.txt
  148. distbz2.target = dist-bzip2
  149. distbz2.commands = zcat ktigcc.tar.gz | bzip2 --best -c > ktigcc.tar.bz2
  150. distbz2.depends = dist
  151. rpm.target = rpm
  152. rpm.commands = rpmbuild -ta ktigcc.tar.bz2
  153. rpm.depends = distbz2
  154. QMAKE_EXTRA_UNIX_TARGETS += distbz2 rpm