lib1funcs.S 8.6 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400401402403404405406407408409410411412413414415416417418419420421422423424425426427
  1. /* SPDX-License-Identifier: GPL-2.0+ */
  2. /*
  3. * linux/arch/arm/lib/lib1funcs.S: Optimized ARM division routines
  4. *
  5. * Author: Nicolas Pitre <nico@fluxnic.net>
  6. * - contributed to gcc-3.4 on Sep 30, 2003
  7. * - adapted for the Linux kernel on Oct 2, 2003
  8. */
  9. /*
  10. * Copyright 1995, 1996, 1998, 1999, 2000, 2003 Free Software Foundation, Inc.
  11. */
  12. #include <linux/linkage.h>
  13. #include <asm/assembler.h>
  14. /*
  15. * U-Boot compatibility bit, define empty UNWIND() macro as, since we
  16. * do not support stack unwinding and define CONFIG_AEABI to make all
  17. * of the functions available without diverging from Linux code.
  18. */
  19. #ifdef __UBOOT__
  20. #define UNWIND(x...)
  21. #define CONFIG_AEABI
  22. #endif
  23. .macro ARM_DIV_BODY dividend, divisor, result, curbit
  24. #if __LINUX_ARM_ARCH__ >= 5
  25. clz \curbit, \divisor
  26. clz \result, \dividend
  27. sub \result, \curbit, \result
  28. mov \curbit, #1
  29. mov \divisor, \divisor, lsl \result
  30. mov \curbit, \curbit, lsl \result
  31. mov \result, #0
  32. #else
  33. @ Initially shift the divisor left 3 bits if possible,
  34. @ set curbit accordingly. This allows for curbit to be located
  35. @ at the left end of each 4 bit nibbles in the division loop
  36. @ to save one loop in most cases.
  37. tst \divisor, #0xe0000000
  38. moveq \divisor, \divisor, lsl #3
  39. moveq \curbit, #8
  40. movne \curbit, #1
  41. @ Unless the divisor is very big, shift it up in multiples of
  42. @ four bits, since this is the amount of unwinding in the main
  43. @ division loop. Continue shifting until the divisor is
  44. @ larger than the dividend.
  45. 1: cmp \divisor, #0x10000000
  46. cmplo \divisor, \dividend
  47. movlo \divisor, \divisor, lsl #4
  48. movlo \curbit, \curbit, lsl #4
  49. blo 1b
  50. @ For very big divisors, we must shift it a bit at a time, or
  51. @ we will be in danger of overflowing.
  52. 1: cmp \divisor, #0x80000000
  53. cmplo \divisor, \dividend
  54. movlo \divisor, \divisor, lsl #1
  55. movlo \curbit, \curbit, lsl #1
  56. blo 1b
  57. mov \result, #0
  58. #endif
  59. @ Division loop
  60. 1: cmp \dividend, \divisor
  61. subhs \dividend, \dividend, \divisor
  62. orrhs \result, \result, \curbit
  63. cmp \dividend, \divisor, lsr #1
  64. subhs \dividend, \dividend, \divisor, lsr #1
  65. orrhs \result, \result, \curbit, lsr #1
  66. cmp \dividend, \divisor, lsr #2
  67. subhs \dividend, \dividend, \divisor, lsr #2
  68. orrhs \result, \result, \curbit, lsr #2
  69. cmp \dividend, \divisor, lsr #3
  70. subhs \dividend, \dividend, \divisor, lsr #3
  71. orrhs \result, \result, \curbit, lsr #3
  72. cmp \dividend, #0 @ Early termination?
  73. movsne \curbit, \curbit, lsr #4 @ No, any more bits to do?
  74. movne \divisor, \divisor, lsr #4
  75. bne 1b
  76. .endm
  77. .macro ARM_DIV2_ORDER divisor, order
  78. #if __LINUX_ARM_ARCH__ >= 5
  79. clz \order, \divisor
  80. rsb \order, \order, #31
  81. #else
  82. cmp \divisor, #(1 << 16)
  83. movhs \divisor, \divisor, lsr #16
  84. movhs \order, #16
  85. movlo \order, #0
  86. cmp \divisor, #(1 << 8)
  87. movhs \divisor, \divisor, lsr #8
  88. addhs \order, \order, #8
  89. cmp \divisor, #(1 << 4)
  90. movhs \divisor, \divisor, lsr #4
  91. addhs \order, \order, #4
  92. cmp \divisor, #(1 << 2)
  93. addhi \order, \order, #3
  94. addls \order, \order, \divisor, lsr #1
  95. #endif
  96. .endm
  97. .macro ARM_MOD_BODY dividend, divisor, order, spare
  98. #if __LINUX_ARM_ARCH__ >= 5
  99. clz \order, \divisor
  100. clz \spare, \dividend
  101. sub \order, \order, \spare
  102. mov \divisor, \divisor, lsl \order
  103. #else
  104. mov \order, #0
  105. @ Unless the divisor is very big, shift it up in multiples of
  106. @ four bits, since this is the amount of unwinding in the main
  107. @ division loop. Continue shifting until the divisor is
  108. @ larger than the dividend.
  109. 1: cmp \divisor, #0x10000000
  110. cmplo \divisor, \dividend
  111. movlo \divisor, \divisor, lsl #4
  112. addlo \order, \order, #4
  113. blo 1b
  114. @ For very big divisors, we must shift it a bit at a time, or
  115. @ we will be in danger of overflowing.
  116. 1: cmp \divisor, #0x80000000
  117. cmplo \divisor, \dividend
  118. movlo \divisor, \divisor, lsl #1
  119. addlo \order, \order, #1
  120. blo 1b
  121. #endif
  122. @ Perform all needed subtractions to keep only the reminder.
  123. @ Do comparisons in batch of 4 first.
  124. subs \order, \order, #3 @ yes, 3 is intended here
  125. blt 2f
  126. 1: cmp \dividend, \divisor
  127. subhs \dividend, \dividend, \divisor
  128. cmp \dividend, \divisor, lsr #1
  129. subhs \dividend, \dividend, \divisor, lsr #1
  130. cmp \dividend, \divisor, lsr #2
  131. subhs \dividend, \dividend, \divisor, lsr #2
  132. cmp \dividend, \divisor, lsr #3
  133. subhs \dividend, \dividend, \divisor, lsr #3
  134. cmp \dividend, #1
  135. mov \divisor, \divisor, lsr #4
  136. subsge \order, \order, #4
  137. bge 1b
  138. tst \order, #3
  139. teqne \dividend, #0
  140. beq 5f
  141. @ Either 1, 2 or 3 comparison/subtractions are left.
  142. 2: cmn \order, #2
  143. blt 4f
  144. beq 3f
  145. cmp \dividend, \divisor
  146. subhs \dividend, \dividend, \divisor
  147. mov \divisor, \divisor, lsr #1
  148. 3: cmp \dividend, \divisor
  149. subhs \dividend, \dividend, \divisor
  150. mov \divisor, \divisor, lsr #1
  151. 4: cmp \dividend, \divisor
  152. subhs \dividend, \dividend, \divisor
  153. 5:
  154. .endm
  155. .pushsection .text.__udivsi3, "ax"
  156. ENTRY(__udivsi3)
  157. ENTRY(__aeabi_uidiv)
  158. UNWIND(.fnstart)
  159. subs r2, r1, #1
  160. reteq lr
  161. bcc Ldiv0
  162. cmp r0, r1
  163. bls 11f
  164. tst r1, r2
  165. beq 12f
  166. ARM_DIV_BODY r0, r1, r2, r3
  167. mov r0, r2
  168. ret lr
  169. 11: moveq r0, #1
  170. movne r0, #0
  171. ret lr
  172. 12: ARM_DIV2_ORDER r1, r2
  173. mov r0, r0, lsr r2
  174. ret lr
  175. UNWIND(.fnend)
  176. ENDPROC(__udivsi3)
  177. ENDPROC(__aeabi_uidiv)
  178. .popsection
  179. .pushsection .text.__umodsi3, "ax"
  180. ENTRY(__umodsi3)
  181. UNWIND(.fnstart)
  182. subs r2, r1, #1 @ compare divisor with 1
  183. bcc Ldiv0
  184. cmpne r0, r1 @ compare dividend with divisor
  185. moveq r0, #0
  186. tsthi r1, r2 @ see if divisor is power of 2
  187. andeq r0, r0, r2
  188. retls lr
  189. ARM_MOD_BODY r0, r1, r2, r3
  190. ret lr
  191. UNWIND(.fnend)
  192. ENDPROC(__umodsi3)
  193. .popsection
  194. .pushsection .text.__divsi3, "ax"
  195. ENTRY(__divsi3)
  196. ENTRY(__aeabi_idiv)
  197. UNWIND(.fnstart)
  198. cmp r1, #0
  199. eor ip, r0, r1 @ save the sign of the result.
  200. beq Ldiv0
  201. rsbmi r1, r1, #0 @ loops below use unsigned.
  202. subs r2, r1, #1 @ division by 1 or -1 ?
  203. beq 10f
  204. movs r3, r0
  205. rsbmi r3, r0, #0 @ positive dividend value
  206. cmp r3, r1
  207. bls 11f
  208. tst r1, r2 @ divisor is power of 2 ?
  209. beq 12f
  210. ARM_DIV_BODY r3, r1, r0, r2
  211. cmp ip, #0
  212. rsbmi r0, r0, #0
  213. ret lr
  214. 10: teq ip, r0 @ same sign ?
  215. rsbmi r0, r0, #0
  216. ret lr
  217. 11: movlo r0, #0
  218. moveq r0, ip, asr #31
  219. orreq r0, r0, #1
  220. ret lr
  221. 12: ARM_DIV2_ORDER r1, r2
  222. cmp ip, #0
  223. mov r0, r3, lsr r2
  224. rsbmi r0, r0, #0
  225. ret lr
  226. UNWIND(.fnend)
  227. ENDPROC(__divsi3)
  228. ENDPROC(__aeabi_idiv)
  229. .popsection
  230. .pushsection .text.__modsi3, "ax"
  231. ENTRY(__modsi3)
  232. UNWIND(.fnstart)
  233. cmp r1, #0
  234. beq Ldiv0
  235. rsbmi r1, r1, #0 @ loops below use unsigned.
  236. movs ip, r0 @ preserve sign of dividend
  237. rsbmi r0, r0, #0 @ if negative make positive
  238. subs r2, r1, #1 @ compare divisor with 1
  239. cmpne r0, r1 @ compare dividend with divisor
  240. moveq r0, #0
  241. tsthi r1, r2 @ see if divisor is power of 2
  242. andeq r0, r0, r2
  243. bls 10f
  244. ARM_MOD_BODY r0, r1, r2, r3
  245. 10: cmp ip, #0
  246. rsbmi r0, r0, #0
  247. ret lr
  248. UNWIND(.fnend)
  249. ENDPROC(__modsi3)
  250. .popsection
  251. #ifdef CONFIG_AEABI
  252. .pushsection .text.__aeabi_uidivmod, "ax"
  253. ENTRY(__aeabi_uidivmod)
  254. UNWIND(.fnstart)
  255. UNWIND(.save {r0, r1, ip, lr} )
  256. stmfd sp!, {r0, r1, ip, lr}
  257. bl __aeabi_uidiv
  258. ldmfd sp!, {r1, r2, ip, lr}
  259. mul r3, r0, r2
  260. sub r1, r1, r3
  261. ret lr
  262. UNWIND(.fnend)
  263. ENDPROC(__aeabi_uidivmod)
  264. .popsection
  265. .pushsection .text.__aeabi_uidivmod, "ax"
  266. ENTRY(__aeabi_idivmod)
  267. UNWIND(.fnstart)
  268. UNWIND(.save {r0, r1, ip, lr} )
  269. stmfd sp!, {r0, r1, ip, lr}
  270. bl __aeabi_idiv
  271. ldmfd sp!, {r1, r2, ip, lr}
  272. mul r3, r0, r2
  273. sub r1, r1, r3
  274. ret lr
  275. UNWIND(.fnend)
  276. ENDPROC(__aeabi_idivmod)
  277. .popsection
  278. #endif
  279. .pushsection .text.Ldiv0, "ax"
  280. Ldiv0:
  281. UNWIND(.fnstart)
  282. UNWIND(.pad #4)
  283. UNWIND(.save {lr})
  284. str lr, [sp, #-8]!
  285. bl __div0
  286. mov r0, #0 @ About as wrong as it could be.
  287. ldr pc, [sp], #8
  288. UNWIND(.fnend)
  289. ENDPROC(Ldiv0)
  290. .popsection
  291. /* Thumb-1 specialities */
  292. #if CONFIG_IS_ENABLED(SYS_THUMB_BUILD) && !defined(CONFIG_HAS_THUMB2)
  293. .pushsection .text.__gnu_thumb1_case_sqi, "ax"
  294. ENTRY(__gnu_thumb1_case_sqi)
  295. push {r1}
  296. mov r1, lr
  297. lsrs r1, r1, #1
  298. lsls r1, r1, #1
  299. ldrsb r1, [r1, r0]
  300. lsls r1, r1, #1
  301. add lr, lr, r1
  302. pop {r1}
  303. bx lr
  304. ENDPROC(__gnu_thumb1_case_sqi)
  305. .popsection
  306. .pushsection .text.__gnu_thumb1_case_uqi, "ax"
  307. ENTRY(__gnu_thumb1_case_uqi)
  308. push {r1}
  309. mov r1, lr
  310. lsrs r1, r1, #1
  311. lsls r1, r1, #1
  312. ldrb r1, [r1, r0]
  313. lsls r1, r1, #1
  314. add lr, lr, r1
  315. pop {r1}
  316. bx lr
  317. ENDPROC(__gnu_thumb1_case_uqi)
  318. .popsection
  319. .pushsection .text.__gnu_thumb1_case_shi, "ax"
  320. ENTRY(__gnu_thumb1_case_shi)
  321. push {r0, r1}
  322. mov r1, lr
  323. lsrs r1, r1, #1
  324. lsls r0, r0, #1
  325. lsls r1, r1, #1
  326. ldrsh r1, [r1, r0]
  327. lsls r1, r1, #1
  328. add lr, lr, r1
  329. pop {r0, r1}
  330. bx lr
  331. ENDPROC(__gnu_thumb1_case_shi)
  332. .popsection
  333. .pushsection .text.__gnu_thumb1_case_uhi, "ax"
  334. ENTRY(__gnu_thumb1_case_uhi)
  335. push {r0, r1}
  336. mov r1, lr
  337. lsrs r1, r1, #1
  338. lsls r0, r0, #1
  339. lsls r1, r1, #1
  340. ldrh r1, [r1, r0]
  341. lsls r1, r1, #1
  342. add lr, lr, r1
  343. pop {r0, r1}
  344. bx lr
  345. ENDPROC(__gnu_thumb1_case_uhi)
  346. .popsection
  347. #endif