entry.S 31 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400401402403404405406407408409410411412413414415416417418419420421422423424425426427428429430431432433434435436437438439440441442443444445446447448449450451452453454455456457458459460461462463464465466467468469470471472473474475476477478479480481482483484485486487488489490491492493494495496497498499500501502503504505506507508509510511512513514515516517518519520521522523524525526527528529530531532533534535536537538539540541542543544545546547548549550551552553554555556557558559560561562563564565566567568569570571572573574575576577578579580581582583584585586587588589590591592593594595596597598599600601602603604605606607608609610611612613614615616617618619620621622623624625626627628629630631632633634635636637638639640641642643644645646647648649650651652653654655656657658659660661662663664665666667668669670671672673674675676677678679680681682683684685686687688689690691692693694695696697698699700701702703704705706707708709710711712713714715716717718719720721722723724725726727728729730731732733734735736737738739740741742743744745746747748749750751752753754755756757758759760761762763764765766767768769770771772773774775776777778779780781782783784785786787788789790791792793794795796797798799800801802803804805806807808809810811812813814815816817818819820821822823824825826827828829830831832833834835836837838839840841842843844845846847848849850851852853854855856857858859860861862863864865866867868869870871872873874875876877878879880881882883884885886887888889890891892893894895896897898899900901902903904905906907908909910911912913914915916917918919920921922923924925926927928929930931932933934935936937938939940941942943944945946947948949950951952953954955956957958959960961962963964965966967968969970971972973974975976977978979980981982983984985986987988989990991992993994995996997998999100010011002100310041005100610071008100910101011101210131014101510161017101810191020102110221023102410251026102710281029103010311032103310341035103610371038103910401041104210431044104510461047104810491050105110521053105410551056105710581059106010611062106310641065
  1. /*
  2. * arch/s390/kernel/entry.S
  3. * S390 low-level entry points.
  4. *
  5. * Copyright (C) IBM Corp. 1999,2006
  6. * Author(s): Martin Schwidefsky (schwidefsky@de.ibm.com),
  7. * Hartmut Penner (hp@de.ibm.com),
  8. * Denis Joseph Barrow (djbarrow@de.ibm.com,barrow_dj@yahoo.com),
  9. * Heiko Carstens <heiko.carstens@de.ibm.com>
  10. */
  11. #include <linux/sys.h>
  12. #include <linux/linkage.h>
  13. #include <asm/cache.h>
  14. #include <asm/lowcore.h>
  15. #include <asm/errno.h>
  16. #include <asm/ptrace.h>
  17. #include <asm/thread_info.h>
  18. #include <asm/asm-offsets.h>
  19. #include <asm/unistd.h>
  20. #include <asm/page.h>
  21. /*
  22. * Stack layout for the system_call stack entry.
  23. * The first few entries are identical to the user_regs_struct.
  24. */
  25. SP_PTREGS = STACK_FRAME_OVERHEAD
  26. SP_ARGS = STACK_FRAME_OVERHEAD + __PT_ARGS
  27. SP_PSW = STACK_FRAME_OVERHEAD + __PT_PSW
  28. SP_R0 = STACK_FRAME_OVERHEAD + __PT_GPRS
  29. SP_R1 = STACK_FRAME_OVERHEAD + __PT_GPRS + 4
  30. SP_R2 = STACK_FRAME_OVERHEAD + __PT_GPRS + 8
  31. SP_R3 = STACK_FRAME_OVERHEAD + __PT_GPRS + 12
  32. SP_R4 = STACK_FRAME_OVERHEAD + __PT_GPRS + 16
  33. SP_R5 = STACK_FRAME_OVERHEAD + __PT_GPRS + 20
  34. SP_R6 = STACK_FRAME_OVERHEAD + __PT_GPRS + 24
  35. SP_R7 = STACK_FRAME_OVERHEAD + __PT_GPRS + 28
  36. SP_R8 = STACK_FRAME_OVERHEAD + __PT_GPRS + 32
  37. SP_R9 = STACK_FRAME_OVERHEAD + __PT_GPRS + 36
  38. SP_R10 = STACK_FRAME_OVERHEAD + __PT_GPRS + 40
  39. SP_R11 = STACK_FRAME_OVERHEAD + __PT_GPRS + 44
  40. SP_R12 = STACK_FRAME_OVERHEAD + __PT_GPRS + 48
  41. SP_R13 = STACK_FRAME_OVERHEAD + __PT_GPRS + 52
  42. SP_R14 = STACK_FRAME_OVERHEAD + __PT_GPRS + 56
  43. SP_R15 = STACK_FRAME_OVERHEAD + __PT_GPRS + 60
  44. SP_ORIG_R2 = STACK_FRAME_OVERHEAD + __PT_ORIG_GPR2
  45. SP_ILC = STACK_FRAME_OVERHEAD + __PT_ILC
  46. SP_TRAP = STACK_FRAME_OVERHEAD + __PT_TRAP
  47. SP_SIZE = STACK_FRAME_OVERHEAD + __PT_SIZE
  48. _TIF_WORK_SVC = (_TIF_SIGPENDING | _TIF_RESTORE_SIGMASK | _TIF_NEED_RESCHED | \
  49. _TIF_MCCK_PENDING | _TIF_RESTART_SVC | _TIF_SINGLE_STEP )
  50. _TIF_WORK_INT = (_TIF_SIGPENDING | _TIF_RESTORE_SIGMASK | _TIF_NEED_RESCHED | \
  51. _TIF_MCCK_PENDING)
  52. STACK_SHIFT = PAGE_SHIFT + THREAD_ORDER
  53. STACK_SIZE = 1 << STACK_SHIFT
  54. #define BASED(name) name-system_call(%r13)
  55. #ifdef CONFIG_TRACE_IRQFLAGS
  56. .macro TRACE_IRQS_ON
  57. l %r1,BASED(.Ltrace_irq_on)
  58. basr %r14,%r1
  59. .endm
  60. .macro TRACE_IRQS_OFF
  61. l %r1,BASED(.Ltrace_irq_off)
  62. basr %r14,%r1
  63. .endm
  64. #else
  65. #define TRACE_IRQS_ON
  66. #define TRACE_IRQS_OFF
  67. #endif
  68. /*
  69. * Register usage in interrupt handlers:
  70. * R9 - pointer to current task structure
  71. * R13 - pointer to literal pool
  72. * R14 - return register for function calls
  73. * R15 - kernel stack pointer
  74. */
  75. .macro STORE_TIMER lc_offset
  76. #ifdef CONFIG_VIRT_CPU_ACCOUNTING
  77. stpt \lc_offset
  78. #endif
  79. .endm
  80. #ifdef CONFIG_VIRT_CPU_ACCOUNTING
  81. .macro UPDATE_VTIME lc_from,lc_to,lc_sum
  82. lm %r10,%r11,\lc_from
  83. sl %r10,\lc_to
  84. sl %r11,\lc_to+4
  85. bc 3,BASED(0f)
  86. sl %r10,BASED(.Lc_1)
  87. 0: al %r10,\lc_sum
  88. al %r11,\lc_sum+4
  89. bc 12,BASED(1f)
  90. al %r10,BASED(.Lc_1)
  91. 1: stm %r10,%r11,\lc_sum
  92. .endm
  93. #endif
  94. .macro SAVE_ALL_BASE savearea
  95. stm %r12,%r15,\savearea
  96. l %r13,__LC_SVC_NEW_PSW+4 # load &system_call to %r13
  97. .endm
  98. .macro SAVE_ALL_SYNC psworg,savearea
  99. la %r12,\psworg
  100. tm \psworg+1,0x01 # test problem state bit
  101. bz BASED(2f) # skip stack setup save
  102. l %r15,__LC_KERNEL_STACK # problem state -> load ksp
  103. #ifdef CONFIG_CHECK_STACK
  104. b BASED(3f)
  105. 2: tml %r15,STACK_SIZE - CONFIG_STACK_GUARD
  106. bz BASED(stack_overflow)
  107. 3:
  108. #endif
  109. 2:
  110. .endm
  111. .macro SAVE_ALL_ASYNC psworg,savearea
  112. la %r12,\psworg
  113. tm \psworg+1,0x01 # test problem state bit
  114. bnz BASED(1f) # from user -> load async stack
  115. clc \psworg+4(4),BASED(.Lcritical_end)
  116. bhe BASED(0f)
  117. clc \psworg+4(4),BASED(.Lcritical_start)
  118. bl BASED(0f)
  119. l %r14,BASED(.Lcleanup_critical)
  120. basr %r14,%r14
  121. tm 1(%r12),0x01 # retest problem state after cleanup
  122. bnz BASED(1f)
  123. 0: l %r14,__LC_ASYNC_STACK # are we already on the async stack ?
  124. slr %r14,%r15
  125. sra %r14,STACK_SHIFT
  126. be BASED(2f)
  127. 1: l %r15,__LC_ASYNC_STACK
  128. #ifdef CONFIG_CHECK_STACK
  129. b BASED(3f)
  130. 2: tml %r15,STACK_SIZE - CONFIG_STACK_GUARD
  131. bz BASED(stack_overflow)
  132. 3:
  133. #endif
  134. 2:
  135. .endm
  136. .macro CREATE_STACK_FRAME psworg,savearea
  137. s %r15,BASED(.Lc_spsize) # make room for registers & psw
  138. mvc SP_PSW(8,%r15),0(%r12) # move user PSW to stack
  139. la %r12,\psworg
  140. st %r2,SP_ORIG_R2(%r15) # store original content of gpr 2
  141. icm %r12,12,__LC_SVC_ILC
  142. stm %r0,%r11,SP_R0(%r15) # store gprs %r0-%r11 to kernel stack
  143. st %r12,SP_ILC(%r15)
  144. mvc SP_R12(16,%r15),\savearea # move %r12-%r15 to stack
  145. la %r12,0
  146. st %r12,__SF_BACKCHAIN(%r15) # clear back chain
  147. .endm
  148. .macro RESTORE_ALL psworg,sync
  149. mvc \psworg(8),SP_PSW(%r15) # move user PSW to lowcore
  150. .if !\sync
  151. ni \psworg+1,0xfd # clear wait state bit
  152. .endif
  153. lm %r0,%r15,SP_R0(%r15) # load gprs 0-15 of user
  154. STORE_TIMER __LC_EXIT_TIMER
  155. lpsw \psworg # back to caller
  156. .endm
  157. /*
  158. * Scheduler resume function, called by switch_to
  159. * gpr2 = (task_struct *) prev
  160. * gpr3 = (task_struct *) next
  161. * Returns:
  162. * gpr2 = prev
  163. */
  164. .globl __switch_to
  165. __switch_to:
  166. basr %r1,0
  167. __switch_to_base:
  168. tm __THREAD_per(%r3),0xe8 # new process is using per ?
  169. bz __switch_to_noper-__switch_to_base(%r1) # if not we're fine
  170. stctl %c9,%c11,__SF_EMPTY(%r15) # We are using per stuff
  171. clc __THREAD_per(12,%r3),__SF_EMPTY(%r15)
  172. be __switch_to_noper-__switch_to_base(%r1) # we got away w/o bashing TLB's
  173. lctl %c9,%c11,__THREAD_per(%r3) # Nope we didn't
  174. __switch_to_noper:
  175. l %r4,__THREAD_info(%r2) # get thread_info of prev
  176. tm __TI_flags+3(%r4),_TIF_MCCK_PENDING # machine check pending?
  177. bz __switch_to_no_mcck-__switch_to_base(%r1)
  178. ni __TI_flags+3(%r4),255-_TIF_MCCK_PENDING # clear flag in prev
  179. l %r4,__THREAD_info(%r3) # get thread_info of next
  180. oi __TI_flags+3(%r4),_TIF_MCCK_PENDING # set it in next
  181. __switch_to_no_mcck:
  182. stm %r6,%r15,__SF_GPRS(%r15)# store __switch_to registers of prev task
  183. st %r15,__THREAD_ksp(%r2) # store kernel stack to prev->tss.ksp
  184. l %r15,__THREAD_ksp(%r3) # load kernel stack from next->tss.ksp
  185. lm %r6,%r15,__SF_GPRS(%r15)# load __switch_to registers of next task
  186. st %r3,__LC_CURRENT # __LC_CURRENT = current task struct
  187. lctl %c4,%c4,__TASK_pid(%r3) # load pid to control reg. 4
  188. l %r3,__THREAD_info(%r3) # load thread_info from task struct
  189. st %r3,__LC_THREAD_INFO
  190. ahi %r3,STACK_SIZE
  191. st %r3,__LC_KERNEL_STACK # __LC_KERNEL_STACK = new kernel stack
  192. br %r14
  193. __critical_start:
  194. /*
  195. * SVC interrupt handler routine. System calls are synchronous events and
  196. * are executed with interrupts enabled.
  197. */
  198. .globl system_call
  199. system_call:
  200. STORE_TIMER __LC_SYNC_ENTER_TIMER
  201. sysc_saveall:
  202. SAVE_ALL_BASE __LC_SAVE_AREA
  203. SAVE_ALL_SYNC __LC_SVC_OLD_PSW,__LC_SAVE_AREA
  204. CREATE_STACK_FRAME __LC_SVC_OLD_PSW,__LC_SAVE_AREA
  205. lh %r7,0x8a # get svc number from lowcore
  206. #ifdef CONFIG_VIRT_CPU_ACCOUNTING
  207. sysc_vtime:
  208. tm SP_PSW+1(%r15),0x01 # interrupting from user ?
  209. bz BASED(sysc_do_svc)
  210. UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
  211. sysc_stime:
  212. UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
  213. sysc_update:
  214. mvc __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
  215. #endif
  216. sysc_do_svc:
  217. l %r9,__LC_THREAD_INFO # load pointer to thread_info struct
  218. sla %r7,2 # *4 and test for svc 0
  219. bnz BASED(sysc_nr_ok) # svc number > 0
  220. # svc 0: system call number in %r1
  221. cl %r1,BASED(.Lnr_syscalls)
  222. bnl BASED(sysc_nr_ok)
  223. lr %r7,%r1 # copy svc number to %r7
  224. sla %r7,2 # *4
  225. sysc_nr_ok:
  226. mvc SP_ARGS(4,%r15),SP_R7(%r15)
  227. sysc_do_restart:
  228. l %r8,BASED(.Lsysc_table)
  229. tm __TI_flags+3(%r9),(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT)
  230. l %r8,0(%r7,%r8) # get system call addr.
  231. bnz BASED(sysc_tracesys)
  232. basr %r14,%r8 # call sys_xxxx
  233. st %r2,SP_R2(%r15) # store return value (change R2 on stack)
  234. # ATTENTION: check sys_execve_glue before
  235. # changing anything here !!
  236. sysc_return:
  237. tm SP_PSW+1(%r15),0x01 # returning to user ?
  238. bno BASED(sysc_leave)
  239. tm __TI_flags+3(%r9),_TIF_WORK_SVC
  240. bnz BASED(sysc_work) # there is work to do (signals etc.)
  241. sysc_leave:
  242. RESTORE_ALL __LC_RETURN_PSW,1
  243. #
  244. # recheck if there is more work to do
  245. #
  246. sysc_work_loop:
  247. tm __TI_flags+3(%r9),_TIF_WORK_SVC
  248. bz BASED(sysc_leave) # there is no work to do
  249. #
  250. # One of the work bits is on. Find out which one.
  251. #
  252. sysc_work:
  253. tm __TI_flags+3(%r9),_TIF_MCCK_PENDING
  254. bo BASED(sysc_mcck_pending)
  255. tm __TI_flags+3(%r9),_TIF_NEED_RESCHED
  256. bo BASED(sysc_reschedule)
  257. tm __TI_flags+3(%r9),(_TIF_SIGPENDING | _TIF_RESTORE_SIGMASK)
  258. bnz BASED(sysc_sigpending)
  259. tm __TI_flags+3(%r9),_TIF_RESTART_SVC
  260. bo BASED(sysc_restart)
  261. tm __TI_flags+3(%r9),_TIF_SINGLE_STEP
  262. bo BASED(sysc_singlestep)
  263. b BASED(sysc_leave)
  264. #
  265. # _TIF_NEED_RESCHED is set, call schedule
  266. #
  267. sysc_reschedule:
  268. l %r1,BASED(.Lschedule)
  269. la %r14,BASED(sysc_work_loop)
  270. br %r1 # call scheduler
  271. #
  272. # _TIF_MCCK_PENDING is set, call handler
  273. #
  274. sysc_mcck_pending:
  275. l %r1,BASED(.Ls390_handle_mcck)
  276. la %r14,BASED(sysc_work_loop)
  277. br %r1 # TIF bit will be cleared by handler
  278. #
  279. # _TIF_SIGPENDING or _TIF_RESTORE_SIGMASK is set, call do_signal
  280. #
  281. sysc_sigpending:
  282. ni __TI_flags+3(%r9),255-_TIF_SINGLE_STEP # clear TIF_SINGLE_STEP
  283. la %r2,SP_PTREGS(%r15) # load pt_regs
  284. l %r1,BASED(.Ldo_signal)
  285. basr %r14,%r1 # call do_signal
  286. tm __TI_flags+3(%r9),_TIF_RESTART_SVC
  287. bo BASED(sysc_restart)
  288. tm __TI_flags+3(%r9),_TIF_SINGLE_STEP
  289. bo BASED(sysc_singlestep)
  290. b BASED(sysc_work_loop)
  291. #
  292. # _TIF_RESTART_SVC is set, set up registers and restart svc
  293. #
  294. sysc_restart:
  295. ni __TI_flags+3(%r9),255-_TIF_RESTART_SVC # clear TIF_RESTART_SVC
  296. l %r7,SP_R2(%r15) # load new svc number
  297. sla %r7,2
  298. mvc SP_R2(4,%r15),SP_ORIG_R2(%r15) # restore first argument
  299. lm %r2,%r6,SP_R2(%r15) # load svc arguments
  300. b BASED(sysc_do_restart) # restart svc
  301. #
  302. # _TIF_SINGLE_STEP is set, call do_single_step
  303. #
  304. sysc_singlestep:
  305. ni __TI_flags+3(%r9),255-_TIF_SINGLE_STEP # clear TIF_SINGLE_STEP
  306. mvi SP_TRAP+1(%r15),0x28 # set trap indication to pgm check
  307. la %r2,SP_PTREGS(%r15) # address of register-save area
  308. l %r1,BASED(.Lhandle_per) # load adr. of per handler
  309. la %r14,BASED(sysc_return) # load adr. of system return
  310. br %r1 # branch to do_single_step
  311. #
  312. # call trace before and after sys_call
  313. #
  314. sysc_tracesys:
  315. l %r1,BASED(.Ltrace)
  316. la %r2,SP_PTREGS(%r15) # load pt_regs
  317. la %r3,0
  318. srl %r7,2
  319. st %r7,SP_R2(%r15)
  320. basr %r14,%r1
  321. clc SP_R2(4,%r15),BASED(.Lnr_syscalls)
  322. bnl BASED(sysc_tracenogo)
  323. l %r8,BASED(.Lsysc_table)
  324. l %r7,SP_R2(%r15) # strace might have changed the
  325. sll %r7,2 # system call
  326. l %r8,0(%r7,%r8)
  327. sysc_tracego:
  328. lm %r3,%r6,SP_R3(%r15)
  329. l %r2,SP_ORIG_R2(%r15)
  330. basr %r14,%r8 # call sys_xxx
  331. st %r2,SP_R2(%r15) # store return value
  332. sysc_tracenogo:
  333. tm __TI_flags+3(%r9),(_TIF_SYSCALL_TRACE|_TIF_SYSCALL_AUDIT)
  334. bz BASED(sysc_return)
  335. l %r1,BASED(.Ltrace)
  336. la %r2,SP_PTREGS(%r15) # load pt_regs
  337. la %r3,1
  338. la %r14,BASED(sysc_return)
  339. br %r1
  340. #
  341. # a new process exits the kernel with ret_from_fork
  342. #
  343. .globl ret_from_fork
  344. ret_from_fork:
  345. l %r13,__LC_SVC_NEW_PSW+4
  346. l %r9,__LC_THREAD_INFO # load pointer to thread_info struct
  347. tm SP_PSW+1(%r15),0x01 # forking a kernel thread ?
  348. bo BASED(0f)
  349. st %r15,SP_R15(%r15) # store stack pointer for new kthread
  350. 0: l %r1,BASED(.Lschedtail)
  351. basr %r14,%r1
  352. TRACE_IRQS_ON
  353. stosm __SF_EMPTY(%r15),0x03 # reenable interrupts
  354. b BASED(sysc_return)
  355. #
  356. # clone, fork, vfork, exec and sigreturn need glue,
  357. # because they all expect pt_regs as parameter,
  358. # but are called with different parameter.
  359. # return-address is set up above
  360. #
  361. sys_clone_glue:
  362. la %r2,SP_PTREGS(%r15) # load pt_regs
  363. l %r1,BASED(.Lclone)
  364. br %r1 # branch to sys_clone
  365. sys_fork_glue:
  366. la %r2,SP_PTREGS(%r15) # load pt_regs
  367. l %r1,BASED(.Lfork)
  368. br %r1 # branch to sys_fork
  369. sys_vfork_glue:
  370. la %r2,SP_PTREGS(%r15) # load pt_regs
  371. l %r1,BASED(.Lvfork)
  372. br %r1 # branch to sys_vfork
  373. sys_execve_glue:
  374. la %r2,SP_PTREGS(%r15) # load pt_regs
  375. l %r1,BASED(.Lexecve)
  376. lr %r12,%r14 # save return address
  377. basr %r14,%r1 # call sys_execve
  378. ltr %r2,%r2 # check if execve failed
  379. bnz 0(%r12) # it did fail -> store result in gpr2
  380. b 4(%r12) # SKIP ST 2,SP_R2(15) after BASR 14,8
  381. # in system_call/sysc_tracesys
  382. sys_sigreturn_glue:
  383. la %r2,SP_PTREGS(%r15) # load pt_regs as parameter
  384. l %r1,BASED(.Lsigreturn)
  385. br %r1 # branch to sys_sigreturn
  386. sys_rt_sigreturn_glue:
  387. la %r2,SP_PTREGS(%r15) # load pt_regs as parameter
  388. l %r1,BASED(.Lrt_sigreturn)
  389. br %r1 # branch to sys_sigreturn
  390. sys_sigaltstack_glue:
  391. la %r4,SP_PTREGS(%r15) # load pt_regs as parameter
  392. l %r1,BASED(.Lsigaltstack)
  393. br %r1 # branch to sys_sigreturn
  394. /*
  395. * Program check handler routine
  396. */
  397. .globl pgm_check_handler
  398. pgm_check_handler:
  399. /*
  400. * First we need to check for a special case:
  401. * Single stepping an instruction that disables the PER event mask will
  402. * cause a PER event AFTER the mask has been set. Example: SVC or LPSW.
  403. * For a single stepped SVC the program check handler gets control after
  404. * the SVC new PSW has been loaded. But we want to execute the SVC first and
  405. * then handle the PER event. Therefore we update the SVC old PSW to point
  406. * to the pgm_check_handler and branch to the SVC handler after we checked
  407. * if we have to load the kernel stack register.
  408. * For every other possible cause for PER event without the PER mask set
  409. * we just ignore the PER event (FIXME: is there anything we have to do
  410. * for LPSW?).
  411. */
  412. STORE_TIMER __LC_SYNC_ENTER_TIMER
  413. SAVE_ALL_BASE __LC_SAVE_AREA
  414. tm __LC_PGM_INT_CODE+1,0x80 # check whether we got a per exception
  415. bnz BASED(pgm_per) # got per exception -> special case
  416. SAVE_ALL_SYNC __LC_PGM_OLD_PSW,__LC_SAVE_AREA
  417. CREATE_STACK_FRAME __LC_PGM_OLD_PSW,__LC_SAVE_AREA
  418. #ifdef CONFIG_VIRT_CPU_ACCOUNTING
  419. tm SP_PSW+1(%r15),0x01 # interrupting from user ?
  420. bz BASED(pgm_no_vtime)
  421. UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
  422. UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
  423. mvc __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
  424. pgm_no_vtime:
  425. #endif
  426. l %r9,__LC_THREAD_INFO # load pointer to thread_info struct
  427. l %r3,__LC_PGM_ILC # load program interruption code
  428. la %r8,0x7f
  429. nr %r8,%r3
  430. pgm_do_call:
  431. l %r7,BASED(.Ljump_table)
  432. sll %r8,2
  433. l %r7,0(%r8,%r7) # load address of handler routine
  434. la %r2,SP_PTREGS(%r15) # address of register-save area
  435. la %r14,BASED(sysc_return)
  436. br %r7 # branch to interrupt-handler
  437. #
  438. # handle per exception
  439. #
  440. pgm_per:
  441. tm __LC_PGM_OLD_PSW,0x40 # test if per event recording is on
  442. bnz BASED(pgm_per_std) # ok, normal per event from user space
  443. # ok its one of the special cases, now we need to find out which one
  444. clc __LC_PGM_OLD_PSW(8),__LC_SVC_NEW_PSW
  445. be BASED(pgm_svcper)
  446. # no interesting special case, ignore PER event
  447. lm %r12,%r15,__LC_SAVE_AREA
  448. lpsw 0x28
  449. #
  450. # Normal per exception
  451. #
  452. pgm_per_std:
  453. SAVE_ALL_SYNC __LC_PGM_OLD_PSW,__LC_SAVE_AREA
  454. CREATE_STACK_FRAME __LC_PGM_OLD_PSW,__LC_SAVE_AREA
  455. #ifdef CONFIG_VIRT_CPU_ACCOUNTING
  456. tm SP_PSW+1(%r15),0x01 # interrupting from user ?
  457. bz BASED(pgm_no_vtime2)
  458. UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
  459. UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
  460. mvc __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
  461. pgm_no_vtime2:
  462. #endif
  463. l %r9,__LC_THREAD_INFO # load pointer to thread_info struct
  464. l %r1,__TI_task(%r9)
  465. mvc __THREAD_per+__PER_atmid(2,%r1),__LC_PER_ATMID
  466. mvc __THREAD_per+__PER_address(4,%r1),__LC_PER_ADDRESS
  467. mvc __THREAD_per+__PER_access_id(1,%r1),__LC_PER_ACCESS_ID
  468. oi __TI_flags+3(%r9),_TIF_SINGLE_STEP # set TIF_SINGLE_STEP
  469. tm SP_PSW+1(%r15),0x01 # kernel per event ?
  470. bz BASED(kernel_per)
  471. l %r3,__LC_PGM_ILC # load program interruption code
  472. la %r8,0x7f
  473. nr %r8,%r3 # clear per-event-bit and ilc
  474. be BASED(sysc_return) # only per or per+check ?
  475. b BASED(pgm_do_call)
  476. #
  477. # it was a single stepped SVC that is causing all the trouble
  478. #
  479. pgm_svcper:
  480. SAVE_ALL_SYNC __LC_SVC_OLD_PSW,__LC_SAVE_AREA
  481. CREATE_STACK_FRAME __LC_SVC_OLD_PSW,__LC_SAVE_AREA
  482. #ifdef CONFIG_VIRT_CPU_ACCOUNTING
  483. tm SP_PSW+1(%r15),0x01 # interrupting from user ?
  484. bz BASED(pgm_no_vtime3)
  485. UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
  486. UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
  487. mvc __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
  488. pgm_no_vtime3:
  489. #endif
  490. lh %r7,0x8a # get svc number from lowcore
  491. l %r9,__LC_THREAD_INFO # load pointer to thread_info struct
  492. l %r1,__TI_task(%r9)
  493. mvc __THREAD_per+__PER_atmid(2,%r1),__LC_PER_ATMID
  494. mvc __THREAD_per+__PER_address(4,%r1),__LC_PER_ADDRESS
  495. mvc __THREAD_per+__PER_access_id(1,%r1),__LC_PER_ACCESS_ID
  496. oi __TI_flags+3(%r9),_TIF_SINGLE_STEP # set TIF_SINGLE_STEP
  497. TRACE_IRQS_ON
  498. stosm __SF_EMPTY(%r15),0x03 # reenable interrupts
  499. b BASED(sysc_do_svc)
  500. #
  501. # per was called from kernel, must be kprobes
  502. #
  503. kernel_per:
  504. mvi SP_TRAP+1(%r15),0x28 # set trap indication to pgm check
  505. la %r2,SP_PTREGS(%r15) # address of register-save area
  506. l %r1,BASED(.Lhandle_per) # load adr. of per handler
  507. la %r14,BASED(sysc_leave) # load adr. of system return
  508. br %r1 # branch to do_single_step
  509. /*
  510. * IO interrupt handler routine
  511. */
  512. .globl io_int_handler
  513. io_int_handler:
  514. STORE_TIMER __LC_ASYNC_ENTER_TIMER
  515. stck __LC_INT_CLOCK
  516. SAVE_ALL_BASE __LC_SAVE_AREA+16
  517. SAVE_ALL_ASYNC __LC_IO_OLD_PSW,__LC_SAVE_AREA+16
  518. CREATE_STACK_FRAME __LC_IO_OLD_PSW,__LC_SAVE_AREA+16
  519. #ifdef CONFIG_VIRT_CPU_ACCOUNTING
  520. tm SP_PSW+1(%r15),0x01 # interrupting from user ?
  521. bz BASED(io_no_vtime)
  522. UPDATE_VTIME __LC_EXIT_TIMER,__LC_ASYNC_ENTER_TIMER,__LC_USER_TIMER
  523. UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
  524. mvc __LC_LAST_UPDATE_TIMER(8),__LC_ASYNC_ENTER_TIMER
  525. io_no_vtime:
  526. #endif
  527. l %r9,__LC_THREAD_INFO # load pointer to thread_info struct
  528. TRACE_IRQS_OFF
  529. l %r1,BASED(.Ldo_IRQ) # load address of do_IRQ
  530. la %r2,SP_PTREGS(%r15) # address of register-save area
  531. basr %r14,%r1 # branch to standard irq handler
  532. TRACE_IRQS_ON
  533. io_return:
  534. tm SP_PSW+1(%r15),0x01 # returning to user ?
  535. #ifdef CONFIG_PREEMPT
  536. bno BASED(io_preempt) # no -> check for preemptive scheduling
  537. #else
  538. bno BASED(io_leave) # no-> skip resched & signal
  539. #endif
  540. tm __TI_flags+3(%r9),_TIF_WORK_INT
  541. bnz BASED(io_work) # there is work to do (signals etc.)
  542. io_leave:
  543. RESTORE_ALL __LC_RETURN_PSW,0
  544. io_done:
  545. #ifdef CONFIG_PREEMPT
  546. io_preempt:
  547. icm %r0,15,__TI_precount(%r9)
  548. bnz BASED(io_leave)
  549. l %r1,SP_R15(%r15)
  550. s %r1,BASED(.Lc_spsize)
  551. mvc SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
  552. xc __SF_BACKCHAIN(4,%r1),__SF_BACKCHAIN(%r1) # clear back chain
  553. lr %r15,%r1
  554. io_resume_loop:
  555. tm __TI_flags+3(%r9),_TIF_NEED_RESCHED
  556. bno BASED(io_leave)
  557. mvc __TI_precount(4,%r9),BASED(.Lc_pactive)
  558. stosm __SF_EMPTY(%r15),0x03 # reenable interrupts
  559. l %r1,BASED(.Lschedule)
  560. basr %r14,%r1 # call schedule
  561. stnsm __SF_EMPTY(%r15),0xfc # disable I/O and ext. interrupts
  562. xc __TI_precount(4,%r9),__TI_precount(%r9)
  563. b BASED(io_resume_loop)
  564. #endif
  565. #
  566. # switch to kernel stack, then check the TIF bits
  567. #
  568. io_work:
  569. l %r1,__LC_KERNEL_STACK
  570. s %r1,BASED(.Lc_spsize)
  571. mvc SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
  572. xc __SF_BACKCHAIN(4,%r1),__SF_BACKCHAIN(%r1) # clear back chain
  573. lr %r15,%r1
  574. #
  575. # One of the work bits is on. Find out which one.
  576. # Checked are: _TIF_SIGPENDING, _TIF_RESTORE_SIGMASK, _TIF_NEED_RESCHED
  577. # and _TIF_MCCK_PENDING
  578. #
  579. io_work_loop:
  580. tm __TI_flags+3(%r9),_TIF_MCCK_PENDING
  581. bo BASED(io_mcck_pending)
  582. tm __TI_flags+3(%r9),_TIF_NEED_RESCHED
  583. bo BASED(io_reschedule)
  584. tm __TI_flags+3(%r9),(_TIF_SIGPENDING | _TIF_RESTORE_SIGMASK)
  585. bnz BASED(io_sigpending)
  586. b BASED(io_leave)
  587. #
  588. # _TIF_MCCK_PENDING is set, call handler
  589. #
  590. io_mcck_pending:
  591. l %r1,BASED(.Ls390_handle_mcck)
  592. la %r14,BASED(io_work_loop)
  593. br %r1 # TIF bit will be cleared by handler
  594. #
  595. # _TIF_NEED_RESCHED is set, call schedule
  596. #
  597. io_reschedule:
  598. l %r1,BASED(.Lschedule)
  599. stosm __SF_EMPTY(%r15),0x03 # reenable interrupts
  600. basr %r14,%r1 # call scheduler
  601. stnsm __SF_EMPTY(%r15),0xfc # disable I/O and ext. interrupts
  602. tm __TI_flags+3(%r9),_TIF_WORK_INT
  603. bz BASED(io_leave) # there is no work to do
  604. b BASED(io_work_loop)
  605. #
  606. # _TIF_SIGPENDING or _TIF_RESTORE_SIGMASK is set, call do_signal
  607. #
  608. io_sigpending:
  609. stosm __SF_EMPTY(%r15),0x03 # reenable interrupts
  610. la %r2,SP_PTREGS(%r15) # load pt_regs
  611. l %r1,BASED(.Ldo_signal)
  612. basr %r14,%r1 # call do_signal
  613. stnsm __SF_EMPTY(%r15),0xfc # disable I/O and ext. interrupts
  614. b BASED(io_work_loop)
  615. /*
  616. * External interrupt handler routine
  617. */
  618. .globl ext_int_handler
  619. ext_int_handler:
  620. STORE_TIMER __LC_ASYNC_ENTER_TIMER
  621. stck __LC_INT_CLOCK
  622. SAVE_ALL_BASE __LC_SAVE_AREA+16
  623. SAVE_ALL_ASYNC __LC_EXT_OLD_PSW,__LC_SAVE_AREA+16
  624. CREATE_STACK_FRAME __LC_EXT_OLD_PSW,__LC_SAVE_AREA+16
  625. #ifdef CONFIG_VIRT_CPU_ACCOUNTING
  626. tm SP_PSW+1(%r15),0x01 # interrupting from user ?
  627. bz BASED(ext_no_vtime)
  628. UPDATE_VTIME __LC_EXIT_TIMER,__LC_ASYNC_ENTER_TIMER,__LC_USER_TIMER
  629. UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
  630. mvc __LC_LAST_UPDATE_TIMER(8),__LC_ASYNC_ENTER_TIMER
  631. ext_no_vtime:
  632. #endif
  633. l %r9,__LC_THREAD_INFO # load pointer to thread_info struct
  634. TRACE_IRQS_OFF
  635. la %r2,SP_PTREGS(%r15) # address of register-save area
  636. lh %r3,__LC_EXT_INT_CODE # get interruption code
  637. l %r1,BASED(.Ldo_extint)
  638. basr %r14,%r1
  639. TRACE_IRQS_ON
  640. b BASED(io_return)
  641. __critical_end:
  642. /*
  643. * Machine check handler routines
  644. */
  645. .globl mcck_int_handler
  646. mcck_int_handler:
  647. spt __LC_CPU_TIMER_SAVE_AREA # revalidate cpu timer
  648. lm %r0,%r15,__LC_GPREGS_SAVE_AREA # revalidate gprs
  649. SAVE_ALL_BASE __LC_SAVE_AREA+32
  650. la %r12,__LC_MCK_OLD_PSW
  651. tm __LC_MCCK_CODE,0x80 # system damage?
  652. bo BASED(mcck_int_main) # yes -> rest of mcck code invalid
  653. #ifdef CONFIG_VIRT_CPU_ACCOUNTING
  654. mvc __LC_SAVE_AREA+52(8),__LC_ASYNC_ENTER_TIMER
  655. mvc __LC_ASYNC_ENTER_TIMER(8),__LC_CPU_TIMER_SAVE_AREA
  656. tm __LC_MCCK_CODE+5,0x02 # stored cpu timer value valid?
  657. bo BASED(1f)
  658. la %r14,__LC_SYNC_ENTER_TIMER
  659. clc 0(8,%r14),__LC_ASYNC_ENTER_TIMER
  660. bl BASED(0f)
  661. la %r14,__LC_ASYNC_ENTER_TIMER
  662. 0: clc 0(8,%r14),__LC_EXIT_TIMER
  663. bl BASED(0f)
  664. la %r14,__LC_EXIT_TIMER
  665. 0: clc 0(8,%r14),__LC_LAST_UPDATE_TIMER
  666. bl BASED(0f)
  667. la %r14,__LC_LAST_UPDATE_TIMER
  668. 0: spt 0(%r14)
  669. mvc __LC_ASYNC_ENTER_TIMER(8),0(%r14)
  670. 1:
  671. #endif
  672. tm __LC_MCCK_CODE+2,0x09 # mwp + ia of old psw valid?
  673. bno BASED(mcck_int_main) # no -> skip cleanup critical
  674. tm __LC_MCK_OLD_PSW+1,0x01 # test problem state bit
  675. bnz BASED(mcck_int_main) # from user -> load async stack
  676. clc __LC_MCK_OLD_PSW+4(4),BASED(.Lcritical_end)
  677. bhe BASED(mcck_int_main)
  678. clc __LC_MCK_OLD_PSW+4(4),BASED(.Lcritical_start)
  679. bl BASED(mcck_int_main)
  680. l %r14,BASED(.Lcleanup_critical)
  681. basr %r14,%r14
  682. mcck_int_main:
  683. l %r14,__LC_PANIC_STACK # are we already on the panic stack?
  684. slr %r14,%r15
  685. sra %r14,PAGE_SHIFT
  686. be BASED(0f)
  687. l %r15,__LC_PANIC_STACK # load panic stack
  688. 0: CREATE_STACK_FRAME __LC_MCK_OLD_PSW,__LC_SAVE_AREA+32
  689. #ifdef CONFIG_VIRT_CPU_ACCOUNTING
  690. tm __LC_MCCK_CODE+2,0x08 # mwp of old psw valid?
  691. bno BASED(mcck_no_vtime) # no -> skip cleanup critical
  692. tm SP_PSW+1(%r15),0x01 # interrupting from user ?
  693. bz BASED(mcck_no_vtime)
  694. UPDATE_VTIME __LC_EXIT_TIMER,__LC_ASYNC_ENTER_TIMER,__LC_USER_TIMER
  695. UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
  696. mvc __LC_LAST_UPDATE_TIMER(8),__LC_ASYNC_ENTER_TIMER
  697. mcck_no_vtime:
  698. #endif
  699. l %r9,__LC_THREAD_INFO # load pointer to thread_info struct
  700. la %r2,SP_PTREGS(%r15) # load pt_regs
  701. l %r1,BASED(.Ls390_mcck)
  702. basr %r14,%r1 # call machine check handler
  703. tm SP_PSW+1(%r15),0x01 # returning to user ?
  704. bno BASED(mcck_return)
  705. l %r1,__LC_KERNEL_STACK # switch to kernel stack
  706. s %r1,BASED(.Lc_spsize)
  707. mvc SP_PTREGS(__PT_SIZE,%r1),SP_PTREGS(%r15)
  708. xc __SF_BACKCHAIN(4,%r1),__SF_BACKCHAIN(%r1) # clear back chain
  709. lr %r15,%r1
  710. stosm __SF_EMPTY(%r15),0x04 # turn dat on
  711. tm __TI_flags+3(%r9),_TIF_MCCK_PENDING
  712. bno BASED(mcck_return)
  713. TRACE_IRQS_OFF
  714. l %r1,BASED(.Ls390_handle_mcck)
  715. basr %r14,%r1 # call machine check handler
  716. TRACE_IRQS_ON
  717. mcck_return:
  718. mvc __LC_RETURN_MCCK_PSW(8),SP_PSW(%r15) # move return PSW
  719. ni __LC_RETURN_MCCK_PSW+1,0xfd # clear wait state bit
  720. #ifdef CONFIG_VIRT_CPU_ACCOUNTING
  721. mvc __LC_ASYNC_ENTER_TIMER(8),__LC_SAVE_AREA+52
  722. tm __LC_RETURN_MCCK_PSW+1,0x01 # returning to user ?
  723. bno BASED(0f)
  724. lm %r0,%r15,SP_R0(%r15) # load gprs 0-15
  725. stpt __LC_EXIT_TIMER
  726. lpsw __LC_RETURN_MCCK_PSW # back to caller
  727. 0:
  728. #endif
  729. lm %r0,%r15,SP_R0(%r15) # load gprs 0-15
  730. lpsw __LC_RETURN_MCCK_PSW # back to caller
  731. RESTORE_ALL __LC_RETURN_MCCK_PSW,0
  732. #ifdef CONFIG_SMP
  733. /*
  734. * Restart interruption handler, kick starter for additional CPUs
  735. */
  736. .globl restart_int_handler
  737. restart_int_handler:
  738. l %r15,__LC_SAVE_AREA+60 # load ksp
  739. lctl %c0,%c15,__LC_CREGS_SAVE_AREA # get new ctl regs
  740. lam %a0,%a15,__LC_AREGS_SAVE_AREA
  741. lm %r6,%r15,__SF_GPRS(%r15) # load registers from clone
  742. stosm __SF_EMPTY(%r15),0x04 # now we can turn dat on
  743. basr %r14,0
  744. l %r14,restart_addr-.(%r14)
  745. br %r14 # branch to start_secondary
  746. restart_addr:
  747. .long start_secondary
  748. #else
  749. /*
  750. * If we do not run with SMP enabled, let the new CPU crash ...
  751. */
  752. .globl restart_int_handler
  753. restart_int_handler:
  754. basr %r1,0
  755. restart_base:
  756. lpsw restart_crash-restart_base(%r1)
  757. .align 8
  758. restart_crash:
  759. .long 0x000a0000,0x00000000
  760. restart_go:
  761. #endif
  762. #ifdef CONFIG_CHECK_STACK
  763. /*
  764. * The synchronous or the asynchronous stack overflowed. We are dead.
  765. * No need to properly save the registers, we are going to panic anyway.
  766. * Setup a pt_regs so that show_trace can provide a good call trace.
  767. */
  768. stack_overflow:
  769. l %r15,__LC_PANIC_STACK # change to panic stack
  770. sl %r15,BASED(.Lc_spsize)
  771. mvc SP_PSW(8,%r15),0(%r12) # move user PSW to stack
  772. stm %r0,%r11,SP_R0(%r15) # store gprs %r0-%r11 to kernel stack
  773. la %r1,__LC_SAVE_AREA
  774. ch %r12,BASED(.L0x020) # old psw addr == __LC_SVC_OLD_PSW ?
  775. be BASED(0f)
  776. ch %r12,BASED(.L0x028) # old psw addr == __LC_PGM_OLD_PSW ?
  777. be BASED(0f)
  778. la %r1,__LC_SAVE_AREA+16
  779. 0: mvc SP_R12(16,%r15),0(%r1) # move %r12-%r15 to stack
  780. xc __SF_BACKCHAIN(4,%r15),__SF_BACKCHAIN(%r15) # clear back chain
  781. l %r1,BASED(1f) # branch to kernel_stack_overflow
  782. la %r2,SP_PTREGS(%r15) # load pt_regs
  783. br %r1
  784. 1: .long kernel_stack_overflow
  785. #endif
  786. cleanup_table_system_call:
  787. .long system_call + 0x80000000, sysc_do_svc + 0x80000000
  788. cleanup_table_sysc_return:
  789. .long sysc_return + 0x80000000, sysc_leave + 0x80000000
  790. cleanup_table_sysc_leave:
  791. .long sysc_leave + 0x80000000, sysc_work_loop + 0x80000000
  792. cleanup_table_sysc_work_loop:
  793. .long sysc_work_loop + 0x80000000, sysc_reschedule + 0x80000000
  794. cleanup_table_io_return:
  795. .long io_return + 0x80000000, io_leave + 0x80000000
  796. cleanup_table_io_leave:
  797. .long io_leave + 0x80000000, io_done + 0x80000000
  798. cleanup_table_io_work_loop:
  799. .long io_work_loop + 0x80000000, io_mcck_pending + 0x80000000
  800. cleanup_critical:
  801. clc 4(4,%r12),BASED(cleanup_table_system_call)
  802. bl BASED(0f)
  803. clc 4(4,%r12),BASED(cleanup_table_system_call+4)
  804. bl BASED(cleanup_system_call)
  805. 0:
  806. clc 4(4,%r12),BASED(cleanup_table_sysc_return)
  807. bl BASED(0f)
  808. clc 4(4,%r12),BASED(cleanup_table_sysc_return+4)
  809. bl BASED(cleanup_sysc_return)
  810. 0:
  811. clc 4(4,%r12),BASED(cleanup_table_sysc_leave)
  812. bl BASED(0f)
  813. clc 4(4,%r12),BASED(cleanup_table_sysc_leave+4)
  814. bl BASED(cleanup_sysc_leave)
  815. 0:
  816. clc 4(4,%r12),BASED(cleanup_table_sysc_work_loop)
  817. bl BASED(0f)
  818. clc 4(4,%r12),BASED(cleanup_table_sysc_work_loop+4)
  819. bl BASED(cleanup_sysc_return)
  820. 0:
  821. clc 4(4,%r12),BASED(cleanup_table_io_return)
  822. bl BASED(0f)
  823. clc 4(4,%r12),BASED(cleanup_table_io_return+4)
  824. bl BASED(cleanup_io_return)
  825. 0:
  826. clc 4(4,%r12),BASED(cleanup_table_io_leave)
  827. bl BASED(0f)
  828. clc 4(4,%r12),BASED(cleanup_table_io_leave+4)
  829. bl BASED(cleanup_io_leave)
  830. 0:
  831. clc 4(4,%r12),BASED(cleanup_table_io_work_loop)
  832. bl BASED(0f)
  833. clc 4(4,%r12),BASED(cleanup_table_io_work_loop+4)
  834. bl BASED(cleanup_io_return)
  835. 0:
  836. br %r14
  837. cleanup_system_call:
  838. mvc __LC_RETURN_PSW(8),0(%r12)
  839. c %r12,BASED(.Lmck_old_psw)
  840. be BASED(0f)
  841. la %r12,__LC_SAVE_AREA+16
  842. b BASED(1f)
  843. 0: la %r12,__LC_SAVE_AREA+32
  844. 1:
  845. #ifdef CONFIG_VIRT_CPU_ACCOUNTING
  846. clc __LC_RETURN_PSW+4(4),BASED(cleanup_system_call_insn+4)
  847. bh BASED(0f)
  848. mvc __LC_SYNC_ENTER_TIMER(8),__LC_ASYNC_ENTER_TIMER
  849. 0: clc __LC_RETURN_PSW+4(4),BASED(cleanup_system_call_insn+8)
  850. bhe BASED(cleanup_vtime)
  851. #endif
  852. clc __LC_RETURN_PSW+4(4),BASED(cleanup_system_call_insn)
  853. bh BASED(0f)
  854. mvc __LC_SAVE_AREA(16),0(%r12)
  855. 0: st %r13,4(%r12)
  856. st %r12,__LC_SAVE_AREA+48 # argh
  857. SAVE_ALL_SYNC __LC_SVC_OLD_PSW,__LC_SAVE_AREA
  858. CREATE_STACK_FRAME __LC_SVC_OLD_PSW,__LC_SAVE_AREA
  859. l %r12,__LC_SAVE_AREA+48 # argh
  860. st %r15,12(%r12)
  861. lh %r7,0x8a
  862. #ifdef CONFIG_VIRT_CPU_ACCOUNTING
  863. cleanup_vtime:
  864. clc __LC_RETURN_PSW+4(4),BASED(cleanup_system_call_insn+12)
  865. bhe BASED(cleanup_stime)
  866. tm SP_PSW+1(%r15),0x01 # interrupting from user ?
  867. bz BASED(cleanup_novtime)
  868. UPDATE_VTIME __LC_EXIT_TIMER,__LC_SYNC_ENTER_TIMER,__LC_USER_TIMER
  869. cleanup_stime:
  870. clc __LC_RETURN_PSW+4(4),BASED(cleanup_system_call_insn+16)
  871. bh BASED(cleanup_update)
  872. UPDATE_VTIME __LC_LAST_UPDATE_TIMER,__LC_EXIT_TIMER,__LC_SYSTEM_TIMER
  873. cleanup_update:
  874. mvc __LC_LAST_UPDATE_TIMER(8),__LC_SYNC_ENTER_TIMER
  875. cleanup_novtime:
  876. #endif
  877. mvc __LC_RETURN_PSW+4(4),BASED(cleanup_table_system_call+4)
  878. la %r12,__LC_RETURN_PSW
  879. br %r14
  880. cleanup_system_call_insn:
  881. .long sysc_saveall + 0x80000000
  882. #ifdef CONFIG_VIRT_CPU_ACCOUNTING
  883. .long system_call + 0x80000000
  884. .long sysc_vtime + 0x80000000
  885. .long sysc_stime + 0x80000000
  886. .long sysc_update + 0x80000000
  887. #endif
  888. cleanup_sysc_return:
  889. mvc __LC_RETURN_PSW(4),0(%r12)
  890. mvc __LC_RETURN_PSW+4(4),BASED(cleanup_table_sysc_return)
  891. la %r12,__LC_RETURN_PSW
  892. br %r14
  893. cleanup_sysc_leave:
  894. clc 4(4,%r12),BASED(cleanup_sysc_leave_insn)
  895. be BASED(2f)
  896. #ifdef CONFIG_VIRT_CPU_ACCOUNTING
  897. mvc __LC_EXIT_TIMER(8),__LC_ASYNC_ENTER_TIMER
  898. clc 4(4,%r12),BASED(cleanup_sysc_leave_insn+4)
  899. be BASED(2f)
  900. #endif
  901. mvc __LC_RETURN_PSW(8),SP_PSW(%r15)
  902. c %r12,BASED(.Lmck_old_psw)
  903. bne BASED(0f)
  904. mvc __LC_SAVE_AREA+32(16),SP_R12(%r15)
  905. b BASED(1f)
  906. 0: mvc __LC_SAVE_AREA+16(16),SP_R12(%r15)
  907. 1: lm %r0,%r11,SP_R0(%r15)
  908. l %r15,SP_R15(%r15)
  909. 2: la %r12,__LC_RETURN_PSW
  910. br %r14
  911. cleanup_sysc_leave_insn:
  912. #ifdef CONFIG_VIRT_CPU_ACCOUNTING
  913. .long sysc_leave + 14 + 0x80000000
  914. #endif
  915. .long sysc_leave + 10 + 0x80000000
  916. cleanup_io_return:
  917. mvc __LC_RETURN_PSW(4),0(%r12)
  918. mvc __LC_RETURN_PSW+4(4),BASED(cleanup_table_io_work_loop)
  919. la %r12,__LC_RETURN_PSW
  920. br %r14
  921. cleanup_io_leave:
  922. clc 4(4,%r12),BASED(cleanup_io_leave_insn)
  923. be BASED(2f)
  924. #ifdef CONFIG_VIRT_CPU_ACCOUNTING
  925. mvc __LC_EXIT_TIMER(8),__LC_ASYNC_ENTER_TIMER
  926. clc 4(4,%r12),BASED(cleanup_io_leave_insn+4)
  927. be BASED(2f)
  928. #endif
  929. mvc __LC_RETURN_PSW(8),SP_PSW(%r15)
  930. c %r12,BASED(.Lmck_old_psw)
  931. bne BASED(0f)
  932. mvc __LC_SAVE_AREA+32(16),SP_R12(%r15)
  933. b BASED(1f)
  934. 0: mvc __LC_SAVE_AREA+16(16),SP_R12(%r15)
  935. 1: lm %r0,%r11,SP_R0(%r15)
  936. l %r15,SP_R15(%r15)
  937. 2: la %r12,__LC_RETURN_PSW
  938. br %r14
  939. cleanup_io_leave_insn:
  940. #ifdef CONFIG_VIRT_CPU_ACCOUNTING
  941. .long io_leave + 18 + 0x80000000
  942. #endif
  943. .long io_leave + 14 + 0x80000000
  944. /*
  945. * Integer constants
  946. */
  947. .align 4
  948. .Lc_spsize: .long SP_SIZE
  949. .Lc_overhead: .long STACK_FRAME_OVERHEAD
  950. .Lc_pactive: .long PREEMPT_ACTIVE
  951. .Lnr_syscalls: .long NR_syscalls
  952. .L0x018: .short 0x018
  953. .L0x020: .short 0x020
  954. .L0x028: .short 0x028
  955. .L0x030: .short 0x030
  956. .L0x038: .short 0x038
  957. .Lc_1: .long 1
  958. /*
  959. * Symbol constants
  960. */
  961. .Ls390_mcck: .long s390_do_machine_check
  962. .Ls390_handle_mcck:
  963. .long s390_handle_mcck
  964. .Lmck_old_psw: .long __LC_MCK_OLD_PSW
  965. .Ldo_IRQ: .long do_IRQ
  966. .Ldo_extint: .long do_extint
  967. .Ldo_signal: .long do_signal
  968. .Lhandle_per: .long do_single_step
  969. .Ljump_table: .long pgm_check_table
  970. .Lschedule: .long schedule
  971. .Lclone: .long sys_clone
  972. .Lexecve: .long sys_execve
  973. .Lfork: .long sys_fork
  974. .Lrt_sigreturn: .long sys_rt_sigreturn
  975. .Lrt_sigsuspend:
  976. .long sys_rt_sigsuspend
  977. .Lsigreturn: .long sys_sigreturn
  978. .Lsigsuspend: .long sys_sigsuspend
  979. .Lsigaltstack: .long sys_sigaltstack
  980. .Ltrace: .long syscall_trace
  981. .Lvfork: .long sys_vfork
  982. .Lschedtail: .long schedule_tail
  983. .Lsysc_table: .long sys_call_table
  984. #ifdef CONFIG_TRACE_IRQFLAGS
  985. .Ltrace_irq_on: .long trace_hardirqs_on
  986. .Ltrace_irq_off:
  987. .long trace_hardirqs_off
  988. #endif
  989. .Lcritical_start:
  990. .long __critical_start + 0x80000000
  991. .Lcritical_end:
  992. .long __critical_end + 0x80000000
  993. .Lcleanup_critical:
  994. .long cleanup_critical
  995. .section .rodata, "a"
  996. #define SYSCALL(esa,esame,emu) .long esa
  997. sys_call_table:
  998. #include "syscalls.S"
  999. #undef SYSCALL