u-boot.lds 1.4 KB

12345678910111213141516171819202122232425262728293031323334353637383940414243444546474849505152535455565758596061626364656667686970717273747576777879
  1. /* SPDX-License-Identifier: GPL-2.0+ */
  2. /*
  3. * (C) Copyright 2006-2010
  4. * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
  5. */
  6. OUTPUT_ARCH(powerpc)
  7. SECTIONS
  8. {
  9. /* Read-only sections, merged into text segment: */
  10. .text :
  11. {
  12. arch/powerpc/cpu/mpc83xx/start.o (.text*)
  13. *(.text*)
  14. . = ALIGN(16);
  15. *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  16. }
  17. /* Read-write section, merged into data segment: */
  18. . = (. + 0x0FFF) & 0xFFFFF000;
  19. _erotext = .;
  20. PROVIDE (erotext = .);
  21. .reloc :
  22. {
  23. _GOT2_TABLE_ = .;
  24. KEEP(*(.got2))
  25. KEEP(*(.got))
  26. _FIXUP_TABLE_ = .;
  27. KEEP(*(.fixup))
  28. }
  29. __got2_entries = ((_GLOBAL_OFFSET_TABLE_ - _GOT2_TABLE_) >> 2) - 1;
  30. __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
  31. .data :
  32. {
  33. *(.data*)
  34. *(.sdata*)
  35. }
  36. _edata = .;
  37. PROVIDE (edata = .);
  38. . = .;
  39. . = ALIGN(4);
  40. .u_boot_list : {
  41. KEEP(*(SORT(.u_boot_list*)));
  42. }
  43. . = .;
  44. __start___ex_table = .;
  45. __ex_table : { *(__ex_table) }
  46. __stop___ex_table = .;
  47. /*
  48. * _end - This is end of u-boot.bin image.
  49. * dtb will be appended here to make u-boot-dtb.bin
  50. */
  51. _end = .;
  52. . = ALIGN(4096);
  53. __init_begin = .;
  54. .text.init : { *(.text.init) }
  55. .data.init : { *(.data.init) }
  56. . = ALIGN(4096);
  57. __init_end = .;
  58. __bss_start = .;
  59. .bss (NOLOAD) :
  60. {
  61. *(.bss*)
  62. *(.sbss*)
  63. *(COMMON)
  64. . = ALIGN(4);
  65. }
  66. __bss_end = . ;
  67. PROVIDE (end = .);
  68. }
  69. ENTRY(_start)