copy_to_user.S 1.9 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101
  1. /*
  2. * linux/arch/arm/lib/copy_to_user.S
  3. *
  4. * Author: Nicolas Pitre
  5. * Created: Sep 29, 2005
  6. * Copyright: MontaVista Software, Inc.
  7. *
  8. * This program is free software; you can redistribute it and/or modify
  9. * it under the terms of the GNU General Public License version 2 as
  10. * published by the Free Software Foundation.
  11. */
  12. #include <linux/linkage.h>
  13. #include <asm/assembler.h>
  14. /*
  15. * Prototype:
  16. *
  17. * size_t __copy_to_user(void *to, const void *from, size_t n)
  18. *
  19. * Purpose:
  20. *
  21. * copy a block to user memory from kernel memory
  22. *
  23. * Params:
  24. *
  25. * to = user memory
  26. * from = kernel memory
  27. * n = number of bytes to copy
  28. *
  29. * Return value:
  30. *
  31. * Number of bytes NOT copied.
  32. */
  33. .macro ldr1w ptr reg abort
  34. ldr \reg, [\ptr], #4
  35. .endm
  36. .macro ldr4w ptr reg1 reg2 reg3 reg4 abort
  37. ldmia \ptr!, {\reg1, \reg2, \reg3, \reg4}
  38. .endm
  39. .macro ldr8w ptr reg1 reg2 reg3 reg4 reg5 reg6 reg7 reg8 abort
  40. ldmia \ptr!, {\reg1, \reg2, \reg3, \reg4, \reg5, \reg6, \reg7, \reg8}
  41. .endm
  42. .macro ldr1b ptr reg cond=al abort
  43. ldr\cond\()b \reg, [\ptr], #1
  44. .endm
  45. .macro str1w ptr reg abort
  46. 100: strt \reg, [\ptr], #4
  47. .section __ex_table, "a"
  48. .long 100b, \abort
  49. .previous
  50. .endm
  51. .macro str8w ptr reg1 reg2 reg3 reg4 reg5 reg6 reg7 reg8 abort
  52. str1w \ptr, \reg1, \abort
  53. str1w \ptr, \reg2, \abort
  54. str1w \ptr, \reg3, \abort
  55. str1w \ptr, \reg4, \abort
  56. str1w \ptr, \reg5, \abort
  57. str1w \ptr, \reg6, \abort
  58. str1w \ptr, \reg7, \abort
  59. str1w \ptr, \reg8, \abort
  60. .endm
  61. .macro str1b ptr reg cond=al abort
  62. 100: str\cond\()bt \reg, [\ptr], #1
  63. .section __ex_table, "a"
  64. .long 100b, \abort
  65. .previous
  66. .endm
  67. .macro enter reg1 reg2
  68. mov r3, #0
  69. stmdb sp!, {r0, r2, r3, \reg1, \reg2}
  70. .endm
  71. .macro exit reg1 reg2
  72. add sp, sp, #8
  73. ldmfd sp!, {r0, \reg1, \reg2}
  74. .endm
  75. .text
  76. ENTRY(__copy_to_user)
  77. #include "copy_template.S"
  78. .section .fixup,"ax"
  79. .align 0
  80. copy_abort_preamble
  81. ldmfd sp!, {r1, r2, r3}
  82. sub r0, r0, r1
  83. rsb r0, r0, r2
  84. copy_abort_end
  85. .previous