memset.S 2.3 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125
  1. /* SPDX-License-Identifier: GPL-2.0 */
  2. /*
  3. * linux/arch/arm/lib/memset.S
  4. *
  5. * Copyright (C) 1995-2000 Russell King
  6. *
  7. * ASM optimised string functions
  8. */
  9. #include <linux/linkage.h>
  10. #include <asm/assembler.h>
  11. .text
  12. .align 5
  13. .syntax unified
  14. #if CONFIG_IS_ENABLED(SYS_THUMB_BUILD) && !defined(MEMSET_NO_THUMB_BUILD)
  15. .thumb
  16. .thumb_func
  17. #endif
  18. ENTRY(memset)
  19. ands r3, r0, #3 @ 1 unaligned?
  20. mov ip, r0 @ preserve r0 as return value
  21. bne 6f @ 1
  22. /*
  23. * we know that the pointer in ip is aligned to a word boundary.
  24. */
  25. 1: orr r1, r1, r1, lsl #8
  26. orr r1, r1, r1, lsl #16
  27. mov r3, r1
  28. cmp r2, #16
  29. blt 4f
  30. #if ! CALGN(1)+0
  31. /*
  32. * We need 2 extra registers for this loop - use r8 and the LR
  33. */
  34. stmfd sp!, {r8, lr}
  35. mov r8, r1
  36. mov lr, r1
  37. 2: subs r2, r2, #64
  38. stmiage ip!, {r1, r3, r8, lr} @ 64 bytes at a time.
  39. stmiage ip!, {r1, r3, r8, lr}
  40. stmiage ip!, {r1, r3, r8, lr}
  41. stmiage ip!, {r1, r3, r8, lr}
  42. bgt 2b
  43. ldmfdeq sp!, {r8, pc} @ Now <64 bytes to go.
  44. /*
  45. * No need to correct the count; we're only testing bits from now on
  46. */
  47. tst r2, #32
  48. stmiane ip!, {r1, r3, r8, lr}
  49. stmiane ip!, {r1, r3, r8, lr}
  50. tst r2, #16
  51. stmiane ip!, {r1, r3, r8, lr}
  52. ldmfd sp!, {r8, lr}
  53. #else
  54. /*
  55. * This version aligns the destination pointer in order to write
  56. * whole cache lines at once.
  57. */
  58. stmfd sp!, {r4-r8, lr}
  59. mov r4, r1
  60. mov r5, r1
  61. mov r6, r1
  62. mov r7, r1
  63. mov r8, r1
  64. mov lr, r1
  65. cmp r2, #96
  66. tstgt ip, #31
  67. ble 3f
  68. and r8, ip, #31
  69. rsb r8, r8, #32
  70. sub r2, r2, r8
  71. movs r8, r8, lsl #(32 - 4)
  72. stmiacs ip!, {r4, r5, r6, r7}
  73. stmiami ip!, {r4, r5}
  74. tst r8, #(1 << 30)
  75. mov r8, r1
  76. strne r1, [ip], #4
  77. 3: subs r2, r2, #64
  78. stmiage ip!, {r1, r3-r8, lr}
  79. stmiage ip!, {r1, r3-r8, lr}
  80. bgt 3b
  81. ldmfdeq sp!, {r4-r8, pc}
  82. tst r2, #32
  83. stmiane ip!, {r1, r3-r8, lr}
  84. tst r2, #16
  85. stmiane ip!, {r4-r7}
  86. ldmfd sp!, {r4-r8, lr}
  87. #endif
  88. 4: tst r2, #8
  89. stmiane ip!, {r1, r3}
  90. tst r2, #4
  91. strne r1, [ip], #4
  92. /*
  93. * When we get here, we've got less than 4 bytes to zero. We
  94. * may have an unaligned pointer as well.
  95. */
  96. 5: tst r2, #2
  97. strbne r1, [ip], #1
  98. strbne r1, [ip], #1
  99. tst r2, #1
  100. strbne r1, [ip], #1
  101. ret lr
  102. 6: subs r2, r2, #4 @ 1 do we have enough
  103. blt 5b @ 1 bytes to align with?
  104. cmp r3, #2 @ 1
  105. strblt r1, [ip], #1 @ 1
  106. strble r1, [ip], #1 @ 1
  107. strb r1, [ip], #1 @ 1
  108. add r2, r2, r3 @ 1 (r2 = r2 - (4 - r3))
  109. b 1b
  110. ENDPROC(memset)